UDP-сервер прослушивает трансляцию

Question

Учитывая, что:
Сервер на Windows XP работает с ActiveState Perl
Сервер подключен к внутренней сети и внешней сети
Компьютер во внутренней сети передает в формате udp 10.4.255.255 через порт 9722

Мне нужно:
прослушать трансляцию и передать сообщения функции

Это код, который я использую:

my $sock;

do {
  eval {
    $sock = IO::Socket::INET->new(LocalPort => 9722, Proto => 'udp')
            or die("Couldn't open the socket: $@");
    1;
  };
  warn($@) and sleep(5) if($@);
} while ($@);

for(my $i = 0;$i &lt 20;$i++) {
  my $string = 'a';
  $sock->recv($string,1024);
  print &parseInput($string);
}

обратите внимание, что & parseInput возвращает исходную строку, в которой она была передана.

Моя проблема:
после вызова $ sock-> recv () $ string становится пустым. Используя другое приложение, я вижу, что, несомненно, есть информация, передаваемая по 10.4.255.255, но я не могу получить к ней доступ.
если это вообще возможно, я хотел бы продолжать использовать IO :: Socket :: INET.

edit: я проверил возвращаемое значение recv (..) и $ !. нет возвращаемого значения из recv (..) и $! = 'Неизвестная ошибка'.

edit 2: я пытаюсь использовать Socket; сейчас и имеют следующее:

$proto = getprotobyname('udp');
socket(SOCKET, PF_INET, SOCK_DGRAM, $proto) or die "socket: $!";
setsockopt(SOCKET, SOL_SOCKET, SO_BROADCAST, 1) or die "sockopt: $!";
bind(SOCKET, sockaddr_in(9722, inet_aton('192.168.0.103'))) or die "bind: $!";
recv(SOCKET, $msg, 128, 0) or die "recv: $!";

Выдает ошибку - recv: Unknown error at ...

Answer 1

Кажется, я обнаружил, что ты главная проблема.

Приемник должен связываться либо с любым интерфейсом (INADDR_ANY), либо с широковещательным адресом сети (либо со всеми сетями, либо с адресом).

Вот пример кода для отправителя и получателя широковещания.

При использовании setsockopt будьте внимательны! Вы должны упаковать последний аргумент.

#!/usr/bin/perl -w
# broadcast sender script
use strict;
use diagnostics;
use Socket;

my $sock;
my $receiverPort = 9722;
my $senderPort = 9721;

socket($sock, PF_INET, SOCK_DGRAM, getprotobyname('udp'))   || die "socket: $!";
setsockopt($sock, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))   || die "setsockopt: $!";
setsockopt($sock, SOL_SOCKET, SO_BROADCAST, pack("l", 1)) or die "sockopt: $!";
bind($sock, sockaddr_in($senderPort, inet_aton('192.168.2.103')))  || die "bind: $!";

while (1) {
    my $datastring = `date`;
    my $bytes = send($sock, $datastring, 0, 
                     sockaddr_in($receiverPort, inet_aton('192.168.2.255')));
    if (!defined($bytes)) { 
        print("$!\n"); 
    } else { 
        print("sent $bytes bytes\n"); 
    }
    sleep(2);
}

#!/usr/bin/perl -w
# broadcast receiver script
use strict;
use diagnostics;
use Socket;

my $sock;

socket($sock, PF_INET, SOCK_DGRAM, getprotobyname('udp'))   || die "socket: $!";
setsockopt($sock, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))   || die "setsockopt: $!";
bind($sock, sockaddr_in(9722, inet_aton('192.168.2.255')))  || die "bind: $!"; 

# just loop forever listening for packets
while (1) {
    my $datastring = '';
    my $hispaddr = recv($sock, $datastring, 64, 0); # blocking recv
    if (!defined($hispaddr)) {
        print("recv failed: $!\n");
        next;
    }
    print "$datastring";
}

Answer 2

Проверьте возвращаемое значение $sock->recv и print "$!\n". Какого рода сообщение об ошибке выводится, когда $string становится пустым? Возможно, вам придется сделать $sock->connect(...) или $sock->bind(...), прежде чем позвонить $sock->recv().