GLSL интерполяционный цветной тесселяционный шейдер - PullRequest
Новая
       52

GLSL интерполяционный цветной тесселяционный шейдер

0 голосов
/ 11 ноября 2011

мой тесселяционный шейдер генерирует кривую Безье для двух вершин.вершины состоят из двух координат x и y (vec2).теперь у каждой вершины есть цвет.мой вопрос: как интерполировать цвет на вершину на сгенерированной кривой?прямо сейчас фрагментный шейдер устанавливает значение цвета по умолчанию (красный).но я хочу, чтобы он получил интерполированный цвет.

, например: 

vertex 1 [vec2(0.0, 0.0), vec4(1.0, 0.0, 0.0, 1.0)] // red
vertex 2 [vec2(1.0, 1.0), vec4(0.0, 1.0, 0.0, 1.0)] // blue

, поэтому должен быть градиент от красного к синему.Как я могу сделать это с помощью тесселяционного шейдера?

Вершинный шейдер: 

#version 400

layout (location = 0 ) in vec2 in_position;
layout (location = 1 ) in vec4 in_color;

void main()
{
    gl_Position = vec4(in_position, 0.0, 1.0);
}

Шейдер управления тесселяцией: 

#version 400

layout( vertices = 2 ) out;

uniform int NumSegments;
uniform int NumStrips;

void main()
{
    gl_out[gl_InvocationID].gl_Position = gl_in[gl_InvocationID].gl_Position;

    gl_TessLevelOuter[0] = float(NumSegments);
    gl_TessLevelOuter[1] = float(NumStrips);
}

шейдер оценки тесселяции: 

#version 400

layout( isolines ) in;

uniform mat4 Projection;
uniform mat4 Modelview;

void main()
{
    float u = gl_TessCoord.x;

    vec3 p0 = gl_in[0].gl_Position.xyz;
    vec3 p1 = vec3(0.5, gl_in[0].gl_Position.y, 0.0);
    vec3 p2 = vec3(0.5, gl_in[1].gl_Position.y, 0.0);
    vec3 p3 = gl_in[1].gl_Position.xyz;

    float u1 = (1.0 - u);
    float u2 = u * u;

    // Bernstein polynomials
    float b3 = u2 * u;
    float b2 = 3.0 * u2 * u1;
    float b1 = 3.0 * u * u1 * u1;
    float b0 = u1 * u1 * u1;

    // Cubic Bezier interpolation
    vec3 p = p0 * b0 + p1 * b1 + p2 * b2 + p3 * b3;

    gl_Position = Projection * Modelview * vec4(p, 1.0);
}

фрагментный шейдер: 

#version 400

layout ( location = 0 ) out vec4 FragColor;

void main()
{
  FragColor = vec4(1.0, 0.0, 0.0, 1.0);
}

1 Ответ

1 голос
/ 06 марта 2012

Это все довольно просто. Просто следуйте схеме ваших уже существующих входов и выходов.

Ваш вершинный шейдер выводит значение gl_Position. Поэтому следует также вывести значение цвета: 

layout (location = 0 ) in vec2 in_position;
layout (location = 1 ) in vec4 in_color;

out vec4 color;

void main()
{
    gl_Position = vec4(in_position, 0.0, 1.0);
    color = in_color;
}

Ваш шейдер управления тесселяцией принимает массив gl_Position с. Итак, вы берете множество цветов. Также необходимо записать в массив цветов: 

layout( vertices = 2 ) out;

uniform int NumSegments;
uniform int NumStrips;

in vec4 color[];

out Tess
{
  vec4 color;
} Out[];

void main()
{
    gl_out[gl_InvocationID].gl_Position = gl_in[gl_InvocationID].gl_Position;
    Out[gl_InvocationID].color = color[gl_InvocationID];

    gl_TessLevelOuter[0] = float(NumSegments);
    gl_TessLevelOuter[1] = float(NumStrips);
}

В вашем оценочном шейдере вам снова нужно взять массив входных и выходных квалификаторов макета. Мы использовали выходной интерфейсный блок с именем Tess, поэтому нам нужно сопоставить его с входным интерфейсным блоком с тем же именем: 

layout( isolines ) in;

uniform mat4 Projection;
uniform mat4 Modelview;

in Tess
{
  vec4 color;
} In[];

out vec4 color;

void main()
{
    float u = gl_TessCoord.x;

    /** Do whatever interpolation stuff you do **/

    // Cubic Bezier interpolation
    vec3 p = p0 * b0 + p1 * b1 + p2 * b2 + p3 * b3;

    gl_Position = Projection * Modelview * vec4(p, 1.0);
    color = Interpolate(In[0].color, In[1].color, ...); //More interpolation stuff.
}

И это все. Ваш фрагментный шейдер принимает в качестве входных данных vec4 color.

Кроме того, небольшое примечание: это не сплайн Безье. Для сплайнов Безье требуются патчи из 4 позиций, а не 2. То, как вы синтезировали два других значения, не делает их правильными.

...