Как изменить цвет столбцов на графике в gnuplot? - PullRequest
Новая
       25

Как изменить цвет столбцов на графике в gnuplot?

0 голосов
/ 17 апреля 2019

У меня есть код, импортирующий данные и выводящий их на график, но все столбцы фиолетового цвета, и я хочу изменить цвета для каждого из них.Еще одна проблема, которую я заметил, это то, что она показывает расположение файла на графике, и я не хочу, чтобы он был там. 

set title "Accuracy Plot for the FASP" 
set xlabel "Fucntion"
set ylabel "(%)"
set boxwidth 0.9 absolute
set style fill   solid 1.00 border lt -1
set key fixed right top vertical Right noreverse noenhanced autotitle nobox
set style increment default
set style histogram clustered gap 1 title textcolor lt -1
set datafile missing '-'
set style data histograms
set xtics border in scale 0,0 nomirror rotate by -45  autojustify
set xtics  norangelimit 
set xtics   ()
set xrange [ * : * ] noreverse writeback
set x2range [ * : * ] noreverse writeback
set yrange [ 0 : 100 ] noreverse writeback
set y2range [ * : * ] noreverse writeback
set zrange [ * : * ] noreverse writeback
set cbrange [ * : * ] noreverse writeback
set rrange [ * : * ] noreverse writeback
plot 'C:\Users\John\Desktop\Mystery Assignment for Lomotey\FASP.dat' using 1:3:xtic(2) with boxes

1 Ответ

0 голосов
/ 23 июня 2019

... если вы сами еще не нашли решение ... Например, вы можете добавить столбец к вашим данным, определяя цвет как шестнадцатеричное число, например, 0xff0000 для красного.Затем в команде plot с linecolor rgb variable он возьмет цвет из столбца 4 (фактически, последний столбец 1:3:4: xtic(2), не считая xtic(2).) Чтобы удалить имя файла в качестве легенды, вы можете добавить notitleв команде plot или в предыдущей строке unset key.

Если вы предпочитаете давать имена цветов вместо номеров цветов, отметьте это gnuplot: применять имена цветов из файла данных

Код: 

### change color of boxes
reset session

$Data <<EOD
1  One     1  0xff0000
2  Two     4  0x00ff00
3  Three   9  0x0000ff
4  Four   16  0xff00ff
5  Five   25  0xffff00
6  Six    36  0x00ffff
EOD

set boxwidth 0.7
plot $Data u 1:3:4:xtic(2) w boxes fill solid 1.0 lc rgb var notitle
### end of code

Результат:

enter image description here

...