Размещение большего количества текста под осью X в gnuplot

Question

Я думаю о том, как разместить больше текста под существующими значениями оси X в gnuplot. Например, как я могу разместить дополнительный текст в скобках, как показано на рисунке ниже?

Пока я просто использовал Inkscape, чтобы изменить сам файл изображения, и ввел текст вручную. Есть предложения по другим инструментам, если не по gnuplot?

Answer 1

Одним из способов может быть следующее.Вы можете настроить нижнее поле и смещение xlabel.

Код:

### some more extra text at tics
reset session

set sample 11
set bmargin 4.5
set xlabel "x-label" offset 0,-1

plot [0:10] '+' u 0:1:xtic(sprintf("%g\n(a)",$1)) w lp pt 7
### end of code

Результат:

Редактировать:

Вы также можете добавить разный текст для каждой метки.В зависимости от ваших конкретных потребностей это может выглядеть, например, следующим образом:

Код:

### some more extra text at tics
reset session

set sample 13
set bmargin 4.5
set xlabel "x-label" offset 0,-1

TicData = "a b c A B C α β γ ant bat cat dog"
TicText(n) = sprintf("%g\n(%s)",int(n),word(TicData,int(n)))

plot [0:12] '+' u 0:1:xtic(TicText($0+1)) w lp pt 7 enhanced
### end of code

Результат: