пространство между концептуальными строками в карте gnuplot pm3d - PullRequest
Новая
       15

пространство между концептуальными строками в карте gnuplot pm3d

0 голосов
/ 12 марта 2019

Нет пробелов от 1 до 3;3 и 5. 3-й ряд не отображается на графике.Вот мой Gnuplot: 

    set terminal jpeg size 1024,768
    set output "test-gnu.jpg"
    set pm3d map corners2color c1
    set palette maxcolors 3
    set palette defined (0 "#FF0000", 1 "#00FF00", 2 "#CCCC00")
    set xlabel "Frame"
    set ylabel ""
    set yrange [   0.000:6.000]
    set xrange [   1.000:5.000]
    splot "-" with pm3d title ""
    1.000     1.000      0
    1.000     3.000      0
    1.000     5.000      0

    2.000     1.000      1
    2.000     3.000      0
    2.000     5.000      1

    3.000     1.000      2
    3.000     3.000      0
    3.000     5.000      2

    4.000     1.000      0
    4.000     3.000      1
    4.000     5.000      2

Я хочу пробел между 1 и 3;3 и 5. а также 3-й ряд в сюжете.

1 Ответ

0 голосов
/ 12 марта 2019

Из вашего описания не совсем понятно, что вы имеете в виду, но я предполагаю, что вам может понадобиться следующее ... Нет необходимости в splot и, вероятно, boxxyerror делает то, что вы хотите. 

reset session
$Data <<EOD
1.000     1.000     0
1.000     3.000     0
1.000     5.000     0

2.000     1.000     1
2.000     3.000     0
2.000     5.000     1

3.000     1.000     2
3.000     3.000     0
3.000     5.000     2

4.000     1.000     0
4.000     3.000     1
4.000     5.000     2
EOD

set palette maxcolors 3
set palette defined (0 "#FF0000", 1 "#00FF00", 2 "#CCCC00")
set xlabel "Frame"
set ylabel ""
set yrange [0:6]
set xrange [0:5]
plot $Data u 1:2:(0.5):(0.5):3 with boxxyerror fs solid 1.0 fc palette notitle

enter image description here

...