Пакетный сценарий даты в переменную

Question

for /F "tokens=1-4 delims=/ " %%i in ('date /t') do (
set Day=%%k
set Month=%%j
set Year=%%l
set DATE=%%k/%%j/%%l)

Я пытаюсь получить дату в вышеуказанные переменные в пакетном скрипте, но в настоящее время дата выглядит как

2011/04/

Есть предложения о том, как это исправить?

Answer 1

Вы не получите того, что ожидали, потому что %DATE% возвращает текущую дату, используя настройки Windows для «короткого формата даты». Этот параметр полностью (бесконечно) настраивается.

Один пользователь может настроить свою систему для отображения короткой даты как Fri040811; в то время как другой пользователь (даже в той же системе) может выбрать 08/04/2011. Это полный кошмар для программиста на BAT.

Одним из возможных решений является использование WMIC . WMIC - это интерфейс командной строки WMI для WMI. WMI Инструментарий управления Windows является http://en.wikipedia.org/wiki/Windows_Management_Instrumentation

WMIC Path Win32_LocalTime Get Day,Hour,Minute,Month,Second,Year /Format:table

возвращает дату удобным способом, чтобы непосредственно проанализировать ее с FOR.

Завершение разбора и сборка частей

 FOR /F "skip=1 tokens=1-6" %%A IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    SET /A TODAY=%%F*10000+%%D*100+%%A
 )

Answer 2

Я получил самое короткое из уже приведенных решений.Это работает на любой системе (XP Pro и выше):

REM ===================================================================
REM CREATE UNIQUE DATETIME STRING IN FORMAT YYYYMMDD-HHMMSS
REM ======================================================================
FOR /f %%a IN ('WMIC OS GET LocalDateTime ^| FIND "."') DO SET DTS=%%a
SET DateTime=%DTS:~0,8%-%DTS:~8,6%
REM ======================================================================

Конечно, вы можете играть с полученным форматом строки.

Answer 3

Я думаю, это то, что вы хотите

@echo off
:MENU
CLS
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set xsukax=%%a
echo Year=%xsukax:~0,4%
echo Month=%xsukax:~4,2%
echo Day=%xsukax:~6,2%
echo hour=%xsukax:~8,2%
echo Minutes=%xsukax:~10,2%
echo seconds=%xsukax:~12,2%

pause
goto MENU

Answer 4

Это то, что я бы использовал в XP Pro и выше. XP Home не имеет wmic.

:: timestamp YYYYMMDD_HHMMSS
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set dt=%dt:~0,8%_%dt:~8,6%
echo %dt%
pause

и еще

:: timestamp YYYY-MM-DD_HH-MM-SS
@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set dt=%dt:~0,4%-%dt:~4,2%-%dt:~6,2%_%dt:~8,2%-%dt:~10,2%-%dt:~12,2%
echo %dt%
pause

Answer 5

Не стесняйтесь использовать это как хотите

:: Date in year, day, month format

FOR /f "tokens=2-4 skip=1 delims=(-)" %%G IN ('echo.^|date') DO (
    FOR /f "tokens=2 delims= " %%A IN ('date /t') DO (
        SET v_first=%%G
        SET v_second=%%H
        SET v_third=%%I
        SET v_all=%%A
        )
    )

SET %v_first%=%v_all:~0,2%
SET %v_second%=%v_all:~3,2%
SET %v_third%=%v_all:~6,4%
SET DATE2= %MM%_%DD%_%YY%
ECHO. The date is: %DATE2%

Answer 6

Следующий скрипт даст местное время с информацией о часовом поясе (TZ), как в истинном ISO8601, так и в человеческом формате (без 'T').Он конвертирует смещение TZ в минутах в необходимый формат ЧЧММ, например, 2019-01-25T08:26:55.347+1300 и 2019-01-25 08:26:55.347+1300 для NZ с DST.

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ccyy_mm_dd=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2%
set hh_mm_ss=%ldt:~8,2%:%ldt:~10,2%:%ldt:~12,2%
set _fff=%ldt:~14,4%
set tzsign=%ldt:~21,1%
set tzmins=%ldt:~22%
set /a tzHH=(%tzmins%/60)
set /a tzMM=(%tzmins%-(%tzHH%*60))
set /a tzHH=100 + %tzHH%
set tzHH=%tzHH:~1,2%
set /a tzMM=100 + %tzMM%
set tzMM=%tzMM:~1,2%
set ldt=%ccyy_mm_dd% %hh_mm_ss%%_fff%%tzsign%%tzHH%%tzMM%
set ldt8601=%ccyy_mm_dd%T%hh_mm_ss%%_fff%%tzsign%%tzHH%%tzMM%
echo %ldt%
echo %ldt8601%

Возможно, вы хотите удалить одну из команд эха

РЕДАКТИРОВАТЬ для тех, кто хотел двоеточие в TZ, измените %tzHH%%tzMM% на %tzHH%:%tzMM%

Answer 7

for /f %%a in ('wmic os get localdatetime ^| find "."') do set dts=%%a
set ymd=%dts:~0,8%
set hour=%dts:~8,6%

Answer 8

Не могли бы вы просто использовать следующую 1 строку для создания вашей переменной (используя любое имя переменной)?

set ymd=%date:~6,4%/%date:~0,2%/%date:~3,2%