Вложения с использованием REST WebService и VB.NET - PullRequest
Новая
       21

Вложения с использованием REST WebService и VB.NET

1 голос
/ 26 мая 2011

В настоящее время я разрабатываю приложение с использованием VB.NET, в котором я использую REST WebServices.Я был в состоянии сделать основы с REST, однако я не смог добавить вложение (более конкретно, загрузить файл, используя REST, который присоединяется).Я провел обширные исследования в Интернете, но до сих пор не смог найти ни одного рабочего примера в VB.NET.Для фактической загрузки данных я использую System.Net.WebClient.Следующий код VB.NET выполняет важную работу: 

Dim Client As New System.Net.WebClient
Dim postBytes As Byte() = System.Text.Encoding.ASCII.GetBytes(postString)
Client.UploadData(URL, "POST", postBytes)

Упрощенная версия моего URL выглядит следующим образом: "../REST/1.0/ticket/" + ticketNumber + "/comment?user=" + userName + "&pass=" + password

Наконец, пример контента, который я публикую,: 

postString = "content=Text: RT Test" + vbLf + "Action: Comment" + vbLf + "Attachment: examplefile.jpg" + vbLf + "attachment_1="

Как видите, postString преобразуется в байты и затем загружается на сервер.Однако я не знаю, где и как я должен публиковать исходное вложение.В документации для сервиса мы специально используем состояния для использования переменной "attachment_1", которую я добавил в переменную postString, но я не уверен, каким должен быть следующий шаг.Должен ли файл быть преобразован в байты и добавлен в переменную postBytes?Я попытался сделать что-то подобное, но получил сообщение об ошибке, в котором говорится, что вложение, например, examplefile.jpg не найдено.

Спасибо за помощь!

1 Ответ

1 голос
/ 07 июня 2011

Мы не могли использовать Client.UploadData (...) и должны были преобразовать весь пост в байты, начиная с полей POST перед вложением, затем самого вложения и, наконец, оставшихся полей POST.* 

Public Sub AddAttachmentToRT(ByVal url As String, ByVal fileName As String, ByVal filePath As String)

    Dim dataBoundary As String = "--xYzZY"
    Dim request As HttpWebRequest
    Dim fileType As String = "image/jpeg" 'Will want to extract this to make it more generic from the uploaded file.

    'Create a POST web request to the REST interface using the passed URL
    request = CType(WebRequest.Create(url), HttpWebRequest)
    request.ContentType = "multipart/form-data; boundary=xYzZY"
    request.Method = "POST"
    request.KeepAlive = True

    'Write the request to the requestStream
    Using requestStream As IO.Stream = request.GetRequestStream()

        'Create a variable "attachment_1" in the POST, specify the file name and file type
        Dim preAttachment As String = dataBoundary + vbCrLf _
        + "Content-Disposition: form-data; name=""attachment_1""; filename=""" + fileName + """" + vbCrLf _
        + "Content-Type: " + fileType + vbCrLf _
        + vbCrLf

        'Convert this preAttachment string to bytes
        Dim preAttachmentBytes As Byte() = System.Text.Encoding.UTF8.GetBytes(preAttachment)

        'Write this preAttachment string to the stream
        requestStream.Write(preAttachmentBytes, 0, preAttachmentBytes.Length)

        'Write the file as bytes to the stream by passing its exact location
        Using fileStream As New IO.FileStream(Server.MapPath(filePath + fileName), IO.FileMode.Open, IO.FileAccess.Read)

            Dim buffer(4096) As Byte
            Dim bytesRead As Int32 = fileStream.Read(buffer, 0, buffer.Length)

            Do While (bytesRead > 0)

                requestStream.Write(buffer, 0, bytesRead)
                bytesRead = fileStream.Read(buffer, 0, buffer.Length)

            Loop

        End Using

        'Create a variable named content in the POST, specify the attachment name and comment text
        Dim postAttachment As String = vbCrLf _
        + dataBoundary + vbCrLf _
        + "Content-Disposition: form-data; name=""content""" + vbCrLf _
        + vbCrLf _
        + "Action: comment" + vbLf _
        + "Attachment: " + fileName + vbCrLf _
        + "Text: Some description" + vbCrLf _
        + vbCrLf _
        + "--xYzZY--"

        'Convert postAttachment string to bytes
        Dim postAttachmentBytes As Byte() = System.Text.Encoding.UTF8.GetBytes(postAttachment)

        'Write the postAttachment string to the stream
        requestStream.Write(postAttachmentBytes, 0, postAttachmentBytes.Length)

    End Using

    Dim response As Net.WebResponse = Nothing

    'Get the response from our REST request to RT
    'Required to capture response, without this Try-Catch attaching will fail
    Try
        response = request.GetResponse()

        Using responseStream As IO.Stream = response.GetResponseStream()

            Using responseReader As New IO.StreamReader(responseStream)

                Dim responseText = responseReader.ReadToEnd()

            End Using

        End Using

    Catch exception As Net.WebException

        response = exception.Response

        If (response IsNot Nothing) Then

            Using reader As New IO.StreamReader(response.GetResponseStream())

                Dim responseText = reader.ReadToEnd()

            End Using

            response.Close()

        End If

    Finally

        request = Nothing

    End Try

End Sub
...