Как я могу отформатировать десятичную в xquery? - PullRequest
Новая
       18

Как я могу отформатировать десятичную в xquery?

6 голосов
/ 30 апреля 2011

Я пытаюсь отформатировать десятичные дроби в XQuery. Десятичные знаки - валюта, поэтому формат должен быть ,###.##.

Например:

5573652.23 должно быть 5,573,652.23

и

352769 должно быть 352,769 (или 352,769.00, если проще / чище)

Сейчас я использую эту функцию из http://www.xqueryhacker.com/2009/09/format-number-in-xquery/,, но не могу использовать с ней десятичные дроби: 

declare function local:format-int($i as xs:int) as xs:string
{
  let $input :=
    if ($i lt 0) then fn:substring(fn:string($i), 2)
    else fn:string($i)
  let $rev := fn:reverse(fn:string-to-codepoints(fn:string($input)))
  let $comma := fn:string-to-codepoints(',')

  let $chars :=
    for $c at $i in $rev
    return (
      $c,
      if ($i mod 3 eq 0 and fn:not($i eq count($rev)))
      then $comma else ()
    )

  return fn:concat(
    if ($i lt 0) then '-' else (),
    fn:codepoints-to-string(fn:reverse($chars))
  )
};

Я использую Saxon 9HE для своего процессора.

Любая помощь будет принята с благодарностью.

----- ОБНОВЛЕНИЕ -----

Основываясь на ответе Димитра, я изменил функцию, чтобы сохранить десятичную часть и добавить ее в конец возвращаемой строки.

Новая функция 

declare function local:format-dec($i as xs:decimal) as xs:string
{
  let $input := tokenize(string(abs($i)),'\.')[1]
  let $dec := substring(tokenize(string($i),'\.')[2],1,2)
  let $rev := reverse(string-to-codepoints(string($input)))
  let $comma := string-to-codepoints(',')

  let $chars :=
    for $c at $i in $rev
    return (
      $c,
      if ($i mod 3 eq 0 and not($i eq count($rev)))
      then $comma else ()
    )

  return concat(if ($i lt 0) then '-' else (),
                codepoints-to-string(reverse($chars)),
                if ($dec != '') then concat('.',$dec) else ()
                )
};

Ответы [ 3 ]

3 голосов
/ 01 мая 2011

Используйте 

let $n := 5573652.23
 return
      concat(local:format-int(xs:int(floor($n))),
             '.',
             substring(string($n - floor($n)), 3)
             )

Это дает именно нужный, правильный результат : 

5,573,652.23
1 голос
/ 01 мая 2011

Это не работает для вас?: 

format-number(5573652.23,",###.##")

Вы можете поиграть с этим здесь .Я почти уверен, что saxon поддерживает эту функцию.

Edit : эта функция не поддерживается в saxon (см. Комментарии ниже).

0 голосов
/ 06 марта 2019

С XQuery 3.0 и Saxon-HE 9.7 Parser вы можете делать следующее: 

declare decimal-format local:de decimal-separator = "," grouping-separator = ".";
declare decimal-format local:en decimal-separator = "." grouping-separator = ",";
let $numbers := (1234.567, 789, 1234567.765)
for $i in $numbers
return (
   format-number($i,"#.###,##","local:de"),
   format-number($i,"#,###.##","local:en")
)

Вывод: 

<?xml version="1.0" encoding="UTF-8"?>1.234,57 1,234.57 789,0 789.0 1.234.567,76 
1,234,567.76
...