XSLT 1.0 Перемещение одного сегмента

Question

скажите, пожалуйста, как я могу переместить сегмент "BGM" из "CNT" в "GRP"?

Фактически XML:

<?xml version="1.0"?>
<SEEDELFOR>
	<AG/>
	<CNT>
		<TRANSMISSION_DATE>20190307</TRANSMISSION_DATE>
		<TRANSMISSION_TIME>113300</TRANSMISSION_TIME>    		</INTERCHANGE_CONTROL_NUMBER>
		</SENDER>
		</SENDER_QUALIFIER>
		</RECEIVER>
		</RECEIVER_QUALIFIER>
		</SYNTAX_IDENTIFIER>
		</SYNTAX_VERSION>
		<BGM>227</BGM>
		<GRP>			
			</IDENTIFIER_BY>
			</IDENTIFIER_SU>
			</DATE_4>
			</REF_ON>    			
		</GRP>
	</CNT>
</SEEDELFOR>

Правильный вывод моего XML должен быть:

<?xml version="1.0"?>
<SEEDELFOR>
	<AG/>
	<CNT>
		<TRANSMISSION_DATE>20190307</TRANSMISSION_DATE>
		<TRANSMISSION_TIME>113300</TRANSMISSION_TIME>
		<SENDER></SENDER>
		</SENDER_QUALIFIER>
		</RECEIVER>
		</RECEIVER_QUALIFIER>
		</SYNTAX_IDENTIFIER>
		</SYNTAX_VERSION>		
		<GRP>
      <BGM>227</BGM>    			   			
		</GRP>
	</CNT>
</SEEDELFOR>

Вот мой XSLT: я пытался копировать, но я думаю, что лучше переместить сегмент?

Редактировать: Это мой полный XSLT: Может быть, я должен объединиться с другими сегментами копирования?

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
    <xsl:output method="xml" indent="yes"/>
    
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
    
<!--Copy all of CNT != BGM-->    
<xsl:template match="CNT">
    <xsl:copy>
        <xsl:apply-templates select="*[local-name()!='BGM']" />
    </xsl:copy>
</xsl:template>

<!--copy BGM from CNT to GRP-->
<xsl:template match="GRP">
    <xsl:element name="GRP">
        <xsl:apply-templates />
        <xsl:copy-of select="../BGM" />
    </xsl:element>
</xsl:template>

<!--copy the data from ADD/CONTACT with Qualifier EM to GRP, so it can be used in the mapping to set EMAIL from Customer-->
<xsl:template match="GRP">
    <xsl:copy>
        <xsl:for-each select ="./ADD/CONTACT">
         <xsl:if test="./QUALIFIER='EM'">          
  <CONTACT_EMAIL>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_EMAIL>
       </xsl:if>
         <xsl:if test="./QUALIFIER='TE'">          
  <CONTACT_TEL>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_TEL>
       </xsl:if>
         <xsl:if test="./QUALIFIER='FX'">          
  <CONTACT_FAX>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_FAX>
       </xsl:if>
      </xsl:for-each>
    <!--copy all other nodes-->
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>
  
  <!--delete IC node-->
  <xsl:template match="IC" />
  
  <!--delete FILTER_SET node-->
  <xsl:template match="FILTER_SET" />
 
  <!--delete SEE_AG node-->
  <xsl:template match="SEE_AG" />

  <!--delete ME node-->
  <xsl:template match="ME" />
  
    <!--delete ADD node-->
  <xsl:template match="ADD" />
  
  <!-- delete segment (ADD) with specified QUALIFER (SU)  -->
  <xsl:template match="ADD[QUALIFIER='SU']"/> 
  
  <!--delete TRANSPORT_DETAILS node-->
  <xsl:template match="TRANSPORT_DETAILS" />
  
  <!--delete PACKAGE_DETAILS node-->
  <xsl:template match="PACKAGE_DETAILS" />
  
  <!--delete AMOUNT_DETAILS node-->
  <xsl:template match="AMOUNT_DETAILS" />
  
    <!--delete IC node-->
  <xsl:template match="CONTACT" />
  
   <!-- delete empty nodes -->
 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>
 <xsl:template match="*[not(@*|*|comment()|processing-instruction()) and normalize-space()='']"/>
<!-- delete empty nodes -->  
  
</xsl:stylesheet>

Спасибо за вашу помощь.

С уважением Джулиан

Answer 1

Идиоматический подход к «перемещению» узла из одного места в другое:

• копируй все как есть,
• кроме рассматриваемого узла и
• скопировать узел на новое место:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<!-- remove BGM -->
<xsl:template match="BGM"/>

<xsl:template match="GRP">
    <xsl:copy>
        <xsl:apply-templates/>
        <!-- add BGM -->
        <xsl:copy-of select="../BGM" />
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

---

Если вам нужно изменить другие узлы, при необходимости добавьте соответствующие им шаблоны.

Answer 2

Кажется, ваш XML не правильно сформирован.Если я правильно понял, вы можете найти ниже xslt для удовлетворения ваших требований:

XML может быть:

<?xml version="1.0"?>
<SEEDELFOR>
<AG />
<CNT>
    <TRANSMISSION_DATE>20190307</TRANSMISSION_DATE>
    <TRANSMISSION_TIME>113300</TRANSMISSION_TIME>
    <INTERCHANGE_CONTROL_NUMBER />
    <SENDER />
    <SENDER_QUALIFIER />
    <RECEIVER />
    <RECEIVER_QUALIFIER />
    <SYNTAX_IDENTIFIER />
    <SYNTAX_VERSION />
    <BGM>227</BGM>
    <GRP>
        <IDENTIFIER_BY />
        <IDENTIFIER_SU />
        <DATE_4 />
        <REF_ON />
    </GRP>
</CNT>
</SEEDELFOR>

Решение может быть таким:

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">

<xsl:template match="*">
    <xsl:copy>
        <xsl:apply-templates />
    </xsl:copy>
</xsl:template>

<xsl:template match="CNT">
    <xsl:copy>
        <xsl:apply-templates select="*[local-name()!='BGM']" />
    </xsl:copy>
</xsl:template>

<xsl:template match="GRP">
    <xsl:element name="GRP">
        <xsl:apply-templates />
        <xsl:copy-of select="../BGM" />
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

http://xsltransform.net/eieE3Q5

Answer 3

<!-- remove BGM at CNT-->
<xsl:template match="BGM"/>

<!--copy the data from ADD/CONTACT with Qualifier EM to GRP, so it can be used in the mapping to set EMAIL from Customer-->
<xsl:template match="GRP">
    <xsl:copy>
        <xsl:for-each select ="./ADD/CONTACT">
         <xsl:if test="./QUALIFIER='EM'">          
  <CONTACT_EMAIL>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_EMAIL>
       </xsl:if>
         <xsl:if test="./QUALIFIER='TE'">          
  <CONTACT_TEL>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_TEL>
       </xsl:if>
         <xsl:if test="./QUALIFIER='FX'">          
  <CONTACT_FAX>
  <xsl:value-of select="NUMBER"/>      
  </CONTACT_FAX>
       </xsl:if>
      </xsl:for-each>
    <!--copy BGM from CNT to GRP -->
      <xsl:copy-of select="../BGM" />
    <!--copy all other nodes-->
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>