Flex / AS3 - кто-нибудь знает, как взять список отображения AS3 и создать из него mxml?

Question

Я боролся с тем, как я могу создать mxml из списка отображения, созданного в приложении. Например, создайте несколько компонентов на холсте, затем нажмите кнопку, чтобы получить отформатированный документ XML в формате mxml холста и его свойств.

Есть ли простой способ для этого?

Большое спасибо за любую помощь ...

Answer 1

Для этого точно не существует простого метода.

Редактировать : Причиной этого является то, что mxml фактически транслируется в actionScript, а затем компилируется. Итак, flash player абсолютно ничего не знает о mxml и его существовании.

Answer 2

Это помогло бы узнать немного больше об этом, например, зачем вам это нужно делать. Насколько я знаю, нет простого или встроенного способа сделать это.

Вот направление, которое может помочь:

• Встраивать файлы шаблонов PlainText mxml для каждого типа объекта DisplayObject, который будет поддерживать ваше приложение. (файлы шаблонов, где каждое свойство имеет переменную, которую нужно поменять с интерполяцией строки, например: mx: HRule height = "{$ hRuleHeight}" width = "$ {hRuleWidth}" /

• Каждый раз, когда объект редактируется / создается, сохраняйте информацию - когда придет время сгенерировать mxml для каждого сохраненного элемента, взять свойства и проанализировать шаблоны с ними. AS3 не поддерживает интерполяцию строк, ниже приведена реализация, если у вас ее нет.

использование:

        var example:StringInterpolation=new StringInterpolation();

        example.setKeyAndValue('${id}','foo');
        example.setKeyAndValue('${baseurl}','http://testing123');

        trace(example.eval('<table width="480" border="0" cellpadding="0" cellspacing="0"><tr><td colspan="3"><object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=8,0,0,0" width="480" height="270"><param name="movie" value="http://testing123/player/Take180Player.swf?xmlLocation=/s/bx/http://testing123}&links=true" />'));


 /*outputs:<table width="480" border="0" cellpadding="0" cellspacing="0"><tr><td colspan="3"><object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=8,0,0,0" width="480" height="270"><param name="movie" value="http://testing123/player/Take180Player.swf?xmlLocation=/s/bx/http://testing123&links=true" /> */

ЦСИ:

//

package com.philipbroadway.utils
{
    public class StringInterpolation extends Object
    {
        internal var _keys:Array;
        internal var _values:Array;
        internal var _result:String;
        internal var i:uint;

        /**
         * 
         * 
         */        
        public function StringInterpolation()
        {
            _keys=[];
            _values=[];    
        }





        /**
         * 
         * @param key:String a variable name
         * @param value:String a value to replace when the key is found during eval
         * 
         */        
        public function setKeyAndValue(key:String,value:String):void
        {
            var metacharacters:Array=[];
            metacharacters.push(new RegExp(/\$/));
            metacharacters.push(new RegExp(/\{/));
            metacharacters.push(new RegExp(/\}/));
            metacharacters.push(new RegExp(/\^/));
            metacharacters.push(new RegExp(/\./));
            metacharacters.push(new RegExp(/\*/));
            metacharacters.push(new RegExp(/\+/));

            var replacements:Array=[];
            replacements.push(new String('\\$'));
            replacements.push(new String('\\{'));
            replacements.push(new String('\\}'));
            replacements.push(new String('\\^'));
            replacements.push(new String('\\.'));
            replacements.push(new String('\\*'));
            replacements.push(new String('\\+'));

            for(i=0;i<metacharacters.length;i++)
            {
                key=key.replace(metacharacters[i],replacements[i]);
            }
            _keys.push(key);
            _values.push(value);
        }





        /**
         * 
         * @param value:String to be interpolated
         * @return String interpolated
         * 
         */        
        public function eval(value:String):String
        {
            _result=value;
            for(i=0;i<_keys.length;i++)
            {
                var regEx:RegExp=new RegExp(_keys[i],'g');
                _result=_result.replace(regEx,_values[i]);
            }

            return _result;
        }




        /**
         * 
         * 
         */        
        public  function reset():void
        {
            _keys=[];
            _values=[];                
        }
    }
}