Это XSLT неэффективно?

Question

Я получил ответ от моего последнего вопроса о переводе XML-файла , и это вдохновило меня поиграть с ним. Я придумал другое решение, но у меня есть ощущение, что два последних выбора неоптимальны. Можно ли сделать это лучше или эффективнее?

Таблица стилей:

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="pFrom" select="'en'"/>
  <xsl:param name="pTo" select="'de'"/>


  <xsl:variable name="translations" select="document('translations.xml')"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@name">
    <xsl:variable name="thisname" select="." />

    <xsl:variable name="entry" select="$translations/translations/entry[attribute::node()[name()=$pFrom and $thisname=.]]"></xsl:variable>
    <xsl:attribute name="name" select="$entry/attribute::node()[local-name() = $pTo]"></xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

Источник:

<?xml version="1.0" encoding="UTF-8"?>
<grammar>
  <element name="table" />
  <element name="chair" />
</grammar>

И файл перевода (translations.xml):

<?xml version="1.0" encoding="UTF-8"?>
<translations>
    <entry en="table" de="Tisch" fr="Table" />
    <entry en="chair" de="Stuhl" fr="Chaise"/>
</translations>

Результат:

<grammar>
   <element name="Tisch"/>
   <element name="Stuhl"/>
</grammar>

Пример: когда я иду от 'en' к 'de' и нахожусь у первого name атрибута ('table') в исходном файле, я просматриваю файл переводов для en entry, где en = " table "и выберите для имени атрибут" de ".

Answer 1

Используйте ключи:

<xsl:key name="en" match="translations/entry" use="@en"/>
<xsl:key name="de" match="translations/entry" use="@de"/>
<xsl:key name="fr" match="translations/entry" use="@fr"/>

, а затем

  <xsl:template match="@name">
    <xsl:attribute name="name" select="key($pFrom, current(), $translatations)/@*[local-name() = $pTo]"/>
  </xsl:template>

(я полагаю, вы используете XSLT 2.0).