GHC выбирает разные экземпляры для одного и того же выражения? - PullRequest
Новая
       35

GHC выбирает разные экземпляры для одного и того же выражения?

2 голосов
/ 13 июля 2011

Я хочу реализовать стрелку с функцией-члена arr, показывающей другое поведение аргументов функции с разными типами, например, arr (\x -> (x,x)) должен вести себя иначе, чем arr id ...

Вот код: 

{-# LANGUAGE Arrows, OverlappingInstances, IncoherentInstances, FlexibleInstances#-}
import Control.Arrow
import Control.Category 
import Prelude hiding (id, (.))

class ToPredefinedStr a where
  toStr :: a -> String


instance ToPredefinedStr ((->) b (b,b)) where
  toStr _ = "b -> (b,b)"

instance ToPredefinedStr (a -> (b,c)) where
  toStr _ = "a -> (b,c)" 

instance ToPredefinedStr ((a,b) -> c) where
  toStr _ = "(a,b) -> c"

instance ToPredefinedStr (a -> b) where 
  toStr _ = "a -> b"

newtype MyArrow a b c = MA (a b (c, String))

instance (Category a, Arrow a) => Category (MyArrow a) where
    -- irrelevant for this example ...

instance (Arrow a) => Arrow (MyArrow a) where
    arr f        = MA (arr (\x -> (f x, toStr f)))

appMyArr (MA a) = a

Но: он показывает следующее очень странное поведение: 

> toStr (\x -> (x,x)) -- that works as expected!
"b -> (b,b)" 
> appMyArr (arr (\x -> (x,x))) () -- but this does'nt!!
(((),()),"a -> b")

Может кто-нибудь объяснить, как заставить ghci выбрать b -> (b,b) -экземпляр для выражения \x -> (x,x) во втором примере?

Ответы [ 2 ]

10 голосов
/ 13 июля 2011

Если вы используете IncoherentInstances, все может произойти. Больше нет никаких обещаний, что экземпляры будут выбраны последовательным образом.

6 голосов
/ 13 июля 2011

Краткий ответ: это происходит потому, что компилятор имеет доступ к более конкретной информации о типах в первом случае, чем во втором.

При компиляции вашего определения arr компилятор видит только тип аргумента функции f как b -> c, поэтому при рассмотрении вызова toStr f он должен выбрать экземпляр на основе только этой информации. В конце концов, arr может быть вызван с любой функцией. Понятно, что выбирать можно только instance ToPredefinedStr (a -> b).

Теперь, когда мы встроим его, как в toStr (\b -> (b, b)), компилятор имеет больше информации, доступной на сайте вызовов, и может выбрать более конкретный экземпляр.

И нет, использование INLINE прагм не изменит выбор экземпляра, если вы об этом думаете.

Для того, что вы пытаетесь достичь, самое близкое, что я могу придумать, это ограничить типы так, чтобы выбор экземпляра происходил снаружи arr: 

{-# LANGUAGE FlexibleContexts, ... #-}

class FancyArrow a where
    myArr :: (ToPredefinedStr (b -> c)) => (b -> c) -> a b c 
    ...

instance (Arrow a) => FancyArrow (MyArrow a) where
    myArr f        = MA (arr (\x -> (f x, toStr f)))

Это дает желаемый результат. 

*Main> appMyArr (myArr (\x -> (x,x))) ()
(((),()),"b -> (b,b)")

Обратите внимание, что это несколько хрупко, так как вы должны контролировать, где делается выбор экземпляра, распространяя ограничение ToPredefinedStr. Например, эта функция молча меняет поведение, если вы удаляете сигнатуру типа. 

foo :: (Arrow a, ToPredefinedStr (b -> c)) => (b -> c) -> a b (c, String)
foo f = appMyArr (myArr f)
...