Полиморфизм строк в Haskell: проблема написания Forth DSL с «преобразованиями» - PullRequest
Новая
       56

Полиморфизм строк в Haskell: проблема написания Forth DSL с «преобразованиями»

9 голосов
/ 18 февраля 2012

Я был вдохновлен недавней активностью блога на Haskell 1 , чтобы попробовать свои силы в написании Forth-подобного DSL на Haskell.Подход, который я выбрал, одновременно прост и запутан: 

{-# LANGUAGE TypeOperators, RankNTypes, ImpredicativeTypes #-}

-- a :~> b represents a "stack transformation"
--          from stack type "a" to stack type "b"
-- a :> b represents a "stack" where the top element is of type "b"
--          and the "rest" of the stack has type "a"
type s :~> s' = forall r. s -> (s' -> r) -> r
data a :> b = a :> b deriving Show
infixl 4 :>

Для выполнения простых вещей это работает очень хорошо: 

start :: (() -> r) -> r
start f = f ()

end :: (() :> a) -> a
end (() :> a) = a

stack x f = f x
runF s = s end
_1 = liftS0 1
neg = liftS1 negate
add = liftS2 (+)

-- aka "push"
liftS0 :: a -> (s :~> (s :> a))
liftS0 a s = stack $ s :> a

liftS1 :: (a -> b) -> ((s :> a) :~> (s :> b))
liftS1 f (s :> a) = stack $ s :> f a

liftS2 :: (a -> b -> c) -> ((s :> a :> b) :~> (s :> c))
liftS2 f (s :> a :> b) = stack $ s :> f a b

Простые функции можно легко преобразовать в соответствующие им преобразования стека.,Некоторые игры пока дают приятные результаты: 

ghci> runF $ start _1 _1 neg add
0

Проблема возникает, когда я пытаюсь расширить это с помощью функций более высокого порядка. 

-- this requires ImpredicativeTypes...not really sure what that means
-- also this implementation seems way too simple to be correct
-- though it does typecheck. I arrived at this after pouring over types
-- and finally eta-reducing the (s' -> r) function argument out of the equation
-- call (a :> f) h = f a h
call :: (s :> (s :~> s')) :~> s'
call (a :> f) = f a

call предполагается преобразовать стек формы (s :> (s :~> s')) в форму s, по существу, "применяя" преобразование (удерживаемое на вершине стека) к его "остальной части".Я думаю, что должно работать так: 

ghci> runF $ start _1 (liftS0 neg) call
-1

Но на самом деле это дает мне огромную ошибку несоответствия типов.Что я делаю неправильно?Может ли представление «преобразование стека» в достаточной степени обрабатывать функции более высокого порядка, или мне нужно его настроить?

1 NB В отличие от того, как эти парни сделали это, вместо start push 1 push 2 add end, яхочу, чтобы это было runF $ start (push 1) (push 2) add, идея заключается в том, что, возможно, позже я смогу поработать с магией типов, чтобы сделать push неявным для определенных литералов.

Ответы [ 2 ]

4 голосов
/ 18 февраля 2012

Проблема в том, что ваш синоним типа является полиморфным типом 

type s :~> s' = forall r. s -> (s' -> r) -> r

Использование полиморфного типа в качестве аргумента для конструктора типа, отличного от ->, называется "непредсказуемостью".Например, следующее было бы непредсказуемым использованием 

Maybe (forall a. a -> a)

По разным причинам определение типа с непредсказуемостью затруднительно, поэтому GHC жалуется.(Название «непредсказуемое» происходит от логики и изоморфизма Карри-Ховардса.)


В вашем случае решение состоит просто в использовании алгебраического типа данных с конструктором: 

data s :~> s' = StackArr { runStackArr :: forall r. s -> (s' -> r) -> r}

По сути, явный конструктор StackArr предоставляет достаточно подсказок для средства проверки типов.

В качестве альтернативы, вы можете попробовать расширение языка ImpredicativeTypes.

3 голосов
/ 23 февраля 2012

Ваш тип :~> не тот, который вы на самом деле хотите (отсюда ImpredicativeTypes).Если вы просто удалите аннотацию типа из call, тогда ваш последний образец будет работать как положено.Еще один способ заставить его работать - использовать менее причудливый, но более подходящий тип с дополнительным параметром: 

type Tran s s' r = s -> (s' -> r) -> r

call :: Tran (s :> (Tran s s' r)) s' r
call (a :> f) = f a

Но если то, что вам нужно, это хороший синтаксис DSL и вы можете терпеть OverlappingInstances, тогда вы можетедаже в значительной степени избавиться от функций liftSx: 

{-# LANGUAGE TypeOperators, MultiParamTypeClasses, TypeFamilies,
             FlexibleInstances, FlexibleContexts,
             UndecidableInstances, IncoherentInstances  #-}

data a :> b = a :> b deriving Show
infixl 4 :>


class Stackable s o r where
    eval :: s -> o -> r


data End = End

instance (r1 ~ s) => Stackable s End r1 where
    eval s End = s


instance (Stackable (s :> a) o r0, r ~ (o -> r0)) => Stackable s a r where
    eval s a = eval (s :> a)

instance (a ~ b, Stackable s c r0, r ~ r0) => Stackable (s :> a) (b -> c) r where
    eval (s :> a) f = eval s (f a)

-- Wrap in Box a function which should be just placed on stack without immediate application
data Box a = Box a

instance (Stackable (s :> a) o r0, r ~ (o -> r0)) => Stackable s (Box a) r where
    eval s (Box a) = eval (s :> a)


runS :: (Stackable () a r) => a -> r
runS a = eval () a

-- tests
t1 = runS 1 negate End
t2 = runS 2 1 negate (+) End

t3 = runS 1 (Box negate) ($) End
t4 = runS [1..5] 0 (Box (+)) foldr End
t5 = runS not True (flip ($)) End

t6 = runS 1 (+) 2 (flip ($)) End
...