Как определить экземпляр Data.Foldable.Constrained? - PullRequest
Новая
       18

Как определить экземпляр Data.Foldable.Constrained?

1 голос
/ 06 июня 2019

Я успешно определил категорию, функтор, полугруппу, ограниченный моноид.Теперь я застрял с Data.Foldable.Constrained.Точнее, я, кажется, правильно определил неограниченные функции fldl и fldMp, но не могу заставить их быть принятыми как экземпляры Foldable.Constrained.Моя попытка определения вставлена ​​как комментарий. 

{-# LANGUAGE OverloadedLists, GADTs, TypeFamilies, ConstraintKinds, 
FlexibleInstances, MultiParamTypeClasses, StandaloneDeriving, TypeApplications #-}

import Prelude ()

import Control.Category.Constrained.Prelude
import qualified Control.Category.Hask as Hask
-- import Data.Constraint.Trivial
import Data.Foldable.Constrained
import Data.Map as M
import Data.Set as S
import qualified Data.Foldable as FL

main :: IO ()
main = print $ fmap (constrained @Ord (+1))
             $ RMS ([(1,[11,21]),(2,[31,41])])

data RelationMS a b where
  IdRMS :: RelationMS a a
  RMS :: Map a (Set b) -> RelationMS a b 
deriving instance (Show a, Show b) => Show (RelationMS a b)

instance Category RelationMS where
    type Object RelationMS o = Ord o
    id = IdRMS
    RMS mp2 . RMS mp1
      | M.null mp2 || M.null mp1 = RMS M.empty
      | otherwise = RMS $ M.foldrWithKey 
            (\k s acc -> M.insert k (S.foldr (\x acc2 -> case M.lookup x mp2 of
                                                        Nothing -> acc2
                                                        Just s2 -> S.union s2 acc2
                                             ) S.empty s
                                    ) acc
            ) M.empty mp1

(°) :: (Object k a, Object k b, Object k c, Category k) => k a b -> k b c -> k a c
r1 ° r2 = r2 . r1

instance (Ord a, Ord b) => Semigroup (RelationMS a b) where
    RMS r1 <> RMS r2 = RMS $ M.foldrWithKey (\k s acc -> M.insertWith S.union k s acc) r1  r2 

instance (Ord a, Ord b) => Monoid (RelationMS a b) where
    mempty = RMS M.empty
    mappend = (<>)

instance Functor (RelationMS a) (ConstrainedCategory (->) Ord) Hask where
    fmap (ConstrainedMorphism f) = ConstrainedMorphism $
            \(RMS r) -> RMS $ M.map (S.map f) r


fldl :: (a -> Set b -> a) -> a -> RelationMS k b -> a
fldl f acc (RMS r) = M.foldl f acc r

fldMp :: Monoid b1 => (Set b2 -> b1) -> RelationMS k b2 -> b1
fldMp m (RMS r) = M.foldr (mappend . m) mempty r


-- instance Foldable (RelationMS a) (ConstrainedCategory (->) Ord) Hask where
    -- foldMap f (RMS r)
        -- | M.null r = mempty
        -- | otherwise = FL.foldMap f r
    -- ffoldl f = uncurry $ M.foldl (curry f)

1 Ответ

2 голосов
/ 07 июня 2019

Вам нужно FL.foldMap (FL.foldMap f) r в вашем определении, чтобы вы сбросили Map и Set.

Однако в вашем экземпляре Functor есть критическая ошибка;ваш fmap является частичным.Он не определен в IdRMS.

. Я предлагаю использовать -Wall, чтобы компилятор предупреждал вас о таких проблемах.

Проблема сводится к тому, что вам необходимо представлять отношения сконечные и бесконечные области.IdRMS :: RelationRMS a a уже может использоваться для представления некоторых отношений бесконечной области, он недостаточно силен для представления отношений, подобных fmap (\x -> [x]) IdRMS.

Один из подходов заключается в использовании Map a (Set b)для конечных отношений и a -> Set b для бесконечных отношений. 

data Relation a b where
   Fin :: Map a (Set b) -> Relation a b
   Inf :: (a -> Set b) -> Relation a b

image :: Relation a b -> a -> Set b
image (Fin f) a = M.findWithDefault (S.empty) a f
image (Inf f) a = f a

Это соответственно изменяет экземпляр категории: 

instance Category Relation where
  type Object Relation a = Ord a

  id = Inf S.singleton

  f . Fin g = Fin $ M.mapMaybe (nonEmptySet . concatMapSet (image f)) g
  f . Inf g = Inf $ concatMapSet (image f) . g

nonEmptySet :: Set a -> Maybe (Set a)
nonEmptySet | S.null s = Nothing
            | otherwise = Just s

concatMapSet :: Ord b => (a -> Set b) -> Set a -> Set b
concatMapSet f = S.unions . fmap f . S.toList

И теперь вы можете определить общий Functor экземпляр: 

instance Functor (Relation a) (Ord ⊢ (->)) Hask where
  fmap (ConstrainedMorphism f) = ConstrainedMorphism $ \case -- using {-# LANGUAGE LambdaCase #-}
    Fin g -> Fin $ fmap (S.map f) g
    Inf g -> Inf $ fmap (S.map f) g

Но при определении экземпляра Foldable возникает новая проблема: 

instance Foldable (Relation a) (Ord ⊢ (->)) Hask where
  foldMap (ConstrainedMorphism f) = ConstrainedMorphism $ \case
    Fin g -> Prelude.foldMap (Prelude.foldMap f) g
    Inf g -> -- uh oh...problem!

У нас есть f :: b -> m и g :: a -> Set b.Monoid m дает нам append :: m -> m -> m, и мы знаем Ord a, но для генерации всех b значений в изображении отношения нам нужны все возможные a значения!

Один из способов попытаться спасти это - использовать Bounded и Enum в качестве дополнительных ограничений на домен отношения.Затем вы можете попытаться перечислить все возможные значения a с помощью [minBound..maxBound] (это может быть не каждое из перечисленных значений для всех типов; я не уверен, является ли это законом для Bounded и Enum). 

instance (Enum a, Bounded a) => Foldable (Relation a) (Ord ⊢ (->)) Hask where
  foldMap (ConstrainedMorphism f) = ConstrainedMorphism $ \case
    Fin g -> Prelude.foldMap (Prelude.foldMap f) g
    Inf g -> Prelude.foldMap (Prelude.foldMap f . g) [minBound .. maxBound]
...