Как получить значения из вложенной процедуры Oracle?

Question

У меня какая-то сложная проблема с Oracle. Я пытаюсь выбрать один набор данных, мы будем называть элементы. Для каждого предмета я хочу вызвать другую процедуру и вернуть инвентарный товар. У меня есть две операции, которые я не уверен, как выполнить.

1. Как получить значение из вложенной процедуры?

2. Как вернуть эти извлеченные значения в форме SYS_REFCURSOR?

Моя попытка заключалась в том, чтобы поместить результаты из spSelect_Inv_Search во вложенную таблицу с именем ITEMS_TABLE. Это не работает.

код ниже

PROCEDURE SPSELECT_ITEM (IO_CURSOR OUT SYS_REFCURSOR) 
AS   
  MY_CURSOR SYS_REFCURSOR;
  TYPE ITEM_TYPE IS TABLE OF ITEMS.ITEM_NO%TYPE;
  ITEM_TABLE ITEM_TYPE := ITEM_TYPE();

  CURSOR ITEMS_CURSOR IS
      SELECT ITEM_NO 
      FROM ITEMS;

  V_COUNTER INTEGER := 0;
BEGIN
  FOR ITEM_REC IN ITEM_CURSOR LOOP
    V_COUNTER := V_COUNTER + 1;
    ITEM_TABLE.EXTEND;
    ITEM_TABLE(V_COUNTER) := spSelect_Inv_Search(ITEM_REC.ITEM_NO, MY_CURSOR);
  END LOOP;
END SPSELECT_ITEMS;

Любая помощь приветствуется, спасибо.

Answer 1

Вы, кажется, хотите объединить неизвестное число SYS_REFCURSOR наборов результатов в один большой. Если вы знаете структуру курсора, возвращенного из spSelect_Inv_Search, вы можете сделать это с помощью промежуточной конвейерной функции.

create package p as
    type tmp_rec_type is record (owner all_objects.owner%type,
        object_type all_objects.object_type%type,
        objects number);
    type tmp_rec_table is table of tmp_rec_type;

    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor);
    function func2 return tmp_rec_table pipelined;
    procedure proc3(p_cursor out sys_refcursor);
end;
/

Типы могут быть определены здесь, они не обязательно должны быть на уровне SQL, так как вам никогда не потребуется ссылаться на них вне пакета.

create package body p as
    procedure proc1(p_owner in varchar2, p_cursor out sys_refcursor) as
    begin
        open p_cursor for select owner, object_type, count(*)
            from all_objects
            where owner = p_owner
            group by owner, object_type;
    end;

    function func2 return tmp_rec_table pipelined as
        cursor c1 is select distinct owner
            from all_tables where owner in ('SYS','SYSTEM');
        tmp_cursor sys_refcursor;
        tmp_rec tmp_rec_type;
    begin
        for r1 in c1 loop
            proc1(r1.owner, tmp_cursor);
            loop
                fetch tmp_cursor into tmp_rec;
                exit when tmp_cursor%notfound;
                pipe row(tmp_rec);
            end loop;
        end loop;
    end;

    procedure proc3(p_cursor out sys_refcursor) as
    begin
        open p_cursor for select * from table(func2);
    end;
end p;
/

Затем для выполнения, которое вы можете выполнить вне пакета, несмотря на типы, используемые для промежуточного этапа, вы можете сделать это для тестирования в SQL * Plus или SQL Developer:

var rc refcursor;
exec p.proc3(:rc);
print rc;

Для моей базы данных это дает:

OWNER                          OBJECT_TYPE         OBJECTS                
------------------------------ ------------------- ---------------------- 
SYSTEM                         VIEW                1                      
SYSTEM                         TABLE               5                      
SYS                            VIEW                1056                   
SYS                            CONSUMER GROUP      2                      
SYS                            PROCEDURE           11                     
SYS                            FUNCTION            56                     
SYS                            SEQUENCE            1                      
SYS                            OPERATOR            6                      
SYS                            EVALUATION CONTEXT  1                      
SYS                            TABLE               13                     
SYS                            WINDOW GROUP        1                      
SYS                            PACKAGE             162                    
SYS                            WINDOW              2                      
SYS                            TYPE                529                    
SYS                            JOB CLASS           1                      
SYS                            SCHEDULE            1     

Это, очевидно, очень надумано, так как вы делаете это одним запросом, но я предполагаю, что вашей внутренней процедуре нужно сделать что-то более сложное.

Answer 2

Чтобы ответить на ваш вопрос о том, как позвонить spSelect_Inv_Search, мне нужно знать сигнатуру этой подпрограммы.Вы описали это как процедуру, но пытаетесь вызвать ее как функцию.Что он?Какие возвращаемые значения и / или параметры режима OUT у него есть?

Чтобы вернуть открытый REF CURSOR из описанной выше процедуры, сначала необходимо объявить вложенный тип таблицы на уровне схемы (используя CREATE TYPEзаявление), а не в коде PL / SQL.Затем вы можете открыть курсор следующим образом, после заполнения вложенной таблицы.

OPEN io_cursor FOR SELECT * FROM TABLE(CAST(item_table AS item_type));

(И, кстати, я бы сам изменил имя типа с ITEM_TYPE на ITEM_TABLE_TYPE.)