Странное поведение в цикле Arduino - PullRequest
Новая
       44

Странное поведение в цикле Arduino

3 голосов
/ 18 апреля 2019

Я создаю систему измерения расстояния в Arduino (плата Mega2560, Arduino 1.8.9, ультразвуковой датчик JSN-SR04T-2.0).Поскольку датчик не очень стабилен, я хочу усреднять 15 измерений или измеренных значений каждые 500 миллисекунд, в зависимости от того, что произойдет раньше.Значения хранятся в массиве длиной 15 целых чисел, и есть счетчик, который сообщает, сколько измерений сделано.Проблема в том, что когда 15 измерений сделаны, и я хочу усреднить (не включены в код, только часть if (...)), счетчик переходит с 14 на очень высокое значение без объяснения и продолжает отсчет,Кроме того, если я установил очень большое время цикла (например, 1800 мс), иногда оно возвращается к 0, не входя в структуру if (где строка cntr = 0).

Я сократил код доминимум, чтобы найти то, что может вызвать проблемы.Кажется, что когда я использую значение, хранящееся в "valueArrayUS", это не работает.Если я закомментирую это, это работает.Я попробовал 2 разных способа использовать это значение, оба испортили его.

Минимальный исполняемый код такой: 

int trigPin = 8;    // Trigger
int echoPin = 9;    // Echo
int cntr=0; //how many measurements
long startTime=0; //start time of cycle
int valueArrayUS[15]; //max 15 values per cycle
int valueArrayUScp[15]; //copy of valueArrayUS
int sumUS=0;
long duration, cm;
int i=0, j=0;

void setup() {
  Serial.begin (9600);
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);

  for (i=0; i<15; i++) {
    valueArrayUS[i]=0; //default state
    valueArrayUScp[i]=valueArrayUS[i];
  }
  startTime=millis(); //time counter start
}

void loop() {

  //ultrasonic measurement
  digitalWrite(trigPin, LOW);
  delayMicroseconds(50);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(20);
  digitalWrite(trigPin, LOW);

  duration = pulseIn(echoPin, HIGH, 38000); //if no object is detected -> 38 ms long pulse from sensor -> 38 ms timeout
  cm = (duration/2) / 29.1;     // Divide by 29.1 or multiply by 0.0343
  valueArrayUS[cntr]=cm;

  Serial.print("cntr:  ");
  Serial.print(cntr);
  Serial.println();

  if ((millis()-startTime>500) || (cntr==15)) { //cycle is ended or buffer full

    Serial.print("enters the cycle, cycle time: ");
    Serial.println();
    Serial.print(millis()-startTime);
    Serial.print(" ms ");
    Serial.println();
    Serial.print("cntr at cycle start: ");
    Serial.print(cntr);
    Serial.println();

    //averaging would be here
    for (j=0; j<15; j++) { 
      valueArrayUScp[j]=valueArrayUS[j];  //THIS IS WHERE IT GOES WRONG
      //sumUS=sumUS+valueArrayUS[j]; //THIS IS WHERE IT GOES WRONG
    }

   for (i=0; i<15; i++) {
    valueArrayUS[i]=0; //default state
    }
    cntr=0; 
    startTime=millis();
    }
  else {
    cntr=cntr+1;
    Serial.print("cntr++    ");
    Serial.println();
  }
}

Вы можете видеть закомментированную строку и строку над ней, оба крушениякод.Если оба закомментированы, это работает как ожидалось.Если какой-либо из них присутствует, результат будет следующим: 

15:51:33.848 -> cntr:  11
15:51:33.894 -> cntr++    
15:51:33.894 -> cntr:  12
15:51:33.894 -> cntr++    
15:51:33.894 -> cntr:  13
15:51:33.942 -> cntr++  
15:51:33.942 -> cntr:  14
15:51:33.942 -> cntr++    
15:51:33.942 -> cntr:  117
15:51:33.989 -> cntr++   
15:51:33.989 -> cntr:  118
15:51:33.989 -> cntr++    
15:51:34.036 -> cntr:  119
15:51:34.036 -> cntr++    
15:51:34.036 -> cntr:  120
15:51:34.036 -> cntr++    
15:51:34.083 -> cntr:  121
15:51:34.083 -> cntr++    
15:51:34.083 -> cntr:  122
15:51:34.083 -> cntr++    
15:51:34.129 -> cntr:  123
15:51:34.129 -> cntr++    
15:51:34.129 -> cntr:  124
15:51:34.129 -> cntr++    
15:51:34.176 -> cntr:  125
15:51:34.176 -> cntr++    
15:51:34.176 -> cntr:  126
15:51:34.223 -> enters the cycle, cycle time: 
15:51:34.223 -> 557 ms 
15:51:34.270 -> cntr at cycle start: 126
15:51:34.270 -> cntr:  0
15:51:34.270 -> cntr++    
15:51:34.318 -> cntr:  1

Это должно быть: 

15:57:33.132 -> cntr:  14
15:57:33.132 -> cntr++    
15:57:33.132 -> cntr:  15
15:57:33.132 -> enters the cycle, cycle time: 
15:57:33.179 -> 392 ms 
15:57:33.179 -> cntr at cycle start: 15
15:57:33.226 -> cntr:  0
15:57:33.226 -> cntr++    
15:57:33.226 -> cntr:  1

Что может вызвать это?

1 Ответ

4 голосов
/ 18 апреля 2019

Ваш цикл делает это: 

{
  valueArrayUS[cntr]=cm;
    //...
  if ((millis()-startTime>500) || (cntr==15)) { //cycle is ended or buffer full
    //...
  else {
    cntr=cntr+1;
  }
}

После удаления остальной части кода легче понять, что вы:

  1. с использованием cntr
  2. проверка, является ли cntr 15 (то есть после конца массива)
  3. обновление cntr

Это не проблема первые 15 раз до loop(), но после этого 15-го раза cntr становится 15 в конце функции, и при следующем проходе через функцию вы в конечном итоге делаете это: 

valueArrayUS[15]=cm;

Это означает, что вы пишете после конца массива, и похоже, что следующая вещь в памяти после valueArrayUS должна быть cntr, потому что вы, очевидно, записываете это значение.

В этом суть проблемы, но как только это произошло, вы попадете в мир боли, потому что теперь cntr может иметь значение> 15, поэтому ваше условие cntr==15 неверно и теперь loop будет записывать значения датчика далеко после конца valueArrayUS. Это эффективно растопчет всю вашу память, и то, какая именно память будет перезаписана во время данного прогона, будет зависеть от того, что считывает датчик.

Чтобы исправить, вам нужно изменить порядок действий:

  1. проверить, находится ли cntr в границах
  2. , если это не так, то сделайте свой расчет и сбросьте cntr
  3. , если cntr в границах, то вы можете прочитать датчик, сохранить значение и обновить cntr

Кроме того, используйте защитный код:

  • изменить ваше состояние с cntr == 15 на cntr > 14 или cntr >= 15
  • объявляйте ваши другие переменные цикла, i и j, локально, например: for (int i...
...