Как добавить текст в конец таблицы esttab без использования estadd

Question

Приведенный ниже код добавляет пользовательский текст к каждому уравнению с использованием локального и производит то, что я хочу:

estimates clear
eststo clear
sysuse auto, clear

eststo w1: regress price mpg trunk length
estadd local number one
eststo w2: regress turn mpg trunk length
estadd local number two
eststo w3: regress displacement mpg trunk length
estadd local number three

esttab w1 w2 w3, stats(number)

Однако я хотел бы иметь возможность написать пользовательский текст в синтаксисе команды esttabи не перед использованием местных жителей.

Это неверно, но опция может выглядеть примерно так:

estimates clear
eststo clear
sysuse auto, clear

eststo w1: regress price mpg trunk length
eststo w2: regress turn mpg trunk length
eststo w3: regress displacement mpg trunk length

esttab w1 w2 w3, stats("number", "one" "two" "three")

Можно ли каким-то образом вставить параметр в команду esttab, где я пишу то, что хочу?Я знаю, что есть опция indicate(), но я не мог понять, может ли она делать то, что мне нужно или нет.

Answer 1

К сожалению, вы не можете определить содержимое элемента stats() на лету.

Однако, обходной путь следующий:

sysuse auto, clear
eststo clear
estimates clear

eststo w1: regress price mpg trunk length
eststo w2: regress turn mpg trunk length
eststo w3: regress displacement mpg trunk length

esttab, prefoot(`"{hline 60}"' ///
                `"numbers{dup 15: }one{dup 13: }two{dup 11: }three"' ///
                `"more numbers{dup 9: }four{dup 12: }five{dup 13: }six"') 

------------------------------------------------------------
                      (1)             (2)             (3)   
                    price            turn    displacement   
------------------------------------------------------------
mpg                -173.7         -0.0656          -1.777   
                  (-1.97)         (-0.88)         (-1.04)   

trunk              -0.855         -0.0593          0.0659   
                  (-0.01)         (-0.66)          (0.03)   

length              21.40           0.165***        3.068***
                   (0.79)          (7.19)          (5.83)   

_cons              5854.0           10.76*         -342.3** 
                   (0.97)          (2.09)         (-2.92)   
------------------------------------------------------------
numbers               one             two           three
more numbers         four            five             six
N                      74              74              74   
------------------------------------------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

Очевидно, вам придется каждый раз указывать пробелы в соответствии с вашим вариантом использования. Вы можете сделать это вручную или написав небольшую программу, которая рассчитывает их.