Нет вывода какого-либо тега XSLT 1.0 - PullRequest
Новая
       12

Нет вывода какого-либо тега XSLT 1.0

1 голос
/ 13 июня 2019

Как вывести значение NUMBER для каждого GRP/ADD/CONTACT, где КВАЛИФЕР = ЭМ?

Правильный вывод должен быть: test@test.de. Пожалуйста, найдите мои XML и XSLT в приложении:

XML: 

<?xml version="1.0"?>
<TEST>
  <CNT>
    <GRP>
      <ADD>
        <QUALIFIER>DP</QUALIFIER>
        <PARTY_NAME_1>Vorname Nachname</PARTY_NAME_1>
        <STREET_1>Strasse 1</STREET_1>
        <CITY>Ort</CITY>
        <POSTAL_CODE>12345</POSTAL_CODE>
        <COUNTRY_CODE>DE</COUNTRY_CODE>
        <CONTACT>
          <QUALIFIER>TE</QUALIFIER>
          <NUMBER>4657</NUMBER>
        </CONTACT>
        <CONTACT>
          <QUALIFIER>EM</QUALIFIER>
          <NUMBER>test2@test.de</NUMBER>
        </CONTACT>
      </ADD>
      <ADD>
        <QUALIFIER>ST</QUALIFIER>
        <PARTY_NAME_1>Vorname Nachname</PARTY_NAME_1>
        <STREET_1>Strasse 1</STREET_1>
        <CITY>Ort</CITY>
        <POSTAL_CODE>12345</POSTAL_CODE>
        <COUNTRY_CODE>DE</COUNTRY_CODE>
        <CONTACT>
          <QUALIFIER>TE</QUALIFIER>
          <NUMBER>12345</NUMBER>
        </CONTACT>
        <CONTACT>
          <QUALIFIER>EM</QUALIFIER>
          <NUMBER>test@test.de</NUMBER>
        </CONTACT>
      </ADD>
    </GRP>
  </CNT>
</TEST>

XSLT: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="GRP">
      <xsl:copy>
        <xsl:for-each select ="./ADD/CONTACT[QUALIFIER='ST']">
          <xsl:if test="./QUALIFIER='EM'">
            <CONTACT_EMAIL>
              <xsl:value-of select="NUMBER"/>
            </CONTACT_EMAIL>
          </xsl:if>
        </xsl:for-each>
        <!--copy all other nodes -->
        <xsl:apply-templates select="@* | node()" />
      </xsl:copy>
    </xsl:template>

    <!-- delete empty nodes -->
    <xsl:template match="node()|@*">
      <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>
    <xsl:template match="*[not(@*|*|comment()|processing-instruction()) and normalize-space()='']"/>
    <!-- delete empty nodes -->
</xsl:stylesheet>

Я тоже пробовал это:

<xsl:for-each select ="./ADD/CONTACT"> вместо <xsl:for-each select ="./ADD/CONTACT[QUALIFIER='ST']">, но там я получаю все данные со значением «число» (из классификатора DP и ST), но мне нужно только из классификатора ST.

Ответы [ 3 ]

1 голос
/ 14 июня 2019

Если это тот результат, который вы хотите, вы можете сделать просто: 

<xsl:template match="GRP">
    <xsl:copy>
        <xsl:for-each select ="ADD[QUALIFIER='ST']/CONTACT[QUALIFIER='EM']">
            <CONTACT_EMAIL>
                <xsl:value-of select="NUMBER"/>
            </CONTACT_EMAIL>
        </xsl:for-each>
        <!--copy all other nodes -->
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>
1 голос
/ 13 июня 2019

У вас в XSLT дважды есть шаблон идентификации (<xsl:template match="@* | node()">), вы можете удалить второй.

При этом ваша логика выглядит следующим образом 

<xsl:for-each select ="./ADD/CONTACT[QUALIFIER='ST']">
  <xsl:if test="./QUALIFIER='EM'">
    <CONTACT_EMAIL>
      <xsl:value-of select="NUMBER"/>
    </CONTACT_EMAIL>
  </xsl:if>
</xsl:for-each>

Этоне может работатьСудя по вашему примеру XML, не может быть <CONTACT> с квалификатором, равным ST, который также имеет квалификатор, равный EM.

Вы, вероятно, имеете в виду это:

<xsl:for-each select ="ADD/CONTACT[QUALIFIER='EM']">
  <CONTACT_EMAIL>
    <xsl:value-of select="NUMBER"/>
  </CONTACT_EMAIL>
</xsl:for-each>

Примечания

  • Я не уверен, что ваш вызов "копировать все остальные узлы" в <xsl:apply-templates select="@* | node()" /> - это то, что вам нужно.Я бы сказал, что это не так.
  • Запись ./ избыточна в XPath.Каждый путь, который не начинается в корне документа, по умолчанию относится к текущему узлу по умолчанию.
0 голосов
/ 14 июня 2019 
<xsl:template match="GRP">
  <xsl:copy>
    <xsl:for-each select ="./ADD[QUALIFIER='ST']">
      <xsl:if test="./CONTACT/QUALIFIER='EM'">
        <CONTACT_EMAIL>
          <xsl:value-of select="CONTACT[QUALIFIER='EM']/NUMBER"/>
        </CONTACT_EMAIL>
      </xsl:if>
    </xsl:for-each>
    <!--copy all other nodes -->
    <xsl:apply-templates select="@* | node()" />
  </xsl:copy>
</xsl:template>

Результат: 

<TEST>
  <CNT>
      <GRP>
         <CONTACT_EMAIL>test@test.de</CONTACT_EMAIL>
         <ADD>
            <QUALIFIER>DP</QUALIFIER>
            <PARTY_NAME_1>Vorname Nachname</PARTY_NAME_1>
            <STREET_1>Strasse 1</STREET_1>
            <CITY>Ort</CITY>
            <POSTAL_CODE>12345</POSTAL_CODE>
            <COUNTRY_CODE>DE</COUNTRY_CODE>
            <CONTACT>
               <QUALIFIER>TE</QUALIFIER>
               <NUMBER>4657</NUMBER>
            </CONTACT>
            <CONTACT>
               <QUALIFIER>EM</QUALIFIER>
               <NUMBER>test2@test.de</NUMBER>
            </CONTACT>
         </ADD>
         <ADD>
            <QUALIFIER>ST</QUALIFIER>
            <PARTY_NAME_1>Vorname Nachname</PARTY_NAME_1>
            <STREET_1>Strasse 1</STREET_1>
            <CITY>Ort</CITY>
            <POSTAL_CODE>12345</POSTAL_CODE>
            <COUNTRY_CODE>DE</COUNTRY_CODE>
            <CONTACT>
               <QUALIFIER>TE</QUALIFIER>
               <NUMBER>12345</NUMBER>
            </CONTACT>
            <CONTACT>
               <QUALIFIER>EM</QUALIFIER>
               <NUMBER>test@test.de</NUMBER>
            </CONTACT>
         </ADD>
      </GRP>
  </CNT>
</TEST>
...