Общий процесс, вероятно, будет намного медленнее с более общими накладными расходами блокировки, но если вы заботитесь только о размере журнала транзакций, вы можете попробовать следующее.
- Добавить столбец с целыми числами без идентификаторов (метаданные)только изменить).
- Напишите код, чтобы обновить его уникальными последовательными целыми числами в пакетах.Это уменьшит размер каждой отдельной транзакции и уменьшит размер журнала (при условии простой модели восстановления).Мой код ниже делает это партиями по 100, надеюсь, у вас есть существующий ПК, который вы можете использовать, чтобы выбрать, где вы остановились, вместо повторных сканирований, которые будут все больше и больше дойти до конца.
- используйте
ALTER TABLE ... ALTER COLUMN, чтобы пометить столбец как NOT NULL.Это потребует, чтобы вся таблица была заблокирована и отсканирована для проверки изменений, но не требовала большого количества регистрации. - Используйте
ALTER TABLE ... SWITCH, чтобы сделать столбец идентичным столбцом.Это только метаданные изменения.
Пример кода ниже
/*Set up test table with just one column*/
CREATE TABLE table_1 ( original_column INT )
INSERT INTO table_1
SELECT DISTINCT
number
FROM master..spt_values
/*Step 1 */
ALTER TABLE table_1 ADD id INT NULL
/*Step 2 */
DECLARE @Counter INT = 0 ,
@PrevCounter INT = -1
WHILE @PrevCounter <> @Counter
BEGIN
SET @PrevCounter = @Counter;
WITH T AS ( SELECT TOP 100
* ,
ROW_NUMBER() OVER ( ORDER BY @@SPID )
+ @Counter AS new_id
FROM table_1
WHERE id IS NULL
)
UPDATE T
SET id = new_id
SET @Counter = @Counter + @@ROWCOUNT
END
BEGIN TRY;
BEGIN TRANSACTION ;
/*Step 3 */
ALTER TABLE table_1 ALTER COLUMN id INT NOT NULL
/*Step 4 */
DECLARE @TableScript NVARCHAR(MAX) = '
CREATE TABLE dbo.Destination(
original_column INT,
id INT IDENTITY(' + CAST(@Counter + 1 AS VARCHAR) + ',1)
)
ALTER TABLE dbo.table_1 SWITCH TO dbo.Destination;
'
EXEC(@TableScript)
DROP TABLE table_1 ;
EXECUTE sp_rename N'dbo.Destination', N'table_1', 'OBJECT' ;
COMMIT TRANSACTION ;
END TRY
BEGIN CATCH
IF XACT_STATE() <> 0
ROLLBACK TRANSACTION ;
PRINT ERROR_MESSAGE() ;
END CATCH ;