Сохранить размеры (вместе с изображением) в столбцах базы данных? - PullRequest
Новая
       0

Сохранить размеры (вместе с изображением) в столбцах базы данных?

1 голос
/ 30 апреля 2011

Я должен хранить свои изображения в полях varbinary (max) в базе данных SQLServer 2008 (файловая система не подходит для моей среды).

Я хотел бы иметь возможность устанавливать свойства изображения и высотына HTML-тегах изображений, когда я подаю их (в моем приложении MVC2) и делаю разные вещи в галерее, в зависимости от портретной или альбомной ориентации.

Итак, по вашему опыту, стоило бы хлопот (и ненормализации?) Хранить эту информацию в отдельных столбцах базы данных, или достаточно дешево, с точки зрения производительности, чтобы захватить высоту иширина и рассчитать ориентацию на лету?

Ответы [ 2 ]

2 голосов
/ 02 ноября 2012

Вы можете кэшировать размеры при первом запросе изображения.Хорошая вещь о varbinary (max) в том, что их относительно легко заглянуть внутрь из SQL.Пришлось написать это недавно, чтобы извлечь размеры JPEG из varbinary 

CREATE PROCEDURE [SP_GET_JPEG_DIMENSIONS] 
(   
    @image varbinary(max), 
    @width int OUTPUT, 
    @height int OUTPUT,
    @Xdensity int OUTPUT,
    @Ydensity int OUTPUT    
) 
AS
    DECLARE @blocksize INT
    DECLARE @datasize INT
    DECLARE @i int
    SET @i=1
    SET @datasize = DATALENGTH(@image);
    IF(
        --Check for correct lead in
        SUBSTRING(@image,@i,1)=0xFF 
        AND SUBSTRING(@image,@i+1,1)=0xD8 
        AND SUBSTRING(@image,@i+2,1)=0xFF 
        AND SUBSTRING(@image,@i+3,1)=0xE0
        )
    BEGIN
        SET @i = @i+4;
        IF 
        (
        --Check for JFIF identifier
        CHAR(SUBSTRING(@image,@i+2,1))='J' 
        AND CHAR(SUBSTRING(@image,@i+3,1))='F' 
        AND CHAR(SUBSTRING(@image,@i+4,1))='I' 
        AND CHAR(SUBSTRING(@image,@i+5,1))='F'
        AND SUBSTRING(@image,@i+6,1)=0x00
        )
        BEGIN
            --get density
            SET @Xdensity = SUBSTRING(@image,@i+10,1)*256+SUBSTRING(@image,@i+11,1)
            SET @Ydensity = SUBSTRING(@image,@i+12,1)*256+SUBSTRING(@image,@i+13,1)

            SET @blocksize = SUBSTRING(@image,@i,1)*256+SUBSTRING(@image,@i+1,1)
            WHILE @i < @datasize
            BEGIN
                SET @i = @i+ @blocksize

                IF SUBSTRING(@image,@i,1) <> 0xFF RETURN -1 --not a good block              

                IF SUBSTRING(@image,@i+1,1)  = 0xC0 --image size block
                BEGIN
                    SET @height = SUBSTRING(@image,@i+5,1)*256+SUBSTRING(@image,@i+6,1)
                    SET @width = SUBSTRING(@image,@i+7,1)*256+SUBSTRING(@image,@i+8,1)

                END
                ELSE -- some other sort of block - move onto the next one
                BEGIN
                    SET @i = @i+2
                    SET @blocksize = SUBSTRING(@image,@i,1)*256+SUBSTRING(@image,@i+1,1)
                END         
            END
        END
        ELSE 
        BEGIN
            SET @width = -1
        END
    END
    ELSE 
    BEGIN
        SET @height = -1
        SET @width = -1
    END     
RETURN
GO
2 голосов
/ 30 апреля 2011

Насколько легко их получить?

Если у вас есть экземпляр объекта каждые раз для каждого изображения, которое приводит к множеству ненужных накладных расходов.Я предполагаю, что изображения тоже будут статичными?

Я бы предпочел сохранить значения, если они использовались часто.

...