Beckhoff - Построить запрос по результатам другого запроса - PullRequest
Новая
       25

Beckhoff - Построить запрос по результатам другого запроса

0 голосов
/ 10 апреля 2019

Я хочу построить оператор SELECT из результатов запроса в среде ПЛК Twicat3.

Запрос выполняется правильно, когда переменная жестко запрограммирована, но не выполняется, когда переменная передается из результатов другого запроса.Определенные типы данных одинаковы.Ошибка в представлении InformationLog указывает на то, что «данный ключ отсутствует в словаре».когда запрос выполняется с использованием результатов первого запроса. 

PROGRAM MAIN
VAR
conv_QueryDB    : Query_tblConveyorQueue;
conv_queryRes   : ARRAY [0..9] OF tblConveyorQueue;
conv_str_query  : STRING(2000);
conv_query      : WSTRING(2000);
conv_query1     : WSTRING(255) := "SELECT TOP 1 LEFT(AreaID,5) FROM ConveyorQueue WHERE CartonID = '";
conv_barcode    : WSTRING(255) := "900981-1";
conv_query2 : WSTRING(255) := "' ORDER BY AreaID";

zone_QueryDB    : Query_tblZoneMap;
zone_queryRes   : ARRAY [0..18] OF tblZoneMap;
zone_str_query  : STRING(2000);
zone_query  : WSTRING(2000);
zone_query1 : WSTRING(255) := "SELECT transfer, zone, direction, neighborZone, deliveryLoc FROM tblZoneMap WHERE transfer = 1 AND zone = 0 AND deliveryLoc = '";
zone_dest       : WSTRING(255);
zone_query2 : WSTRING(255) := "' ";
END_VAR

conv_query := WCONCAT(conv_query1, WCONCAT(conv_barcode, conv_query2));
conv_str_query := WSTRING_TO_STRING(conv_query);
conv_QueryDB(queryString := conv_str_query, dbConn := 2, bConnect := 1);
conv_queryRes := conv_QueryDB.queryResults;

zone_dest := STRING_TO_WSTRING(conv_queryRes[0].AreaID); 
//zone_dest := "P1030"; //This works when uncommented??!!??
zone_query := WCONCAT(zone_query1, WCONCAT(zone_dest, zone_query2));
zone_str_query := WSTRING_TO_STRING(zone_query);
zone_QueryDB(queryString := zone_str_query, dbConn := 1, bConnect := 1);
zone_queryRes := zone_QueryDB.queryResults;

Я бы ожидал, что zone_queryRes будет таким же при выполнении zone_dest в качестве жестко закодированного значения по сравнению с его извлечением из массива conv_queryRes.Я не уверен, что это проблема с типом данных.При выполнении строки запроса имеют правильный синтаксис.

-------------- РЕДАКТИРОВАТЬ -----------------------------------------------------------------

Включая функциональный блок SQL. 

FUNCTION_BLOCK Query_tblZoneMap
VAR_INPUT 
    queryString     : STRING(2000); //Select statement
    dbConn          : UDINT; //Int of connection configured in TF6420
    bCONNECT        : BOOL; //Rising trigger to connect to db. Need to make this re-fireable

END_VAR
VAR_OUTPUT
    queryResults    : ARRAY [0..18] OF tblZoneMap;
    nError          : INT;

END_VAR
VAR
    fbSQLDatabase   : FB_SQLDatabase(sNetID:='', tTimeout:=T#500MS);
    fbSqlCommand    : FB_SQLCommand(sNetID := '', tTimeout := T#500MS);     
    fbSQLResult     : FB_SQLResult(sNetID:='', tTimeout:=T#500MS);
    nState          : INT;
    R_TRIG1         : R_TRIG;
END_VAR


(*
    Welcome to the QueryDB function block!
    This function exists to query a database that is configured using the TF6420 Connectivity module. 
    When executed, it establishes a connection with the database, creates an instance of the FB_SQLCommand,
    executes the instance of FB_SQLCommand, then reads the cached results using FB_SQLResult into the 
    queryResults array.
    When results are received successfully, the database connection is closed.

*)
R_TRIG1(CLK:=bCONNECT);
IF R_TRIG1.Q AND nState = 0 THEN
    nState := 1;

END_IF
CASE nState OF
    0:(*Idle*)
    IF bConnect THEN
        bCONNECT := 0;
    END_IF  
    1: // Connect to database 
    IF fbSqlDatabase.Connect(dbConn) THEN
        IF fbSqlDatabase.bError THEN
            nState := 255;
        ELSE
            nState := nState+1;
        END_IF
    END_IF  

    2: // Create a command reference
    IF fbSqlDatabase.CreateCmd(ADR(fbSqlCommand)) THEN
        IF fbSqlDatabase.bError THEN
            nState := 255;
        ELSE
            nState := nState+1;
        END_IF
    END_IF

    3://Execute SELECT Statement FB_SQLCommand.ExecuteDataReturn(pSQLCmd:= , cbSQLCmd:= , pSQLDBResult:= )
    IF fbSQLCommand.ExecuteDataReturn(pSQLCmd:= ADR(queryString)
                                    , cbSQLCmd:= SIZEOF(queryString)
                                    , pSQLDBResult:= ADR(fbSqlResult)) THEN
        IF fbSQLCommand.bError THEN
            nState := 255;
            ELSE
            nState := nState + 1;
        END_IF
    END_IF

    4://Read Results 
    IF fbSqlResult.Read(nStartIndex:= 0
                        ,nRecordCount:= 19
                        ,pData:= ADR(queryResults)
                        ,cbData:= SIZEOF(queryResults)
                        ,bWithVerifying:= FALSE
                        ,bDataRelease:= FALSE) THEN
        IF fbSqlResult.bError THEN
            nState := 255;
        ELSE
            nState := nState+1;
        END_IF
    END_IF  
    5:// disconnect from database
    IF fbSqlDatabase.Disconnect() THEN
        IF fbSqlDatabase.bError THEN
            nState := 255;
        ELSE
            nState := 0;
            bConnect := 0;
        END_IF
    END_IF
    255:
        nError  := 1; // If errored, check SQL logs.
        bConnect := 0;
        nState := 0;
END_CASE

Ответы [ 2 ]

0 голосов
/ 12 апреля 2019

Я также думаю, что вы должны поместить свои запросы в последовательность шагов, чтобы избежать любого конфликта в функциональном блоке Query_tblZoneMap: 

CASE nStep OF

    eFIRST_QUERY: 

        sConvQuery := F_CONCAT3(sConvQuery1, sConvBarcode, sConvQuery2);
        //Use Enums instead of numbers 
        fbQueryDB(queryString := sConvQuery , dbConn := 2, bConnect := TRUE);
        nStep := eWAIT_FOR_FIRST_RESULT;

    eWAIT_FOR_FIRST_RESULT:     

        IF NOT fbQueryDB.bBusy THEN
            aConvQueryRes := fbQueryDB.queryResults;
            nStep := eSECOND_QUERY;
        END_IF

        //Error handling 
        //ELSIF fbQueryDB.bError ...

    eSECOND_QUERY:

        sZoneDest := aConvQueryRes[0].AreaID; 
        sZoneQuery := F_CONCAT3(sZoneQuery1,sZoneDest,sZoneQuery2);
        fbQueryDB(queryString := sZoneQuery, dbConn := 1, bConnect := TRUE);
        nStep := eWAIT_FOR_SECOND_RESULT;

    eWAIT_FOR_SECOND_RESULT:    

        IF NOT fbQueryDB.bBusy THEN
            aZoneQueryRes := fbQueryDB.queryResults;
            nStep := eCHECK_RESULT;
        END_IF

        //Error handling
        //ELSIF fbQueryDB.bError ...

    eCHECK_RESULT: //...    

END_CASE
0 голосов
/ 11 апреля 2019

почему вы используете WSTRING в первую очередь? Используйте обычные строки, чтобы вам не приходилось конвертировать туда-сюда, и ваш код стал более читабельным.

Если вы объедините много строк вместе, создайте функцию, способную на это. Что-то, что выглядит так, когда вы называете это: 

F_CONCAT3(
    zone_query1,
    zone_dest,
    zone_query2,
);

Я советую вам использовать соглашение о кодировании Beckhoff, чтобы и другие разработчики могли прочитать ваш код:

https://infosys.beckhoff.com/english.php?content=../content/1033/tc3_plc_intro/45035999420423563.html&id=

Ваш код может выглядеть следующим образом: 

sConvQuery := F_CONCAT3(sConvQuery1, sConvBarcode, sConvQuery2);

//Use Enums instead of numbers 
fbQueryDB(queryString := sConvQuery , dbConn := 2, bConnect := TRUE);
aConvQueryRes := fbQueryDB.queryResults;

sZoneDest := aConvQueryRes[0].AreaID; 
sZoneQuery := F_CONCAT3(sZoneQuery1,sZoneDest,sZoneQuery2);

fbQueryDB(queryString := sZoneQuery, dbConn := 1, bConnect := TRUE);
aZoneQueryRes := fbQueryDB.queryResults;

Не могли бы вы опубликовать код функционального блока zone_QueryDB?

...