AS3 Фильтр Массив Объекта - PullRequest
Новая
       5

AS3 Фильтр Массив Объекта

0 голосов
/ 11 мая 2011

У меня есть массив объектов, которые я хочу отфильтровать в зависимости от некоторых строк поиска.Я хочу создать новый массив из моего исходного массива, который будет содержать только объекты, свойства которых равны строкам в поиске: 

    var _array =  new Array();
    _array.push({name:"Ben",Title:"Mr",location:"UK"});
    _array.push({name:"Brian",Title:"Mr",location:"USA"});
    _array.push({name:"Ben",Title:"Mr",location:"USA"});

    var searchQuery:Array = new Array();
    searchQuery.push("Ben");
    searchQuery.push("Mr");

Я хочу, чтобы новый массив содержал первый и последний объект какони оба содержат строки «Ben» и «Mr».

Могу ли я использовать Array.filter для достижения этой цели?

Любая помощь приветствуется.

Ответы [ 2 ]

3 голосов
/ 11 мая 2011

Это мой подход: 

var _array:Array =  new Array();
_array.push({name:"Ben",Title:"Mr",location:"UK"});
_array.push({name:"Brian",Title:"Mr",location:"USA"});
_array.push({name:"Ben",Title:"Mr",location:"USA"});

var searchQuery:Array = new Array();
searchQuery.push("Ben");
searchQuery.push("Mr");

var resultArray:Array = _array.filter(ff); //The result.

function ff(el:*,ind:int,arr:Array){//Filter Function
    for(var i:int=0;i<searchQuery.length;i++){//Everything in searchQuery array should in el object.
        var b:Boolean = false;
        for(var s:String in el){
            if(el[s]==searchQuery[i]){
                b=true; break;
            }
        }
        if(!b) return false; //no searchQuery[i] in el... :(
    }
    return true;
}
2 голосов
/ 12 мая 2011

Ах, совсем ничего, как проблема старой доброй коллекции:)

Хотя ответ JiminP действительно правильный; это страдает от пары проблем производительности; Самым большим из которых является то, что замыкания в AS3 являются медленными , поэтому, если вы ищете по большому массиву, операция может выполняться медленно.

Следующая функция не так чиста, но даст большую производительность по сравнению с большим массивом. 

var _array : Array = [];
_array.push({name:"Ben", Title:"Mr", location:"UK"});
_array.push({name:"Brian", Title:"Mr", location:"USA"});
_array.push({name:"Ben", Title:"Mr", location:"USA"});

// I presumed you would want a little bit more control over the search matching; by
// using a Map you can ensure that no-one with the (somewhat unlikley) name of "Mr"
// gets matched by mistake.
var searchQueryMap : Dictionary = new Dictionary();
searchQueryMap["name"] = "Ben";
searchQueryMap["Title"] = "Mr";

const results : Array = [];

// Loop over earch objectin the 'haystack' that we wish to search.
for each (var object : Object in _array) 
{
    // This variable is used to break out of the loop if the current object doesn't match the
    // searchQueryMap; this gets reset to true for each loop of the supplied array.
    var match : Boolean = true;

    // Loop over each key (property) in the searchQueryMap.
    for (var key : * in searchQueryMap) 
    {
        if (searchQueryMap[key] !== object[key]) 
        {
            // No match, we can break out of looping over the searchQueryMap here.
            match = false;
            break;          
        }
    }

    // Check to see if we still have a positive match; if we do, push it onto the results Array.
    if (match) {
        results.push(object);   
    }
}

// Debug the results.
trace("Matches:");
for each (var result : Object in results)
{
    for (var prop : * in result) {
        trace("\t" + prop + " => " + result[prop]);
    }
    trace("---");
}
...