Есть ли способ выйти из каждого цикла сразу после того, как условие станет истинным? - PullRequest
Новая
       11

Есть ли способ выйти из каждого цикла сразу после того, как условие станет истинным?

1 голос
/ 27 марта 2019

Мне нужно выйти для каждого цикла сразу же, как только условие становится истинным.и хотите вернуть текущий индекс, где разрывы цикла.ниже мой пример xml и xslt 

<xsl:stylesheet xmlns:xalan="http://xml.apache.org/xalan" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
    <xsl:template match="Data">
        <xsl:element name="Data">
            <xsl:call-template name="TempData" />
        </xsl:element>
    </xsl:template>
    <xsl:template name="TempData">
        <xsl:element name="TempData">
            <xsl:for-each select="/Data/Subject/SubTest">
                    <xsl:choose>
                        <xsl:when test="@System='OK' and @SubFlag!='1'">
                            <xsl:attribute name="CurrentSubFlag">
                                <xsl:value-of select="position()" />
                            </xsl:attribute>
                        </xsl:when>
                    </xsl:choose>
                </xsl:for-each>
            <xsl:copy-of select="TempData/*" />
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

<Data>
    <Subject>
        <SubTest SubFlag="1" System="OK"> </SubTest>
        <SubTest SubFlag="csdcd" System="OK"> </SubTest>
        <SubTest SubFlag="zxczx" System="OK"> </SubTest>  
    </Subject>
    <TempData CurrentSubFlag="abc"/>
</Data>

выходной xml должен быть 

<Data>
    <Subject>
        <SubTest SubFlag="1" System="OK"> </SubTest>
        <SubTest SubFlag="csdcd" System="OK"> </SubTest>
        <SubTest SubFlag="zxczx" System="OK"> </SubTest>  
    </Subject>
    <TempData CurrentSubFlag="2"/>
</Data>

, если вход 

<Data>
    <Subject>
        <SubTest SubFlag="1" System="OK"> </SubTest>
        <SubTest SubFlag="1" System="OK"> </SubTest>
        <SubTest SubFlag="1" System="OK"> </SubTest>  
    </Subject>
    <TempData CurrentSubFlag="abc"/>
</Data>

, тогда выход будет тот же CurrentSubFlag = "abc«

Ответы [ 2 ]

3 голосов
/ 27 марта 2019

xsl:for-each не является циклом, и требуемый результат может быть достигнут без цикла или рекурсии.

Дано:

XML 

<Data>
    <Subject>
        <SubTest SubFlag="1" System="OK"> </SubTest>
        <SubTest SubFlag="csdcd" System="OK"> </SubTest>
        <SubTest SubFlag="zxczx" System="OK"> </SubTest>  
    </Subject>
    <TempData CurrentSubFlag="abc"/>
</Data>

следующая таблица стилей:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="TempData">
    <xsl:variable name="index" select="count(/Data/Subject/SubTest[not(@SubFlag=1 and @System='OK')][1]/preceding-sibling::SubTest) + 1" />
    <TempData CurrentSubFlag="{$index}"/>
</xsl:template>

</xsl:stylesheet>

вернет:

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<Data>
  <Subject>
    <SubTest SubFlag="1" System="OK"/>
    <SubTest SubFlag="csdcd" System="OK"/>
    <SubTest SubFlag="zxczx" System="OK"/>
  </Subject>
  <TempData CurrentSubFlag="2"/>
</Data>

Добавлено:

Чтобы учесть добавленные вами условия, попробуйте: 

<xsl:template match="TempData">
    <xsl:variable name="fail" select="/Data/Subject/SubTest[not(@SubFlag=1 and @System='OK')]" />
    <xsl:choose>
        <xsl:when test="$fail">
            <TempData CurrentSubFlag="{count($fail[1]/preceding-sibling::SubTest) + 1}"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy-of select="."/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
0 голосов
/ 27 марта 2019

То, что вы спрашиваете, эквивалентно циклу while. Это можно сделать с помощью рекурсивного шаблона, имеющего переменную (см. Как создать цикл типа "пока" в XSLT? или http://www.humbug.in/2010/a-sample-loop-in-xsl-alternative-for-while-for-loops-2/).

В псевдокоде: 

function findFirst(elements)
    foreach element in elements
        if test(element)
            return element

Так же, как: 

function findFirst(elements, offset)
    element = elements[offset]
    if test(element)
        return element
    else
        return findFirst(elements, offset + 1)

последнее можно сделать с помощью рекурсивных шаблонов (см. Ссылки)

(Примечание: код предполагает, что элемент существует)

...