XSLT 1.0 конвертирует the_brown_fox в |Коричневая лиса | - PullRequest
Новая
       4

XSLT 1.0 конвертирует the_brown_fox в |Коричневая лиса |

1 голос
/ 24 июня 2011

Моя попытка: 

<xsl:template name="GetDisplay">
        <xsl:param name="input"/>
        <xsl:text>|</xsl:text>
        <xsl:call-template name="GetDisplay_1">
            <xsl:with-param name="input" select="$input"/>
        </xsl:call-template>
        <xsl:text> |</xsl:text>
    </xsl:template>

<xsl:template name="GetDisplay_1">
    <xsl:param name="input"/>
    <xsl:text> </xsl:text>
    <xsl:call-template name="GetUpper">
        <xsl:with-param name="input" select="substring($input,1,1)"/>
    </xsl:call-template>
    <xsl:variable name="head" select="substring-before($input,'_')"/>
    <xsl:choose>
        <xsl:when test="$head=''">
            <xsl:value-of select="substring($input,2)"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="substring($head,2)"/>
            <xsl:call-template name="GetDisplay_1">
                <xsl:with-param name="input" select="substring-after($input,'_')"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="GetUpper">
    <xsl:param name="input"/>
    <xsl:value-of select="translate($input,'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
</xsl:template>

Вместо необходимости использования 2 функций ( GetDisplay и GetDisplay_1 ) я хочу иметь только 1 функцию для выполнениятот же результат (мы можем оставить GetUpper без изменений, конечно).

Возможно ли это?

PS: строго XSLT 1.0 спасибо.(и без EXSLT / и т.д. спасибо)

1 Ответ

1 голос
/ 24 июня 2011

Почему бы не добавить параметр, который будет использоваться только при первом вызове? 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/test">
        <xsl:call-template name="GetDisplay_1">
            <xsl:with-param name="input" select="'the_brown_fox'"/>
            <xsl:with-param name="start" select="'start'"/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="GetDisplay_1">
        <xsl:param name="input"/>
        <xsl:param name="start" select="''"/>

        <xsl:choose>

            <xsl:when test="$start='start'">
                <xsl:text>|</xsl:text>
                <xsl:call-template name="GetDisplay_1">
                    <xsl:with-param name="input" select="$input"/>
                </xsl:call-template>
                <xsl:text> |</xsl:text>
            </xsl:when>

            <xsl:otherwise>
                <xsl:text> </xsl:text>
                <xsl:call-template name="GetUpper">
                    <xsl:with-param name="input" select="substring($input,1,1)"/>
                </xsl:call-template>
                <xsl:variable name="head" select="substring-before($input,'_')"/>

                <xsl:choose>
                    <xsl:when test="$head=''">
                        <xsl:value-of select="substring($input,2)"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="substring($head,2)"/>
                        <xsl:call-template name="GetDisplay_1">
                            <xsl:with-param name="input" select="substring-after($input,'_')"/>
                        </xsl:call-template>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:otherwise>

        </xsl:choose>
    </xsl:template>

    <xsl:template name="GetUpper">
        <xsl:param name="input"/>
        <xsl:value-of select="translate($input,'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
    </xsl:template>

</xsl:stylesheet>
...