Ошибка 1004 во время выполнения не может установить видимое свойство класса DrawingObjects

Question

Так что код работал до недавнего обновления, однако моя ИТ-команда не может выяснить, что является причиной ошибки.Мне интересно, есть ли Ссылка, которую я пропускаю, или это что-то еще.Основной код приведен на листе 1, а функция - в модуле 1.

Я провел небольшое исследование со ссылками, и в настоящее время выбрано все: Visual Basic для приложений, библиотека объектов MS Excel 16.0, OLEАвтоматизация, библиотека объектов MS Office 16.0, библиотека объектов MS Forms 2.0, MS VBScript Reg Exp 1.0 и 5.5, библиотека объектов MS Outlook 16.0.

Private Sub ToggleButton1_Click()
Dim rng As Range
Dim OutApp As Outlook.Application
Dim OutMail As Outlook.MailItem

Set rng = Nothing
On Error Resume Next
'Only the visible cells in the selection
Set rng = Selection.SpecialCells(xlCellTypeVisible)
'You can also use a fixed range if you want
Set rng = Sheets("Sheet1").Range("A1:H15").SpecialCells(xlCellTypeVisible)
On Error GoTo 0

If rng Is Nothing Then
    MsgBox "The selection is not a range or the sheet is protected" & _
           vbNewLine & "please correct and try again.", vbOKOnly
    Exit Sub
End If

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

On Error Resume Next
With OutMail
    .To = "compliance.data@rheem.com"
    .CC = ""
    .BCC = ""
    .Subject = "NEW VENDOR SETUP"
    .HTMLBody = RangetoHTML(rng)
    .Display   'or use .Display
End With
On Error GoTo 0

With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing
End Sub

КОД МОДУЛЯ 1:

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook

TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
    .Cells(1).PasteSpecial Paste:=8
    .Cells(1).PasteSpecial xlPasteValues, , False, False
    .Cells(1).PasteSpecial xlPasteFormats, , False, False
    .Cells(1).Select
    Application.CutCopyMode = False
    On Error Resume Next
    .DrawingObjects.Visible = True
    .DrawingObjects.Delete
    On Error GoTo 0
End With

'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
     SourceType:=xlSourceRange, _
     Filename:=TempFile, _
     Sheet:=TempWB.Sheets(1).Name, _
     Source:=TempWB.Sheets(1).UsedRange.Address, _
     HtmlType:=xlHtmlStatic)
    .Publish (True)
End With

'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                      "align=left x:publishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function

Ошибка появляется на .DrawingObjects.Visible = True, и я не уверен, почему.

Answer 1

Это предположение, но оно помогло мне в работе с электронной таблицей.

Если на вашем листе нет рисованных объектов, вы можете получить ошибку.Попробуйте заменить этот бит на:

On Error Resume Next
If .DrawingObjects.Count > 0 Then
    .DrawingObjects.Visible = True
    .DrawingObjects.Delete
End If    
On Error GoTo 0

Я также, вероятно, удалил бы биты On Error, но посмотрите, работает ли вышеперечисленное ...