Генерация треугольника Серпинского итеративно в Mathematica?

Question

Я написал код, который рисует фрактал Серпинского.Это действительно медленно, так как использует рекурсию.Кто-нибудь из вас знает, как я могу написать один и тот же код без рекурсии, чтобы он был быстрее?Вот мой код:

 midpoint[p1_, p2_] := Mean[{p1, p2}]
 trianglesurface[A_, B_, C_] :=  Graphics[Polygon[{A, B, C}]]
 sierpinski[A_, B_, C_, 0] := trianglesurface[A, B, C]
 sierpinski[A_, B_, C_, n_Integer] :=
 Show[
 sierpinski[A, midpoint[A, B], midpoint[C, A], n - 1],
 sierpinski[B, midpoint[A, B], midpoint[B, C], n - 1],
 sierpinski[C, midpoint[C, A], midpoint[C, B], n - 1]
 ]

edit:

Я написал его с подходом Chaos Game на случай, если кому-то будет интересно.Спасибо за ваши отличные ответы!Вот код:

 random[A_, B_, C_] := Module[{a, result},
 a = RandomInteger[2];
 Which[a == 0, result = A,
 a == 1, result = B,
 a == 2, result = C]]

 Chaos[A_List, B_List, C_List, S_List, n_Integer] :=
 Module[{list},
 list = NestList[Mean[{random[A, B, C], #}] &, 
 Mean[{random[A, B, C], S}], n];
 ListPlot[list, Axes -> False, PlotStyle -> PointSize[0.001]]]

Answer 1

Используется Scale и Translate в сочетании с Nest для создания списка треугольников.

Manipulate[
  Graphics[{Nest[
    Translate[Scale[#, 1/2, {0, 0}], pts/2] &, {Polygon[pts]}, depth]}, 
   PlotRange -> {{0, 1}, {0, 1}}, PlotRangePadding -> .2],
  {{pts, {{0, 0}, {1, 0}, {1/2, 1}}}, Locator},
  {{depth, 4}, Range[7]}]

Answer 2

Вы можете попробовать

l = {{{{0, 1}, {1, 0}, {0, 0}}, 8}};
g = {};
While [l != {},
 k = l[[1, 1]];
 n = l[[1, 2]];
 l = Rest[l];
 If[n != 0,
  AppendTo[g, k];
  (AppendTo[l, {{#1, Mean[{#1, #2}], Mean[{#1, #3}]}, n - 1}] & @@ #) & /@
                                                 NestList[RotateLeft, k, 2]
  ]]
Show@Graphics[{EdgeForm[Thin], Pink,Polygon@g}]

, а затем заменить AppendTo на что-то более эффективное.См., Например, https://mathematica.stackexchange.com/questions/845/internalbag-inside-compile

Изменить

Быстрее:

f[1] = {{{0, 1}, {1, 0}, {0, 0}}, 8};
i = 1;
g = {};
While[i != 0,
 k = f[i][[1]];
 n = f[i][[2]];
 i--;
 If[n != 0,
  g = Join[g, k];
  {f[i + 1], f[i + 2], f[i + 3]} =
    ({{#1, Mean[{#1, #2}], Mean[{#1, #3}]}, n - 1} & @@ #) & /@ 
                                                 NestList[RotateLeft, k, 2];
  i = i + 3
  ]]
Show@Graphics[{EdgeForm[Thin], Pink, Polygon@g}]

Answer 3

Если вы хотите получить высококачественное приближение треугольника Серпинского, вы можете использовать подход, называемый game of chaos .Идея заключается в следующем: выберите три точки, которые вы хотите определить как вершины треугольника Серпинского, и выберите одну из этих точек случайным образом.Затем повторите следующую процедуру так долго, как вам нужно:

1. Выберите случайную вершину транла.
2. Переместитесь из текущей точки в точку на полпути между ее текущим местоположениеми эта вершина треугольника.
3. Постройте пиксель в этой точке.

Как вы можете видеть на этой анимации , эта процедура в конечном итоге отследитверсия треугольника в высоком разрешении.Если вы хотите, вы можете использовать многопоточность, чтобы несколько процессов отображали пиксели одновременно, что в конечном итоге приведет к более быстрому рисованию треугольника.

В качестве альтернативы, если вы просто хотите перевести рекурсивный код в итеративный код,Одним из вариантов будет использование подхода рабочего списка.Поддерживать стек (или очередь), который содержит коллекцию записей, каждая из которых содержит вершины треугольника и число n.Сначала включите в этот рабочий список вершины главного треугольника и глубину фрактала.Тогда:

• Пока рабочий список не пуст:
  • Удалить первый элемент из рабочего списка.
  • Если его значение n не равно нулю:
    • Нарисуйте треугольник, соединяющий середины треугольника.
    • Для каждого подтреугольника добавьте этот треугольник с n-значением n - 1 в рабочий список.

По существу, итеративно имитирует рекурсию.

Надеюсь, это поможет!

Answer 4

Так как основанные на треугольнике функции уже хорошо освещены, здесь используется растровый подход.
Это итеративно строит треугольник Паскаля, затем берет модуль 2 и выводит результат.

NestList[{0, ##} + {##, 0} & @@ # &, {1}, 511] ~Mod~ 2 // ArrayPlot

Answer 5

Clear["`*"];
sierpinski[{a_, b_, c_}] := 
  With[{ab = (a + b)/2, bc = (b + c)/2,  ca = (a + c)/2}, 
   {{a, ab, ca}, {ab, b, bc}, {ca, bc, c}}];

pts = {{0, 0}, {1, 0}, {1/2, Sqrt[3]/2}} // N;
n = 5;
d = Nest[Join @@ sierpinski /@ # &, {pts}, n]; // AbsoluteTiming
Graphics[{EdgeForm@Black, Polygon@d}]

(*sierpinski=Map[Mean, Tuples[#,2]~Partition~3 ,{2}]&;*)

Вот 3D-версия, https://mathematica.stackexchange.com/questions/22256/how-can-i-compile-this-function

ListPlot@NestList[(# + RandomChoice[{{0, 0}, {2, 0}, {1, 2}}])/2 &,
 N@{0, 0}, 10^4]

With[{data = 
   NestList[(# + RandomChoice@{{0, 0}, {1, 0}, {.5, .8}})/2 &, 
    N@{0, 0}, 10^4]}, 
 Graphics[Point[data, 
   VertexColors -> ({1, #[[1]], #[[2]]} & /@ Rescale@data)]]
 ]

With[{v = {{0, 0, 0.6}, {-0.3, -0.5, -0.2}, {-0.3, 0.5, -0.2}, {0.6, 
     0, -0.2}}}, 
 ListPointPlot3D[
  NestList[(# + RandomChoice[v])/2 &, N@{0, 0, 0}, 10^4], 
  BoxRatios -> 1, ColorFunction -> "Pastel"]
 ]