Могу ли я обернуть форму доступа транзакцией?

Question

Я хочу сделать форму, которая по существу создает счет, но использует некоторые другие связанные данные в качестве входных данных или ограничений; В процессе добавления товаров в накладную мне нужно уменьшить количество предметов в другой таблице. Поскольку пользователь будет вводить несколько элементов одновременно, я хотел бы выдать «START TRANSACTION» при загрузке формы, а затем выполнить «COMMIT» при обновлении формы. Таким образом, если они отменяют форму, другие связанные таблицы (показанные через подчиненные формы) будут возвращаться к предыдущим значениям.

Answer 1

Не может быть сделано с использованием связанных форм. Вы можете использовать временные таблицы для хранения данных, а затем обновить основные таблицы. Немного круто, но я делал это в прошлом.

См. Страницу TempTables.MDB на моем веб-сайте , на которой показано, как использовать временный MDB в вашем приложении.

Answer 2

Да, это можно сделать, чтобы взять под контроль транзакцию в нужной вам форме, используйте этот код:

Private Sub Form_Open(Cancel As Integer)
    Set Me.Recordset = CurrentDb.OpenRecordset("NAME_OF_YOUR_TABLE_OR_QUERY")
End Sub

После этого вы можете использовать DBEngine для управления транзакцией.

Это работает для меня (я использую Access 2007)

Примечание. Если вы вставляете новую запись, используя интерфейс формы, она отображается при возникновении события Form_AfterInsert, поэтому вы можете использовать DbEngine.Rollback в этом событии, чтобы отменить изменения.

Answer 3

Я понял, что возможно иметь его на связанных формах. Все, что вам нужно назначить переменную, которая содержит идентификационный номер на событие изменения любого из родительского элемента управления. Затем вам нужно передать это значение идентификатора в связанное поле подчиненной формы и выполнить транзакцию как для основной, так и для подчиненной форм. Вот пример того, как я это сделал.

Primary Form VBA

Option Compare Database
Option Explicit

Private boolFrmDirty As Boolean
Private boolFrmSaved As Boolean

Private Sub EmpolyeesID_Change()
Dim ordID As Integer
Dim subFormOrdID As Object

Set subFormOrdID = Forms!Order.OrderInstallation.Form!OrderID

ordID = Me.Form!OrderID

subFormOrdID.DefaultValue = ordID

End Sub

Private Sub Form_AfterDelConfirm(Status As Integer)
    If Me.Saved = False Then Me.Saved = (Status = acDeleteOK)
End Sub
Private Sub Form_AfterUpdate()
    Me.Saved = True
End Sub
Private Sub Form_Delete(Cancel As Integer)
    If Me.Dirtied = False Then DBEngine.BeginTrans
    Me.Dirtied = True
End Sub
'Check if form has got new values in it
Private Sub Form_Dirty(Cancel As Integer)
    If Me.Dirtied = False Then DBEngine.BeginTrans
    Me.Dirtied = True
End Sub
'Open Form as a Record Set and set the variables for it
Private Sub Form_Open(Cancel As Integer)
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Set db = CurrentDb
    Set rs = db.OpenRecordset("SELECT * FROM Orders", dbOpenDynaset, dbAppendOnly)
    Set Me.Recordset = rs
End Sub
Private Sub Form_Unload(Cancel As Integer)
    Dim msg As Integer
    If Me.Saved Then
        msg = MsgBox("Do you want to commit all changes?", vbYesNoCancel)
        Select Case msg
            Case vbYes
                DBEngine.CommitTrans
            Case vbNo
                DBEngine.Rollback
            Case vbCancel
                Cancel = True
        End Select
    Else
        If Me.Dirtied Then DBEngine.Rollback
    End If
End Sub

Public Property Get Dirtied() As Boolean
    Dirtied = boolFrmDirty
End Property

Public Property Let Dirtied(boolFrmDirtyIn As Boolean)
    boolFrmDirty = boolFrmDirtyIn
End Property

Public Property Get Saved() As Boolean
    Saved = boolFrmSaved
End Property

Public Property Let Saved(boolFrmSavedIn As Boolean)
    boolFrmSaved = boolFrmSavedIn
End Property

Private Sub ProductID_AfterUpdate()
'Calculations of VAT and Floor Price
Dim clcVAT As Integer
Dim sqlQry As String
Dim instID As Integer

instID = Me.Form!ProductID.Value

sqlQry = "SELECT Products.Price FROM Products WHERE Products.ProductID =" & instID & ""

Me.flPrice.RowSource = sqlQry

End Sub

Sub Form VBA 

Option Compare Database
Option Explicit
'Transaction for sub-form
Private Sub Form_Open(Cancel As Integer)
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Set db = CurrentDb
    Set rs = db.OpenRecordset("SELECT * FROM OrderInstallation")
    Set Me.Recordset = rs
End Sub
Private Sub Form_AfterUpdate()
    Dim emplID As Object
    Dim cstmID As Object
    Dim prdcID As Object
    Dim DataArray As Variant
    Dim RqrdFieldErorr As String
    Dim qry As String

    Set emplID = Me.Parent!EmpolyeesID
    Set cstmID = Me.Parent!CustomerID
    Set prdcID = Me.Parent!ProductID

    If IsNull(emplID.Value) Or IsNull(cstmID.Value) Or IsNull(prdcID.Value) Then
        MsgBox ("Please enter select required fields first")

        Else
    End If
End Sub
'Restrict updates of Installation subform if Employee, Customer and Product is not selected
Private Sub InstallationID_AfterUpdate()
    Dim instID As Integer
    Dim instPrice As Integer
    Dim strQry As String

    ' Create query based on InstallationID value
    instID = InstallationID.Value
    strQry = "SELECT Installation.Price, Installation.InstallationID FROM Installation WHERE Installation.InstallationID =" & instID & ""
    Me.Price.RowSource = strQry
End Sub