XSLT 1.0 (xsltproc) - вывод только последнего дублированного узла - PullRequest
Новая
       15

XSLT 1.0 (xsltproc) - вывод только последнего дублированного узла

0 голосов
/ 18 мая 2019

Как вывести только последний дублирующий узел, используя XSLT 1.0?Я использую процессор xsltproc.

Input.xml 

<testng-results>
    <suite>
        <test>
            <class name="system.apps.CreateTerritory">
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="FAIL"  name="ABC"> </test-method>
            </class>
            <class name="system.apps.CreateAccount">
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="SKIP"  name="DEF"> </test-method>
                <test-method status="PASS"  name="initTest" is-config="true"> </test-method>
                <test-method status="FAIL"  name="DEF"> </test-method>
            </class>
        </test>
    </suite>
</testng-results>

My Current XSL: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:str="http://exslt.org/strings" extension-element-prefixes="str" version="1.0">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />
    <xsl:strip-space elements="*" />
    <xsl:template match="/">
        <Suite>
            <xsl:for-each select="testng-results/suite/test/class">
                 <xsl:for-each select="test-method">
                     <xsl:if test="not(@is-config)">
                             <Test>
                                 <Method_Name>
                                     <xsl:value-of select="@name"/>
                                 </Method_Name>
                                 <Status>
                                     <xsl:value-of select="@status"/>
                                 </Status>
                             </Test>
                     </xsl:if>
                 </xsl:for-each>
            </xsl:for-each>
        </Suite>
    </xsl:template>
</xsl:stylesheet>

Примечание: я не могу изменить способ выполнения вложенного соответствия(для каждого класса, а затем для каждого метода тестирования, так как мне нужно быть таким по другим причинам)

Current Output.xml: 

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Method_Name>ABC</Method_Name>
    <Status>FAIL</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>SKIP</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>FAIL</Status>
  </Test>
</Suite>

Ожидаемый Output.xml (толькопоследний узел выводится для каждого дублирующего метода тестирования): 

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Method_Name>ABC</Method_Name>
    <Status>FAIL</Status>
  </Test>
  <Test>
    <Method_Name>DEF</Method_Name>
    <Status>FAIL</Status>
  </Test>
</Suite>

1 Ответ

1 голос
/ 18 мая 2019

Если вы используете xsltproc (то есть процессор libxslt), вы можете воспользоваться функцией расширения EXSLT set:distinct(), чтобы использовать сокращенную версию мюнхенской группировки :

XSLT 1.0 (+ EXSLT) 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:set="http://exslt.org/sets"
extension-element-prefixes="set">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="test-by-name" match="test-method[not(@is-config)]" use="@name" />

<xsl:template match="/testng-results">
    <xsl:variable name="tests" select="suite/test/class/test-method[not(@is-config)]" />
    <Suite>
        <xsl:for-each select="set:distinct($tests/@name)">
            <Test>
                <Method_Name>
                    <xsl:value-of select="."/>
                </Method_Name>
                <Status>
                    <xsl:value-of select="key('test-by-name', .)[last()]/@status"/>
                </Status>
            </Test>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

Или, если хотите, вы можете сделать это в чистом XSLT 1.0 как:

XSLT 1.0 

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="test-by-name" match="test-method[not(@is-config)]" use="@name" />

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class/test-method[not(@is-config)][count(. | key('test-by-name', @name)[last()]) = 1]">
            <Test>
                <Method_Name>
                    <xsl:value-of select="."/>
                </Method_Name>
                <Status>
                    <xsl:value-of select="@status"/>
                </Status>
            </Test>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

Обратите внимание на использование предиката [last()] вместо обычного [1].

...