Добавить столбец различий в таблицы сводной статистики в Stata - PullRequest
Новая
       20

Добавить столбец различий в таблицы сводной статистики в Stata

1 голос
/ 21 сентября 2011

Если я создаю таблицу двусторонней сводной статистики в Stata, используя table, могу ли я добавить еще один столбец, в котором разница двух других столбцов?

Скажите, что у меня есть трипеременные (a, b, c).Я генерирую квинтили на a и b, затем генерирую двустороннюю таблицу средних c в каждом пересечении квинтиль-квинтиль.Я хотел бы сгенерировать шестой столбец, который представляет собой разность среднего c между верхним и нижним квинтилями b для каждого квинтиля a.

Я могу сгенерировать таблицу среднего c для каждого пересечения квинтиль-квинтиль, но я не могу понять столбец различий.

* generate data
clear
set obs 2000
generate a = rnormal()
generate b = rnormal()
generate c = rnormal()

* generate quantiles for for a and b
xtile a_q = a, nquantiles(5)
xtile b_q = b, nquantiles(5)

* calculate the means of each quintile intersection
table a_q b_q, c(mean c)

* if I want the top and bottom b quantiles
table a_q b_q if b_q == 1 | b_q == 5, c(mean c)

Обновление : Вот пример того, что я хотел бы сделать. enter image description here

1 Ответ

1 голос
/ 21 сентября 2011

С помощью команды collapse вы можете создавать настраиваемые таблицы, подобные той, которую вы имеете в виду. 

preserve
collapse (mean) c, by(a_q b_q)
keep if inlist(b_q, 1, 5)
reshape wide c, i(a_q) j(b_q)
gen c5_c1 = c5 - c1
set obs `=_N + 1'
replace c1 = c1[`=_N - 1'] - c1[1] if mi(a_q)
replace c5 = c5[`=_N - 1'] - c5[1] if mi(a_q)
replace c5_c1 = c5_c1[`=_N - 1'] - c5_c1[1] if mi(a_q)
list, sep(0) noobs
restore

Затем вы должны получить что-то подобное в своем выводе: 

  +-----------------------------------------+
  | a_q          c1          c5       c5_c1 |
  |-----------------------------------------|
  |   1    .2092651    .1837719   -.0254932 |
  |   2    .0256483   -.0118134   -.0374617 |
  |   3     .022957    .0586441    .0356871 |
  |   4    .0431809    .0876745    .0444935 |
  |   5   -.0859874    .0199202    .1059076 |
  |   .   -.2952525   -.1638517    .1314008 |
  +-----------------------------------------+

Если вы не очень знакомы со Stata, следующие страницы справки могут быть полезны для понимания кода 

help _variables
help subscripting
...