XSLT для замены атрибута в элементе XML, если он существует в другом XML? - PullRequest
Новая
       20

XSLT для замены атрибута в элементе XML, если он существует в другом XML?

3 голосов
/ 09 августа 2011

У меня 2 файла

catalog.xml 

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="unknown"/>
</catalog>

vinyl.xml 

<?xml version="1.0" encoding="UTF-8"?>
<Vinyl>
    <Album>
        <Title>When a man loves a woman</Title>
        <Vinyl>Yes</Vinyl>
    </Album>
</Vinyl>

Как создать такой файл output.xml с помощью xslt? 

<?xml version="1.0" encoding="UTF-8"?>
<catalog>
    <CD Title="Still got the blues" vinyl="unknown"/>
    <CD Title="When a man loves a woman" vinyl="yes"/>***   
</catalog>

*** отметьте эту строку, потому что она изменилась в output.xml

1 Ответ

4 голосов
/ 09 августа 2011

В следующем преобразовании используется catalog.xml в качестве входных данных и загружается vinyl.xml с использованием document(). Он выполняет слияние, просто выполняя простой тест.

[XSLT 1.0] 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:variable name="vinyl" select="document('test_i2.xml')"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@vinyl">
        <xsl:attribute name="vinyl">
            <xsl:variable name="test" select="
                 $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl"/>
            <xsl:choose>
                <xsl:when test="$test">
                    <xsl:value-of select="$test"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="."/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

Этот шаблон для атрибута менее непосредственный, но он использует чистый XPath: 

<xsl:template match="@vinyl">
    <xsl:attribute name="vinyl">
        <xsl:value-of select="
          $vinyl/Vinyl/Album[Title=current()/../@Title]/Vinyl
          |
          self::node()[count($vinyl/Vinyl/Album[Title=current()/../@Title])=0]"/>
    </xsl:attribute>
</xsl:template>
...