DistributionFitTest [] для пользовательских дистрибутивов в Mathematica - PullRequest
Новая
       19

DistributionFitTest [] для пользовательских дистрибутивов в Mathematica

8 голосов
/ 15 июня 2011

У меня есть PDF-файлы и CDF-файлы для двух пользовательских дистрибутивов, средство генерации RandomVariates для каждого и код для подгонки параметров к данным. Часть этого кода, который я выложил ранее по адресу:

Расчет ожидания для пользовательского распределения в Mathematica

Вот некоторые из них: 

nlDist /: PDF[nlDist[alpha_, beta_, mu_, sigma_], 
   x_] := (1/(2*(alpha + beta)))*alpha* 
   beta*(E^(alpha*(mu + (alpha*sigma^2)/2 - x))* 
      Erfc[(mu + alpha*sigma^2 - x)/(Sqrt[2]*sigma)] + 
     E^(beta*(-mu + (beta*sigma^2)/2 + x))* 
      Erfc[(-mu + beta*sigma^2 + x)/(Sqrt[2]*sigma)]); 

nlDist /: 
  CDF[nlDist[alpha_, beta_, mu_, sigma_], 
   x_] := ((1/(2*(alpha + beta)))*((alpha + beta)*E^(alpha*x)* 
        Erfc[(mu - x)/(Sqrt[2]*sigma)] - 
       beta*E^(alpha*mu + (alpha^2*sigma^2)/2)*
        Erfc[(mu + alpha*sigma^2 - x)/(Sqrt[2]*sigma)] + 
       alpha*E^((-beta)*mu + (beta^2*sigma^2)/2 + alpha*x + beta*x)*
        Erfc[(-mu + beta*sigma^2 + x)/(Sqrt[2]*sigma)]))/ 
   E^(alpha*x);         

dplDist /: PDF[dplDist[alpha_, beta_, mu_, sigma_], x_] := 
  PDF[nlDist[alpha, beta, mu, sigma], Log[x]]/x;
dplDist /: CDF[dplDist[alpha_, beta_, mu_, sigma_], x_] := 
  CDF[nlDist[alpha, beta, mu, sigma], Log[x]];

nlDist /: DistributionDomain[nlDist[alpha_, beta_, mu_, sigma_]] := 
 Interval[{-Infinity, Infinity}]

nlDist /: 
    Random`DistributionVector[
    nlDist [alpha_, beta_, mu_, sigma_], n_, prec_] :=
    RandomVariate[ExponentialDistribution[alpha], n, 
        WorkingPrecision -> prec] - 
      RandomVariate[ExponentialDistribution[beta], n, 
        WorkingPrecision -> prec] + 
      RandomVariate[NormalDistribution[mu, sigma], n, 
        WorkingPrecision -> prec];

dplDist /: 
    Random`DistributionVector[
    dplDist[alpha_, beta_, mu_, sigma_], n_, prec_] :=
    Exp[RandomVariate[ExponentialDistribution[alpha], n, 
         WorkingPrecision -> prec] - 
       RandomVariate[ExponentialDistribution[beta], n, 
         WorkingPrecision -> prec] + 
       RandomVariate[NormalDistribution[mu, sigma], n, 
         WorkingPrecision -> prec]];

Я могу опубликовать больше кода, если кому-то нужно его увидеть, но я думаю, что вышеизложенное дает хороший смысл подхода.

Теперь мне нужен способ использовать DistributionFitTest [] с этими дистрибутивами примерно так: 

DistributionFitTest[data, dplDist[3.77, 1.34, -2.65, 0.40],"HypothesisTestData"]

Ах, но это не работает. Вместо этого я получаю сообщение об ошибке, которое начинается как:

«Аргумент dplDist [3.77,1.34, -2.65,0.4] должно быть действительный дистрибутив ... "

Похоже, что DistributionFitTest [] не распознает эти распределения как распределения.

Я не вижу, как использование TagSet поможет в этом случае, если только вы не можете использовать TagSet, чтобы дать DistributionFitTest [] то, что нужно для идентификации этих пользовательских дистрибутивов.

Может кто-нибудь посоветовать мне способ заставить это работать? Я хотел бы использовать DistributionFitTest [] с такими пользовательскими дистрибутивами или найти способ обойтись без оценки.

Спасибо - Ягра

1 Ответ

15 голосов
/ 15 июня 2011

Поскольку этот вопрос возникал много раз, я думаю, что сейчас самое время предоставить некоторые рецепты того, как правильно готовить пользовательский дистрибутив для v8.

Используйте TagSet, чтобы определить для своего дистрибутива:

  1. DistributionParameterQ, DistributionParameterAssumptions, DistributionDomain
  2. Определить PDF, CDF, SurvivalFunction, HazardFunction
  3. Определить генерацию случайного числакодировать путем кодирования Random`DistributionVector

В этом случае все, кроме оценки параметров, будет работать для вашего распределения.

Ваша ошибка заключалась в том, что dplDist не имеет DistributionDomain определения, и обаnlDist и dplDist не имели DistributionParameterQ и DistributionParameterAssumptions определений.

Я добавил к вашим определениям следующее: 

dplDist /: DistributionDomain[dplDist[alpha_, beta_, mu_, sigma_]] := 
 Interval[{-Infinity, Infinity}]

nlDist /: 
 DistributionParameterQ[nlDist[alpha_, beta_, mu_, sigma_]] := ! 
  TrueQ[Not[
    Element[{alpha, beta, sigma, mu}, Reals] && alpha > 0 && 
     beta > 0 && sigma > 0]]

dplDist /: 
 DistributionParameterQ[dplDist[alpha_, beta_, mu_, sigma_]] := ! 
  TrueQ[Not[
    Element[{alpha, beta, sigma, mu}, Reals] && alpha > 0 && 
     beta > 0 && sigma > 0]]

nlDist /: 
 DistributionParameterAssumptions[
  nlDist[alpha_, beta_, mu_, sigma_]] := 
 Element[{alpha, beta, sigma, mu}, Reals] && alpha > 0 && beta > 0 && 
  sigma > 0

dplDist /: 
 DistributionParameterAssumptions[
  dplDist[alpha_, beta_, mu_, sigma_]] := 
 Element[{alpha, beta, sigma, mu}, Reals] && alpha > 0 && beta > 0 && 
  sigma > 0

И теперь это сработало: 

In[1014]:= data = RandomVariate[dplDist[3.77, 1.34, -2.65, 0.40], 100];

In[1015]:= DistributionFitTest[data, dplDist[3.77, 1.34, -2.65, 0.40],
  "HypothesisTestData"]

Out[1015]= HypothesisTestData[<<DistributionFitTest>>]
...