gnuplot: интерактивная 3D анимация? - PullRequest
Новая
       37

gnuplot: интерактивная 3D анимация?

0 голосов
/ 06 апреля 2019

С помощью gnuplot вы можете создать трехмерный график с помощью splot и интерактивно изменить вид.enter image description here

Вы также можете создавать анимации с помощью gnuplot с помощью set terminal gif animate.

enter image description here

### interactive animation?
reset session
set view equal
set border 0
unset tics

$Data <<EOD
1   1.000   0.000   0.000
2   0.500   0.866   0.000
3   -0.500  0.866   0.000
4   -1.000  0.000   0.000
5   -0.500  -0.866  0.000
6   0.500   -0.866  0.000
1   1.000   0.000   0.000
EOD

$Off <<EOD
1   0.00    0.00    0.1
2   0.00    0.00    -0.1
3   0.00    0.00    0.1
4   0.00    0.00    -0.1
5   0.00    0.00    0.1
6   0.00    0.00    -0.1
1   0.00    0.00    0.1
EOD

set xrange[-2:2]
set yrange[-2:2]
set zrange[-2:2]
set view 45,45
max=10.
Offset(n,axis,i) = real(word($Off[n+1],axis+1))*sin(2*pi*i/max)

set term gif animate delay 5 size 400,300
set output "Molecule.gif"

do for [i=0:max] {
    splot $Data u ($2+Offset($0,1,i)):($3+Offset($0,2,i)):($4+Offset($0,3,i)) \
    w lp pt 7 ps 2 lw 2 lc rgb "red" not
    unset autoscale
}

set term wxt size 400,300
set margin 0
splot $Data u 2:3:4 w lp pt 7 ps 2 lw 2 lc rgb "red" not
set output
### end of code

Теперь мой вопрос: есть ли возможность создавать интерактивные анимации?Я хотел бы повернуть вид, пока он анимирован.Возможно ли это как-то с gnuplot?Есть идеи?

Редактировать:

@ Ответ Итана решает этот вопрос.Однако есть ли способ избежать мерцания курсора мыши?

enter image description here

1 Ответ

2 голосов
/ 06 апреля 2019

Помещение команд заговора в цикл не отключает взаимодействие с мышью. Простой ответ должен работать: 

set xrange[-2:2]
set yrange[-2:2]
set zrange[-2:2]
set view 45,45
Offset(n,axis,i) = real(word($Off[n+1],axis+1))*sin(2*pi*i/max)

# Loop forever
# but allow an explicit end condition triggered by a hot key
done = 0
bind "d" "done = 1"

while (!done) {
  do for [i=0:10] {
    splot $Data u ($2+Offset($0,1,i)):($3+Offset($0,2,i)):($4+Offset($0,3,i)) \
    w lp pt 7 ps 2 lw 2 lc rgb "red" not
    pause 0.1
  }
}
...