Группировка узлов с использованием XSLT версии 1.0 - PullRequest
Новая
       1

Группировка узлов с использованием XSLT версии 1.0

1 голос
/ 31 января 2012

Мне нужна помощь по xslt, который я пишу.Ниже приведен мой источник xml. 

<document>
    <content1></content1>
    <content2></content2>
    <Br/>
    <content3></content3>
    <content4></content4>
    <Br/>
    <content5></content5>
    <content6></content6>
</document>

Вот структура вывода, который я намереваюсь создать: 

<document>
    <p>
        <content1></content1>
        <content2></content2>
    </p>
    <p>
        <content3></content3>
        <content4></content4>
    </p>
    <p>
        <content5></content5>
        <content6></content6>
    </p>
</document>

Мой вопрос: как мне сгруппировать содержимое и обернуть его вТег "

", когда я вижу тег "
"?

Спасибо!

Ответы [ 2 ]

1 голос
/ 31 января 2012

XSLT 1.0 дает ожидаемый результат: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:key name="parag" match="document/*[not(self::Br)]" use="count(following-sibling::Br)"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="document/*[not(self::Br) and not(position()=1)]"/>
    <xsl:template match="Br|document/*[position()=1]">
        <p>
            <xsl:for-each select="key('parag',count(following-sibling::Br))">
                <xsl:copy>
                    <xsl:apply-templates select="node()|@*"/>                    
                </xsl:copy>
            </xsl:for-each>
        </p>
    </xsl:template>
</xsl:stylesheet>
1 голос
/ 31 января 2012

Использование метода Мюнхена для группировки детей по document по их первому предшествующему Br: 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:key name="byPosition" match="/document/*[not(self::Br)]"
             use="generate-id(preceding-sibling::Br[1])"/>
    <xsl:template match="@*|node()" name="identity" priority="-5">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="/document/*[not(self::Br) and 
            generate-id()=generate-id(key('byPosition', 
                                generate-id(preceding-sibling::Br[1]))[1])]">
        <p><xsl:copy-of 
               select="key('byPosition', 
                            generate-id(preceding-sibling::Br[1]))"/></p>
    </xsl:template>
    <xsl:template match="/document/*" priority="-3"/>
</xsl:stylesheet>

Объяснение: Сначала элементы группируются по keyв их первом предшествующем элементе Br: 

<xsl:key name="byPosition" match="/document/*[not(self::Br)]"
         use="generate-id(preceding-sibling::Br[1])"/>

Преобразование идентичности используется для копирования большинства узлов без изменений: 

<xsl:template match="@*|node()" name="identity" priority="-5">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

Затем мы сопоставляем все дочерние элементы document, которыепервый такой элемент для их key: 

<xsl:template match="document/*[not(self::Br) and 
            generate-id()=generate-id(key('byPosition', 
                                generate-id(preceding-sibling::Br[1]))[1])]">

... и использовать его как точку, в которой можно скопировать все элементы, сгруппированные по этому key: 

<xsl:copy-of select="key('byPosition', 
                          generate-id(preceding-sibling::Br[1]))"/>
...