xslt V1.0 - подшаблон с рекурсивным циклом возвращает пустое значение - PullRequest
Новая
       9

xslt V1.0 - подшаблон с рекурсивным циклом возвращает пустое значение

4 голосов
/ 28 июля 2011

Я пытаюсь получить наибольшее значение суммы дочерних элементов каждого кластера.

  • cluster1: 10 + 20 = 30

  • cluster2: 20 + 30 = 50 -> 50 - самое высокое значение

Проблема : возвращаемое значение подшаблона "".
Зачем?Переменная tempMax получает узел с моим номером в нем, а не просто числом. 

$tempMax = {Dimension:[1]}
+ [1] = /
+ + node()[1] = 50

Как я могу это исправить?(xslt v1.0).

xml: 

<?xml version="1.0"?>
<column-chart-stacked-full>
<clusters>
    <cluster number="1">
        <bar>
            <value>10</value>
        </bar>
        <bar>
            <value>20</value>
        </bar>
    </cluster>
    <cluster number="2">
        <bar>
            <value>20</value>
        </bar>
        <bar>
            <value>30</value>
        </bar>
    </cluster>
</clusters>
</column-chart-stacked-full>

my xsl: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation" xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml">

    <xsl:variable name="highestClusterVal">
        <xsl:call-template name="findMaxClusterVal"/>
    </xsl:variable>

    <xsl:template name="findMaxClusterVal">
        <xsl:param name="count" select="count(column-chart-stacked-  full/clusters/cluster)"/>
        <xsl:param name="limit" select="$count"/>
        <xsl:param name="max" select="0"/>
        <xsl:choose>
          <xsl:when test="$count &gt; 0">
            <xsl:variable name ="barSum" select="sum(column-chart-stacked-full/clusters/cluster[$count]/bar/value)"/>
            <xsl:variable name="tempMax">
              <xsl:choose>
                <xsl:when test="$max &lt; $barSum">
                  <xsl:value-of select="$barSum"/>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:value-of select="$max"/>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:variable>
            <!-- recursive loop -->
            <xsl:call-template name="findMaxClusterVal">
              <xsl:with-param name="count" select="$count - 1"/>
              <xsl:with-param name="limit" select="$limit"/>
              <xsl:with-param name="max" select="$tempMax"/>
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <!-- return max value -->
            <xsl:value-of select="$max"/>
         </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

возврат $ max 

$max = {Dimension:[1]}
+ [1] = /
+ + node()[1] = 50

1 Ответ

2 голосов
/ 29 июля 2011

Вы пропускаете противоположный случай при назначении tempMax: 

        <xsl:variable name="tempMax">
            <xsl:if test="$max &lt; $barSum">
                <xsl:value-of select="$barSum"/>
            </xsl:if>      
            <xsl:if test="$max >= $barSum">
                <xsl:value-of select="$max"/>
            </xsl:if>
        </xsl:variable>

Вот как я это проверил (изменено с помощью xsl:choose, как предложено @Mads, даже если оно логически эквивалентно).

[XSLT 1.0] Протестировано с Saxon 6.5 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <xsl:call-template name="findMaxClusterVal"/>
    </xsl:template>

    <xsl:template name="findMaxClusterVal">
        <xsl:param name="count" select="count(column-chart-stacked-full/clusters/cluster)"/>
        <xsl:param name="limit" select="$count"/>
        <xsl:param name="max" select="0"/>
        <xsl:if test="$count &gt; 0">
            <xsl:variable name ="barSum" select="sum(column-chart-stacked-full/clusters/cluster[$count]/bar/value)"/>
            <xsl:variable name="tempMax">
                <xsl:choose>
                    <xsl:when test="$max &lt; $barSum">
                        <xsl:value-of select="$barSum"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$max"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <!-- recursive loop -->
            <xsl:call-template name="findMaxClusterVal">
                <xsl:with-param name="count" select="$count - 1"/>
                <xsl:with-param name="limit" select="$limit"/>
                <xsl:with-param name="max" select="$tempMax"/>
            </xsl:call-template>
        </xsl:if>
        <!-- return max value -->
        <xsl:if test="$count = 0">
            <xsl:value-of select="$max"/>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

, примененное к вводу, указанному в вопросе, возвращает 50.

Применяется для этого измененного ввода: 

<column-chart-stacked-full>
    <clusters>
        <cluster number="1">
            <bar>
                <value>10</value>
            </bar>
            <bar>
                <value>20</value>
            </bar>
        </cluster>
        <cluster number="2">
            <bar>
                <value>20</value>
            </bar>
            <bar>
                <value>30</value>
            </bar>
        </cluster>
                <cluster number="1">
            <bar>
                <value>10</value>
            </bar>
            <bar>
                <value>20</value>
            </bar>
        </cluster>
        <cluster number="2">
            <bar>
                <value>70</value>
            </bar>
            <bar>
                <value>30</value>
            </bar>
        </cluster>
    </clusters>
</column-chart-stacked-full>

Возвращает 100.

...