Butterknife не работает в подпроекте динамических функций: ошибка: пакет R2 не существует

Question

Я перевожу приложение, чтобы использовать динамическую доставку, а модуль динамических функций и Butterknife больше не работает с новой конфигурацией.

В настоящее время Butterknife работает в базовом модуле :app, он также работаетв стандартных модулях библиотеки отмечены apply plugin: 'com.android.library'.Проблема только в моем новом модуле динамических функций, помеченном plugin: 'com.android.dynamic-feature '.

Вот мой файл gradle уровня проекта:

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        jcenter()

    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.1'
        classpath 'com.jakewharton:butterknife-gradle-plugin:10.1.0'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
}

Теперь мой файл gradle базового приложения (здесь, в :app butternife работает с R как обычно)

apply plugin: 'com.android.application'

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "com.elksa.ddsample"
        minSdkVersion 17
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    bundle {
        language {
            enableSplit = true
        }
        density {
            enableSplit = true
        }
        abi {
            enableSplit = true
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    dynamicFeatures = [":images"]
}

dependencies {
    api 'androidx.lifecycle:lifecycle-extensions:2.0.0'
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    api 'androidx.appcompat:appcompat:1.0.2'
    api 'androidx.constraintlayout:constraintlayout:1.1.3'

    // Butter Knife
    api 'com.jakewharton:butterknife:10.1.0'
    annotationProcessor 'com.jakewharton:butterknife-compiler:10.1.0'

    // Dynamic features
    implementation 'com.google.android.play:core:1.6.1'

    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test:runner:1.2.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.2.0'
}

Наконец, вот файл gradle моего модуля динамических функций, где Butterknife не работает, привязка с R дает мне ссылку null, как и ожидалось, и R2 полностью отсутствует.

apply plugin: 'com.android.dynamic-feature'
apply plugin: 'com.jakewharton.butterknife'

android {
    compileSdkVersion 28

    defaultConfig {
        minSdkVersion 21
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation project(':app')
}

Наконец, вот что я получаю в своем модуле динамических функций, когда пытаюсь использовать нож (error: package R2 does not exist)

Есть идеи?Заранее спасибо!

Answer 1

в вашем "динамическом элементе" модуль build.gradle файл, добавьте также

// Нож для масла

    api 'com.jakewharton:butterknife:10.1.0'

    annotationProcessor 'com.jakewharton:butterknife-compiler:10.1.0'

apply plugin: 'com.android.dynamic-feature'
apply plugin: 'com.jakewharton.butterknife'

android {
  compileSdkVersion 28

  defaultConfig {
    minSdkVersion 21
    targetSdkVersion 28
    versionCode 1
    versionName "1.0"
   }
 }

  dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation project(':app')

    // Butter Knife
    api 'com.jakewharton:butterknife:10.1.0'
    annotationProcessor 'com.jakewharton:butterknife-compiler:10.1.0'
  }