Как изменить URI пространства имен, используя xsl в запросе мыла

Question

У меня есть запрос на мыло:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"         xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd">
<soapenv:Header>
    <wsse:Security mustUnderstand="1">
        <wsse:UsernameToken>
            <wsse:Username>test</wsse:Username>
            <wsse:Password>test</wsse:Password>
        </wsse:UsernameToken>
    </wsse:Security>
</soapenv:Header>
<soapenv:Body>
  <hel:docTypeRef_tns_sayHello xmlns:hel="http://aaa/bbb.fr">
     <arg0>John</arg0>
     <arg1>111-222-333</arg1>
  </hel:docTypeRef_tns_sayHello>
</soapenv:Body>
</soapenv:Envelope>

Сначала я хотел бы изменить пространство имен, отображаемое в элементе hel: docTypeRef_tns_sayHello, на другое (например: http://test.fr). Это определение пространства имен может появиться в Элемент hel: docTypeRef_tns_sayHello, как в приведенном выше коде или в корневом элементе Envelope, поэтому я хотел бы добавить это определение пространства имен только в элемент Envelope

Тогда я бы хотел изменить значение атрибута mustUnderstand на 0.

Результат должен иметь вид:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"       xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-    1.0.xsd" 
**xmlns:hel="http://test.fr"**>
<soapenv:Header>
    <wsse:Security mustUnderstand="**0**">
        <wsse:UsernameToken>
            <wsse:Username>test</wsse:Username>
            <wsse:Password>test</wsse:Password>
        </wsse:UsernameToken>
    </wsse:Security>
</soapenv:Header>
<soapenv:Body>
  <hel:docTypeRef_tns_sayHello>
     <arg0>John</arg0>
     <arg1>111-222-333</arg1>
  </hel:docTypeRef_tns_sayHello>
</soapenv:Body>
</soapenv:Envelope>

Может ли кто-нибудь мне помочь? Спасибо!

Answer 1

I.Вот общее параметризованное решение XSLT 1.0 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pElemName" select="'hel:docTypeRef_tns_sayHello'"/>
 <xsl:param name="pOldNamespace" select="'http://aaa/bbb.fr'"/>
 <xsl:param name="pNewNamespace" select="'http://test.fr'"/>

 <xsl:variable name="vPrefix" select="substring-before($pElemName, ':')"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*">
  <xsl:choose>
      <xsl:when test=
       "not(name() = $pElemName
          and
            namespace-uri() = $pOldNamespace
           )
       ">
        <xsl:call-template name="identity"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:element name="{name()}" namespace="{$pNewNamespace}">
         <xsl:copy-of select=
           "namespace::*
                 [not(name() = $vPrefix
                    and
                      . = $pOldNamespace
                      )
                ]"/>

         <xsl:apply-templates select="@*"/>

         <xsl:apply-templates select="node()" mode="removeNS"/>
        </xsl:element>
      </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

 <xsl:template match="*" mode="removeNS">
  <xsl:choose>
   <xsl:when test=
     "not(starts-with(name(), $vPrefix)
        and
          namespace-uri() = $pOldNamespace
         )">
     <xsl:element name="{name()}" namespace="{namespace-uri()}">
         <xsl:copy-of select=
           "namespace::*
                 [not(name() = $vPrefix
                    and
                      . = $pOldNamespace
                      )
                ]"/>
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="node()" mode="removeNS"/>
     </xsl:element>
   </xsl:when>
  </xsl:choose>
 </xsl:template>

 <xsl:template match="@mustUnderstand">
  <xsl:attribute name="{name()}">0</xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к предоставленному XML-документу :

<soapenv:Envelope
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd">
    <soapenv:Header>
        <wsse:Security mustUnderstand="1">
            <wsse:UsernameToken>
                <wsse:Username>test</wsse:Username>
                <wsse:Password>test</wsse:Password>
            </wsse:UsernameToken>
        </wsse:Security>
    </soapenv:Header>
    <soapenv:Body>
        <hel:docTypeRef_tns_sayHello xmlns:hel="http://aaa/bbb.fr">
            <arg0>John</arg0>
            <arg1>111-222-333</arg1>
        </hel:docTypeRef_tns_sayHello>
    </soapenv:Body>
</soapenv:Envelope>

желаемый, правильный результат получается :

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
 xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd">
   <soapenv:Header>
      <wsse:Security mustUnderstand="0">
         <wsse:UsernameToken>
            <wsse:Username>test</wsse:Username>
            <wsse:Password>test</wsse:Password>
         </wsse:UsernameToken>
      </wsse:Security>
   </soapenv:Header>
   <soapenv:Body>
      <hel:docTypeRef_tns_sayHello xmlns:hel="http://test.fr">
         <arg0>John</arg0>
         <arg1>111-222-333</arg1>
      </hel:docTypeRef_tns_sayHello>
   </soapenv:Body>
</soapenv:Envelope>

Примечание : в XSLT 1.0 это невозможно без использования функции расширения (по крайней мере xxx:node-set())динамически добавлять новое пространство имен (которое еще не существует как узел пространства имен) к элементу.В XSLT 2.0 новая инструкция xsl:namespace может использоваться для динамического конструирования нового узла пространства имен из динамических (статически неизвестных) частей.

Вот небольшой пример того, как с XSLT 1.0 добавить новый,не существует в начале узла пространства имен преобразования :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <xsl:variable name="vrtfDoc">
   <t xmlns:hel="http://test.fr"/>
  </xsl:variable>

  <xsl:variable name="vNS" select=
   "ext:node-set($vrtfDoc)/*/namespace::*
                               [name()='hel']"/>

  <xsl:element name="{name()}"
               namespace="{namespace-uri()}">
    <xsl:copy-of select="namespace::*"/>

    <xsl:copy-of select="$vNS"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к этому документу XML :

<t xmlns:someNS="some:NS"/>

itвоссоздает верхний элемент t со всеми его узлами пространства имен и добавляет к нему один новый узел пространства имен:

<t xmlns:someNS="some:NS" xmlns:hel="http://test.fr"/>

II.Вот полное решение XSLT 2.0 :

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pElemName" select="'hel:docTypeRef_tns_sayHello'"/>
 <xsl:param name="pOldNamespace" select="'http://aaa/bbb.fr'"/>
 <xsl:param name="pNewNamespace" select="'http://test.fr'"/>

 <xsl:variable name="vPrefix" select="substring-before($pElemName, ':')"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
   <xsl:namespace name="{$vPrefix}" select="$pNewNamespace"/>

   <xsl:copy-of select=
       "namespace::*
             [not(name() = $vPrefix
                and
                  . = $pOldNamespace
                  )
              ]"/>

   <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="*">
  <xsl:choose>
      <xsl:when test=
       "not(name() = $pElemName
          and
            namespace-uri() = $pOldNamespace
           )
       ">
        <xsl:call-template name="identity"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:element name="{name()}" namespace="{$pNewNamespace}">
         <xsl:copy-of select=
           "namespace::*
                 [not(name() = $vPrefix
                    and
                      . = $pOldNamespace
                      )
                ]"/>

         <xsl:apply-templates select="@*"/>

         <xsl:apply-templates select="node()" mode="removeNS"/>
        </xsl:element>
      </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

 <xsl:template match="*" mode="removeNS">
  <xsl:choose>
   <xsl:when test=
     "not(starts-with(name(), $vPrefix)
        and
          namespace-uri() = $pOldNamespace
         )">
     <xsl:element name="{name()}" namespace="{namespace-uri()}">
         <xsl:copy-of select=
           "namespace::*
                 [not(name() = $vPrefix
                    and
                      . = $pOldNamespace
                      )
                ]"/>
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="node()" mode="removeNS"/>
     </xsl:element>
   </xsl:when>
  </xsl:choose>
 </xsl:template>

 <xsl:template match="@mustUnderstand">
  <xsl:attribute name="{name()}">0</xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к тому же XML-документу (см. Выше), получается требуемый, правильный результат :

<soapenv:Envelope xmlns:hel="http://test.fr"
                  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
                  xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd">
   <soapenv:Header>
      <wsse:Security mustUnderstand="0">
         <wsse:UsernameToken>
            <wsse:Username>test</wsse:Username>
            <wsse:Password>test</wsse:Password>
         </wsse:UsernameToken>
      </wsse:Security>
   </soapenv:Header>
   <soapenv:Body>
      <hel:docTypeRef_tns_sayHello>
         <arg0>John</arg0>
         <arg1>111-222-333</arg1>
      </hel:docTypeRef_tns_sayHello>
   </soapenv:Body>
</soapenv:Envelope>