Как получить полезные показания акселерометра - PullRequest
Новая
       10

Как получить полезные показания акселерометра

1 голос
/ 25 июня 2019

У меня есть устройство на базе Arduino (Teensy 3.2), и я пытаюсь считывать данные с отладочной платы акселерометра H3LIS331DL. Я могу записывать в регистры управления на акселерометре и считывать данные из регистров данных, но у меня возникают проблемы с получением стабильных, полезных данных.

Во-первых, полезные данные. В паспорте на микросхему акселерометра просто сказано для регистров данных: «Данные ускорения по оси X. Значение выражается в виде дополнения к двум». В библиотеке SparkFun LIS331 говорится: «Выходные данные - это 12-битные данные, выровненные по левому краю, поэтому младшие четыре бита данных всегда равны нулю». Если данные равны 12 битам на ось, я бы предположил, что вывод (должным образом обусловленный) должен быть 0-4095 с нулевым значением G, равным 2048, но это не соответствует тому, что я получаю. Сейчас, когда акселерометр неподвижно сидит за моим столом, оси X и Y дают показания на верхнем и нижнем уровнях (0-19 или 4063-4095), а ось Z показывает значения 9-80 (всегда ниже 2048 в любая ориентация).

Мои ожидания в отношении данных неверны или я что-то делаю, чтобы не получить правильные данные?

Во-вторых, стабильные данные. Низкое значение этого акселерометра составляет +/- 100G. Мой текущий стендовый тест составляет от -1G до + 1G (1% от полного диапазона), поэтому я ожидаю, что выходные данные будут иметь пропорционально небольшой диапазон, но выходной диапазон только из постоянной позиции уже составляет почти 2% от полного шкала.

Что я могу сделать, чтобы получить более стабильные выходные данные? 

#include <i2c_t3.h>

#define ACCEL_NEW_PIN    16

#define CTRL_REG1        0x20
#define CTRL_REG2        0x21
#define CTRL_REG3        0x22
#define CTRL_REG4        0x23
#define OUT_X_L          0x28
#define OUT_X_H          0x29
#define OUT_Y_L          0x2A
#define OUT_Y_H          0x2B
#define OUT_Z_L          0x2C
#define OUT_Z_H          0x2D

#define accelAddress     0x19

volatile bool accelNew = true;
int16_t x, y, z;

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println("hello, world!");
  accelSetup();
}

void loop(){
  if(accelNew){
    getAccel(x, y, z);
    Serial.println(x);
    Serial.println(y);
    Serial.println(z);
    accelNew = false;
  }
}

void accelSetup(){
  Wire.begin(I2C_MASTER, 0x00, I2C_PINS_18_19, I2C_PULLUP_EXT, 1800000, I2C_OP_MODE_IMM);
  writeAccel(CTRL_REG1, B00111111); //normal mode, 1000Hz, X, Y and Z enabled
  writeAccel(CTRL_REG2, B00110000); //high pass filter enabled
  writeAccel(CTRL_REG3, B00000010); //Data ready output pin enabled
  writeAccel(CTRL_REG4, B10000000); //Block data update enabled, 100G range
  pinMode(ACCEL_NEW_PIN,INPUT);
  attachInterrupt(digitalPinToInterrupt(ACCEL_NEW_PIN), accelISR, RISING);
}

void accelISR(){
  accelNew = true;
}

void getAccel(int16_t& xAccel, int16_t& yAccel, int16_t& zAccel){
  uint8_t data[6];
  readAccel(OUT_X_L, data, 6);
  xAccel = (data[0] | data[1] << 8) >> 4;
  yAccel = (data[2] | data[3] << 8) >> 4;
  zAccel = (data[4] | data[5] << 8) >> 4;
}

void readAccel(byte address, byte* data, uint8_t bytes)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address | 0x80);//
  Wire.sendTransmission();
  Wire.sendRequest(accelAddress, bytes);
  while(Wire.available()) *(data++) = Wire.readByte();
}

void writeAccel(byte address, byte data)
{
  Wire.beginTransmission(accelAddress);
  Wire.write(address);
  Wire.write(data);
  Wire.endTransmission();
}

1 Ответ

2 голосов
/ 26 июня 2019

Я в основном нашел ответ на свой вопрос.Байты регистра данных do должны быть объединены так, как я это сделал, и имеют сдвиг вправо, но это должен быть сдвиг вправо со знаком , тогда как мой код составлял без знака смещение вправо.Знаковый бит неправильно истолковывался как бит значения и отправлял полученное значение в верхнюю часть диапазона всякий раз, когда число должно было быть отрицательным.Приведение объединенных беззнаковых байтов в виде со знаком int до сдвига решило эту проблему и сделало выходные данные более понятными.

xAccel = (int16_t)(data[0] | data[1] << 8) >> 4;

Хорошая новость заключается в том, что все 3 оси теперь дают значимые данные с одинаковым линейным наклоном в зависимости от ориентации.

Плохая новость заключается в том, что каждая ось имеет различное смещениеот 0 до 0G, и каждая ось по-прежнему имеет дисперсию / дрожание около +/- 18 от среднего значения (что выше, чем хотелось бы).

...