Функция Haskell, которая принимает переменную функцию в качестве аргумента (и возвращает что-то еще, кроме этой функции) без FlexibleInstances, чистый Haskell2010 - PullRequest
Новая
       27

Функция Haskell, которая принимает переменную функцию в качестве аргумента (и возвращает что-то еще, кроме этой функции) без FlexibleInstances, чистый Haskell2010

11 голосов
/ 04 декабря 2011

можно ли выразить следующую программу на Haskell без FlexibleInstances , то есть в чистом Haskell2010? 

{-# LANGUAGE FlexibleInstances #-}

class    Funk a       where  truth :: a  -> [Bool]
instance Funk [Bool]  where  truth =  \x ->  x
instance Funk Bool    where  truth =  \x -> [x]

instance Funk b => Funk (Bool -> b) where
    truth f = concat [truth (f True), truth (f False)]

Это вдохновлено ответом на Как написать Haskellфункция, которая принимает переменную функцию в качестве аргумента .

Я подозреваю, что проблема в том, что truth возвращает что-то другое, чем функция, которую она принимает в качестве аргумента (которая возвращает Bool, а не [Bool]).

Цель этого фрагмента - дать список всех оценок всех возможных конфигураций для булевой функции, т. Е. 

Main> truth (\x y -> x && y)
[True,False,False,False]

Main> truth (\x y -> x || y)
[True,True,True,False]

В конце концов,таблица должна быть напечатана следующим образом (см. примерную таблицу в конце этого поста, чтобы увидеть код, который ее производит): 

Main> main
T T T | T
T T F | T
T F T | T
T F F | F
F T T | T
F T F | F
F F T | T
F F F | T

Вот некоторый код типовой части для тестирования и визуализации, чтоНазначение этой функции: 

class TruthTable a where
    truthTable :: Funk f => f -> a

instance TruthTable [String] where
    truthTable f = zipWith (++) (hCells (div (length t) 2)) (map showBool $ truth f)
        where
            showBool True = "| T"
            showBool False = "| F"
            hCells 1 = ["T ", "F "]
            hCells n = ["T " ++ x | x <- hCells (div n 2)] ++ ["F " ++ x | x <- hCells (div n 2)]

instance TruthTable [Char] where
    truthTable f = foldl1 join (truthTable f)
        where join a b = a ++ "\n" ++ b

instance TruthTable (IO a) where
    truthTable f = putStrLn (truthTable f) >> return undefined

main :: IO ()
main = truthTable (\x y z -> x `xor` y ==> z)

xor :: Bool -> Bool -> Bool
xor a b = not $ a == b

(==>) :: Bool -> Bool -> Bool
a ==> b = not $ a && not b

Ответы [ 2 ]

12 голосов
/ 04 декабря 2011

Нет проблем: 

class    Funk a                  where  truth :: a  -> [Bool]
instance (IsBool a) => Funk [a]  where  truth =  map toBool
instance Funk Bool               where  truth =  \x -> [x]

instance (IsBool a, Funk b) => Funk (a -> b) where
    truth f = concat [truth (f $ fromBool True), truth (f $ fromBool False)]

class IsBool a where
    toBool :: a -> Bool
    fromBool :: Bool -> a

instance IsBool Bool where
    toBool = id
    fromBool = id

Вы можете даже сделать «почетные логические значения», если хотите, например, Integer с 0 и 1 и т. Д.

1 голос
/ 04 декабря 2011

Способ Haskell98 - использовать новые типы для ([] Bool) и ((->) Bool b): 

newtype LB = LB [Bool]
newtype FAB b = FAB (Bool -> b)

class    Funk a       where  truth :: a  -> [Bool]
instance Funk LB      where  truth =  \(LB x) -> x
instance Funk Bool    where  truth =  \x -> [x]

instance Funk b => Funk (FAB b) where
    truth (FAB f) = concat [truth (f True), truth (f False)]

Эта часть затем компилируется без каких-либо расширений ЯЗЫКА. Но это исключает случай использования упрощения работы с «правдой».

...