Firemonkey и TDownloadUrl

Question

У меня есть приложение (Delphi XE2) VCL, содержащее объект TDownloadUrl (VCL.ExtActns) для проверки нескольких веб-страниц, поэтому мне интересно, есть ли в FireMonkey эквивалентный объект, потому что я хочу воспользоваться богатыми возможностями этого нового Платформа.

Демонстрация приложения Firemonkey с использованием потоков была бы признательна. Заранее спасибо.

Answer 1

Относительно этого:

Демонстрация приложения Firemonkey с использованием потоков будет признательна.

Вы можете найти демоверсию FireMonkey, которая использует Thread здесь: https://radstudiodemos.svn.sourceforge.net/svnroot/radstudiodemos/branches/RadStudio_XE2/FireMonkey/FireFlow/MainForm.pas

type

  TImageThread = class(TThread)
  private
    FImage: TImage;
    FTempBitmap: TBitmap;
    FFileName: string;
  protected
    procedure Execute; override;
    procedure Finished;
  public
    constructor Create(const AImage: TImage; const AFileName: string);
    destructor Destroy; override;
  end;

...

TImageThread.Create(Image, Image.TagString).Start;

если у вас нет этой демонстрации в вашем каталоге с примерами, вы можете проверить ее из репозитория subversion, использованного по ссылке выше.

Answer 2

Действия еще не существуют с FireMonkey.

Кстати, вы можете создать такое же поведение с помощью кода, подобного следующему:

IdHTTP1: TIdHTTP;

...

procedure TForm2.MenuItem1Click(Sender: TObject);
const
  FILENAME = 'C:\Users\Whiler\Desktop\test.htm';
  URL      = '/8005023/firemonkey-i-tdownloadurl';
var
//  sSource: string;
  fsSource: TFileStream;
begin
  if FileExists(FILENAME) then
  begin
    fsSource := TFileStream.Create(FILENAME, fmOpenWrite);
  end
  else
  begin
    fsSource := TFileStream.Create(FILENAME, fmCreate);
  end;

  try
    IdHTTP1.Get(URL, fsSource);
  finally
    fsSource.Free;
  end;
//  sSource := IdHTTP1.Get(URL);
end;

Закомментированные строки могут заменить другие, если вам просто нужен источник в памяти ...

---

---

Если вы хотите использовать поток, вы можете управлять им следующим образом:

unit Unit2;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdHTTP, FMX.Menus;

type
  TDownloadThread = class(TThread)
  private
    idDownloader: TIdHTTP;
    FFileName   : string;
    FURL        : string;
  protected
    procedure Execute; override;
    procedure Finished;
  public
    constructor Create(const sURL: string; const sFileName: string);
    destructor  Destroy; override;
  end;
type
  TForm2 = class(TForm)
    MenuBar1: TMenuBar;
    MenuItem1: TMenuItem;
    procedure MenuItem1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.fmx}

procedure TForm2.MenuItem1Click(Sender: TObject);
const
  FILENAME = 'C:\Users\Whiler\Desktop\test.htm';
  URL      = '/8005023/firemonkey-i-tdownloadurl';
var
//  sSource: string;
  fsSource: TFileStream;
begin
  TDownloadThread.Create(URL, FILENAME).Start;
end;

{ TDownloadThread }

constructor TDownloadThread.Create(const sURL, sFileName: string);
begin
  inherited Create(true);
  idDownloader := TIdHTTP.Create(nil);
  FFileName       := sFileName;
  FURL            := sURL;
  FreeOnTerminate := True;
end;

destructor TDownloadThread.Destroy;
begin
  idDownloader.Free;
  inherited;
end;

procedure TDownloadThread.Execute;
var
//  sSource: string;
  fsSource: TFileStream;
begin
  inherited;
  if FileExists(FFileName) then
  begin
    fsSource := TFileStream.Create(FFileName, fmOpenWrite);
  end
  else
  begin
    fsSource := TFileStream.Create(FFileName, fmCreate);
  end;

  try
    idDownloader.Get(FURL, fsSource);
  finally
    fsSource.Free;
  end;
  Synchronize(Finished);
end;

procedure TDownloadThread.Finished;
begin
  // replace by whatever you need
  ShowMessage(FURL + ' has been downloaded!');
end;

end.

Answer 3

Вы можете использовать этот код.

unit BitmapHelperClass;

interface

uses
  System.Classes, FMX.Graphics;

type
  TBitmapHelper = class helper for TBitmap
  public
    procedure LoadFromUrl(AUrl: string);

    procedure LoadThumbnailFromUrl(AUrl: string; const AFitWidth, AFitHeight: Integer);
  end;

implementation

uses
  System.SysUtils, System.Types, IdHttp, IdTCPClient, AnonThread;

procedure TBitmapHelper.LoadFromUrl(AUrl: string);
var
  _Thread: TAnonymousThread<TMemoryStream>;
begin
  _Thread := TAnonymousThread<TMemoryStream>.Create(
    function: TMemoryStream
    var
      Http: TIdHttp;
    begin
      Result := TMemoryStream.Create;
      Http := TIdHttp.Create(nil);
      try
        try
          Http.Get(AUrl, Result);
        except
          Result.Free;
        end;
      finally
        Http.Free;
      end;
    end,
    procedure(AResult: TMemoryStream)
    begin
      if AResult.Size > 0 then
        LoadFromStream(AResult);
      AResult.Free;
    end,
    procedure(AException: Exception)
    begin
    end
  );
end;

procedure TBitmapHelper.LoadThumbnailFromUrl(AUrl: string; const AFitWidth,
  AFitHeight: Integer);
var
  Bitmap: TBitmap;
  scale: Single;
begin
  LoadFromUrl(AUrl);
  scale := RectF(0, 0, Width, Height).Fit(RectF(0, 0, AFitWidth, AFitHeight));
  Bitmap := CreateThumbnail(Round(Width / scale), Round(Height / scale));
  try
    Assign(Bitmap);
  finally
    Bitmap.Free;
  end;
end;

end.