Сбой RSA_private_decrypt при повторном вызове - PullRequest
Новая
       19

Сбой RSA_private_decrypt при повторном вызове

0 голосов
/ 20 марта 2019

Пожалуйста, обратите внимание на следующий метод: 

int BCVirtualCard::decrypt(std::string from, std::string *to, int keyId, bool padding)
{
    if (to == nullptr)
    {
        NSCAssert(NO, @"Invalid params");
        return 0;
    }

    NSString* privateKey            = [m_storage privateKeyForSlot:keyId];
    NSArray<NSString*>* components  = [privateKey componentsSeparatedByString:@"_"];
    const NSInteger componentsCount = 4;

    if (components.count != componentsCount)
    {
        *to = "";
        return 0;
    }

    const char* d = [components[0] UTF8String];
    const char* n = [components[1] UTF8String];
    const char* p = [components[2] UTF8String];
    const char* q = [components[3] UTF8String];

    RSA* rsa = RSA_new();

    BN_hex2bn(&rsa->d, d);
    BN_hex2bn(&rsa->n, n);
    BN_hex2bn(&rsa->p, p);
    BN_hex2bn(&rsa->q, q);

    unsigned char* _to = (unsigned char *)calloc(1, sizeof(unsigned char));

    int decryptedSize = RSA_private_decrypt((int)from.length(), (unsigned char *)from.c_str(), _to, rsa, RSA_NO_PADDING);

    free(_to);

    if (decryptedSize <= 0)
    {
        ERR_print_errors_cb(test, NULL);

        *to = "";
        return 0;
    }

    _to = (unsigned char *)calloc(decryptedSize, sizeof(unsigned char));

    RSA_private_decrypt((int)from.length(), (unsigned char *)from.c_str(), _to, rsa, RSA_NO_PADDING);

    *to = std::string((char *)_to, strlen((char *)_to));

    free(_to);

    RSA_free(rsa);

    return 1;
}

Здесь строка from должна быть расшифрована и записана в строку to. Для расшифровки я использую функцию RSA_private_decrypt. Я звоню это два раза. Первый раз для определения размера расшифрованного текста и второй раз для записи расшифрованного текста в _to буфер. И когда я вызываю его во второй раз, он обычно падает так: 

malloc: Heap corruption detected, free list is damaged at 0x280ff3d70
*** Incorrect guard value: 0
No1BCmail(2171,0x170efb000) malloc: *** set a breakpoint in malloc_error_break to debug

Точка останова включена, и это позволило мне найти место крушения. Однако я не могу понять причину сбоя. Я попытался воссоздать структуру RSA и поиграть с размером, выделенным для _to во второй раз, но ничего не помогло. Вы видите, что здесь не так? Спасибо

1 Ответ

1 голос
/ 20 марта 2019

RSA_private_decrypt требует, чтобы параметр to указывал на буфер подходящего размера. Ваш первый вызов использует только буфер размера 1, который слишком мал и имеет неопределенное поведение. Что вам нужно сделать, это получить размер от rsa с помощью RSA_size(rsa), а затем вы можете использовать его для выделения места для _to. Это означает, что вам не нужно вызывать функцию дважды, так как вы уже получите размер в первый раз около

Вы также должны использовать decryptedSize для длины, если строящаяся строка вместо strlen, так как _to может не заканчиваться нулем.

Собрав все это вместе, вы должны выглядеть примерно так: 

int BCVirtualCard::decrypt(std::string from, std::string *to, int keyId, bool padding)
{
    if (to == nullptr)
    {
        NSCAssert(NO, @"Invalid params");
        return 0;
    }

    NSString* privateKey            = [m_storage privateKeyForSlot:keyId];
    NSArray<NSString*>* components  = [privateKey componentsSeparatedByString:@"_"];
    const NSInteger componentsCount = 4;

    if (components.count != componentsCount)
    {
        *to = "";
        return 0;
    }

    const char* d = [components[0] UTF8String];
    const char* n = [components[1] UTF8String];
    const char* p = [components[2] UTF8String];
    const char* q = [components[3] UTF8String];

    RSA* rsa = RSA_new();

    BN_hex2bn(&rsa->d, d);
    BN_hex2bn(&rsa->n, n);
    BN_hex2bn(&rsa->p, p);
    BN_hex2bn(&rsa->q, q);

    auto _to = std::make_unique<unsigned char[]>(RSA_size(rsa)); // use smart pointers so you don't have to worry about releasing the memory

    int decryptedSize = RSA_private_decrypt((int)from.length(), (unsigned char *)from.c_str(), _to.get(), rsa, RSA_NO_PADDING);

    if (decryptedSize <= 0)
    {
        ERR_print_errors_cb(test, NULL);    
        *to = "";
        return 0;
    }

    *to = std::string((char *)_to.get(), decryptedSize);
    return 1;
}
...