xsl печатает дочерние узлы в строке ниже, где я хочу - PullRequest
Новая
       9

xsl печатает дочерние узлы в строке ниже, где я хочу

0 голосов
/ 30 марта 2012

Это мой первый пост, поэтому я надеюсь, что форматирование / подробности представлены хорошо.Кроме того, я действительно новичок в xml / xsl, но я искал ответ на этот вопрос и ничего не нашел.У меня есть данные, которые я пытаюсь отобразить в одной строке, но когда я запускаю xsltproc с файлом xsl, данные появляются в строке ниже, где я хочу.

Во-первых, вот вывод, который я получаю: 

$ xsltproc MyXSL.xsl MyData.xml

<?xml version="1.0"?>

Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement1,,Suspect Flag
DEFAULT2
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement2,,Suspect Flag
DEFAULT19
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement3,,Suspect Flag
DEFAULT2
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement4,,Suspect Flag
DEFAULT0

Мне нужно следующее: 

Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement1,DEFAULT,2,Suspect Flag
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement2,DEFAULT,19,Suspect Flag
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement3,DEFAULT,2,Suspect Flag
Measurement Information,Time Stamp:20120315150500.0+0000,Granularity Period:300,Measurement Values,Object Instance ID,,DataElement4,DEFAULT,0,Suspect Flag

Вот данные, над которыми я работаю,и у меня возникают проблемы с дочерними полями "mdc / md / mi / mv", "moid" и "r": 

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="MyXSL.xsl" ?>
<mdc xmlns:HTML="http://www.w3.org/TR/REC-xml">
<md>
<mi>
    <mts>20120315150500.0+0000</mts>
    <gp>300</gp>
    <mt>DataElement1</mt>
    <mv>
        <moid>DEFAULT</moid>
        <r>2</r>
    </mv>
</mi>
<mi>
    <mts>20120315150500.0+0000</mts>
    <gp>300</gp>
    <mt>DataElement2</mt>
    <mv> 
        <moid>DEFAULT</moid> 
        <r>19</r> 
    </mv>
</mi>
<mi>
    <mts>20120315150500.0+0000</mts>
    <gp>300</gp>
    <mt>DataElement3</mt>
    <mv>
        <moid>DEFAULT</moid>
        <r>2</r>
    </mv>
</mi>
<mi>
    <mts>20120315150500.0+0000</mts>
    <gp>300</gp>
    <mt>DataElement4</mt>
    <mv>
        <moid>DEFAULT</moid>
        <r>0</r>
    </mv>
</mi>
</md>
</mdc>

Вот файл xsl, который яиспользуя для разбора xml: 

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:strip-space elements="*"/>

<xsl:template match="/">
      <xsl:apply-templates/>
</xsl:template>

<xsl:template match="mdc">
   <xsl:apply-templates/>
</xsl:template>

<xsl:template match="md">
   <xsl:apply-templates/>
</xsl:template>

<xsl:template match="mi">
Measurement Information,Time Stamp:<xsl:value-of select="mts"/>,Granularity Period:<xsl:value-of select="gp"/>,Measurement Values,Object Instance ID,<xsl:for-each select="mt">,<xsl:value-of select="."/>,</xsl:for-each>,Suspect Flag
<xsl:apply-templates/>
</xsl:template>

<xsl:template match="mts">
</xsl:template>

<xsl:template match="gp">
</xsl:template>

<xsl:template match="mt">
</xsl:template>

<xsl:template match="mv">
<xsl:value-of select="moid"/>
<xsl:for-each select="r">
<xsl:value-of select="."/>
</xsl:for-each>
<xsl:value-of select="sf"/>
</xsl:template>

</xsl:stylesheet>

Все файлы были созданы / получены через файловые системы только для Unix, и я вдвойне убедился, что это не было вызвано символами завершения строки, выполнив ввод через sedя s / \ r // g '

Любая помощь очень ценится.

Спасибо!

1 Ответ

1 голос
/ 30 марта 2012

Вот упрощенная таблица стилей, которая создает вывод, который вы опубликовали как требуемый результат: 

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:strip-space elements="*"/>

<xsl:template match="mi">
  <xsl:text>Measurement Information</xsl:text>
  <xsl:apply-templates select="descendant::*[not(*)]"/>
  <xsl:text>,Suspect Flag&#10;</xsl:text>
</xsl:template>

<xsl:template match="mts">
  <xsl:if test="position() > 1">
    <xsl:text>,</xsl:text>
  </xsl:if>
  <xsl:text>Time Stamp:</xsl:text><xsl:value-of select="."/>
</xsl:template>

<xsl:template match="gp">
  <xsl:if test="position() > 1">
    <xsl:text>,</xsl:text>
  </xsl:if>
  <xsl:text>Granularity Period:</xsl:text><xsl:value-of select="."/>
  <xsl:text>,Measurement Values,Object Instance ID,</xsl:text>
</xsl:template>

<xsl:template match="mt | mv/*">
  <xsl:if test="position() > 1">
    <xsl:text>,</xsl:text>
  </xsl:if>
  <xsl:value-of select="."/>
</xsl:template>

</xsl:stylesheet>
...