XSLT 1.0 (xsltproc) - есть ли способ применить условную подстроку? - PullRequest
Новая
       14

XSLT 1.0 (xsltproc) - есть ли способ применить условную подстроку?

0 голосов
/ 14 июня 2019

Как применить условную подстроку с использованием XSLT 1.0? Я использую процессор xsltproc.

Input.xml 

<testng-results>
    <suite>
        <test>
            <class>
                <test-method status="PASS" description="Test_ID:123,Test_Name:Test ABC,Category:Category ABC, Feature_ID:12345"></test-method>
                <test-method status="PASS" description="Test_ID:456,Test_Name:Test XYZ,Category:Category XYZ"></test-method>
            </class>
        </test>
    </suite>
</testng-results>

Мой текущий XSL: 

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/testng-results">
        <Suite>
            <xsl:for-each select="suite/test/class/test-method">
                <test
                        status="{@status}"
                        Test_ID="{substring-before(substring-after(@description, 'Test_ID:'), ',') }"
                        Test_Name="{substring-before(substring-after(@description, 'Test_Name:'), ',') }"
                        Category="{substring-before(substring-after(@description, 'Category:'), ',') }"
                        Feature_ID="{substring-after(@description, 'Feature_ID:')}"/>
            </xsl:for-each>
        </Suite>
    </xsl:template>
</xsl:stylesheet>

Current Output.xml (проблема в том, что «Category» и «Feature_ID» пустые для второй строки): 

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <test status="PASS" Test_ID="123" Test_Name="Test ABC" Category="Category ABC" Feature_ID="12345"/>
  <test status="PASS" Test_ID="456" Test_Name="Test XYZ" Category="" Feature_ID=""/>
</Suite>

Желаемый выход.xml 

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <test status="PASS" Test_ID="123" Test_Name="Test ABC" Category="Category ABC" Feature_ID="12345"/>
  <test status="PASS" Test_ID="456" Test_Name="Test XYZ" Category="Category XYZ" Feature_ID=""/>
</Suite>

1 Ответ

1 голос
/ 14 июня 2019

Вы можете сделать:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class/test-method">
            <xsl:variable name="description" select="concat(@description, ',')" />
            <test
                status="{@status}"
                Test_ID="{substring-before(substring-after($description, 'Test_ID:'), ',')}"
                Test_Name="{substring-before(substring-after($description, 'Test_Name:'), ',')}"
                Category="{substring-before(substring-after($description, 'Category:'), ',')}"
                Feature_ID="{substring-before(substring-after($description, 'Feature_ID:'), ',')}"/>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

Таким образом, вы не зависите от порядка подстрок в description.

...