Как я могу разделить строку в элементе xml, используя xslt 1.0 - PullRequest
Новая
       28

Как я могу разделить строку в элементе xml, используя xslt 1.0

0 голосов
/ 19 марта 2019

У меня проблема с разделением строки истории платежей, например 

"Apr:2013,XXX/STD|Jan:2013,XXX/STD|Dec:2012,XXX/STD|Nov:2012,XXX/STD|"

, на элемент XML ниже, как показано ниже 

<Periods>
<Period Year=2013>
     <Months month1="Apr" month1Value="XXX/STD" month2="Jan" month2Value="XXX/STD" 
</Period >
<Period Year=2012>
     <Months month1="Dec" month1Value="XXX/STD" month2="Nov" month2Value="XXX/STD" 
</Period>
</Periods>

Из комментариев

давайте предположим, что моя точная история платежей приведена ниже "Апр: 2013, XXX / STD | Март: 2013, XXX / STD | Фев: 2013, XXX / STD | Янв: 2013, XXX / STD | Дек: 2012, XXX/ STD | ноябрь: 2012, XXX / STD | Октябрь: 2012, XXX / STD | сентябрь: 2012, XXX / STD | Август: 2012, XXX / STD | июль: 2012, XXX / STD | июнь: 2012, XXX / STD| май: 2012, XXX / STD | Апрель: 2012, XXX / STD | Mar: 2012, XXX / STD |»но теперь его генерация дублирует узлы.Пожалуйста, предложите

Ответы [ 2 ]

0 голосов
/ 19 марта 2019

Попробуйте следующим образом:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:param name="input"/>

<xsl:template match="/">
    <Periods>
        <xsl:call-template name="tokenize-to-pairs">
            <xsl:with-param name="text" select="$input"/>
        </xsl:call-template>
    </Periods>
</xsl:template>

<xsl:template name="tokenize-to-pairs">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="'|'"/>
    <xsl:if test="contains($text, $delimiter) and contains(substring-after($text, $delimiter), $delimiter)">
        <xsl:call-template name="parse-period">
            <xsl:with-param name="month1" select="substring-before($text, $delimiter)"/>
            <xsl:with-param name="month2" select="substring-before(substring-after($text, $delimiter), $delimiter)"/>
        </xsl:call-template>
         <!-- recursive call -->
        <xsl:call-template name="tokenize-to-pairs">
            <xsl:with-param name="text" select="substring-after(substring-after($text, $delimiter), $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template name="parse-period">
    <xsl:param name="month1"/>
    <xsl:param name="month2"/>
    <Period Year="{substring-before(substring-after($month1, ':'), ',')}">
        <Months 
            month1="{substring-before($month1, ':')}" 
            month1Value="{substring-after($month1, ',')}" 
            month2="{substring-before($month2, ':')}" 
            month2Value="{substring-after($month2, ',')}"/>
    </Period >
</xsl:template>

</xsl:stylesheet>

Когда эта таблица стилей вызывается с параметром input: 

Apr:2013,XXX/STD|Mar:2013,XXX/STD|Feb:2013,XXX/STD|Jan:2013,XXX/STD|Dec:2012,XXX/STD|Nov:2012,XXX/STD|Oct:2012,XXX/STD|Sep:2012,XXX/STD|Aug:2012,XXX/STD|Jul:2012,XXX/STD|Jun:2012,XXX/STD|May:2012,XXX/STD|Apr:2012,XXX/STD|Mar:2012,XXX/STD|

результат будет: 

<Periods>
  <Period Year="2013">
    <Months month1="Apr" month1Value="XXX/STD" month2="Mar" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2013">
    <Months month1="Feb" month1Value="XXX/STD" month2="Jan" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2012">
    <Months month1="Dec" month1Value="XXX/STD" month2="Nov" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2012">
    <Months month1="Oct" month1Value="XXX/STD" month2="Sep" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2012">
    <Months month1="Aug" month1Value="XXX/STD" month2="Jul" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2012">
    <Months month1="Jun" month1Value="XXX/STD" month2="May" month2Value="XXX/STD"/>
  </Period>
  <Period Year="2012">
    <Months month1="Apr" month1Value="XXX/STD" month2="Mar" month2Value="XXX/STD"/>
  </Period>
</Periods>

Обратите внимание, что год периода - это год первого месяца.

0 голосов
/ 19 марта 2019

Предполагая, что ваша строка будет содержать историю платежей, классифицированную по году .

Что делает код ниже:

1. Будет разбит строка накаждый второй разделитель '|'

например, он сгенерирует 

<temp>Apr:2013,XXX/STD|Jan:2013,XXX/STD</temp>
<temp>Dec:2012,XXX/STD|Nov:2012,XXX/STD</temp>

2. Далее он будет получать значения от каждого <temp> итерации по сохраненному сгенерированному массивув переменной values.

А вот и вы: 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
            xmlns:exsl="http://exslt.org/common" version="1.0"
            exclude-result-prefixes="exsl">

<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="payment_history">

        <xsl:variable name="values">
            <xsl:call-template name="split">
                <xsl:with-param name="pText" select="."/>
            </xsl:call-template>
        </xsl:variable>

        <Periods>
            <xsl:for-each select="exsl:node-set($values)/*">
                <Period Year="{substring-before(substring-after(normalize-space(.),':'),',')}">
                    <Months month1="{substring-before(.,':')}" 
                            month1Value="{substring-before(substring-after(normalize-space(.),','),'|')}"
                            month2="{substring-before(substring-after(normalize-space(.),'|'),':')}" 
                            month2Value="{substring-after(substring-after(normalize-space(.),'|'),',')}" />
                </Period>
            </xsl:for-each>
        </Periods>
</xsl:template>

<xsl:template match="text()" name="split">
    <xsl:param name="pText" select="."/>

    <xsl:if test="normalize-space($pText)">
        <xsl:variable name="vText" select="normalize-space($pText)"/>
        <temp> 
            <xsl:value-of select="substring-before($vText, '|')"/>
            <xsl:value-of select="concat('|', substring-before(substring-after($vText, '|'), '|'))"/>
        </temp>
        <xsl:call-template name="split">
            <xsl:with-param name="pText" select="substring-after(substring-after($vText, '|'), '|')"/>
        </xsl:call-template>
    </xsl:if>
  </xsl:template>

  </xsl:stylesheet>

http://xsltfiddle.liberty -development.net / bnnZW3

...