Add / Tween / Remove - несколько экземпляров одного и того же MC (Tweenlite) - PullRequest
Новая
       14

Add / Tween / Remove - несколько экземпляров одного и того же MC (Tweenlite)

1 голос
/ 12 ноября 2009

Я пытаюсь создать простой цикл, который добавляет случайное количество звезд, затемняет их и удаляет их.

Сценарий, который я придумал, делает все, кроме удаления их, и, возможно, мне нужно меньше при добавлении детей на сцену.

Вот что я придумала 

import flash.display.*;
import com.greensock.*;
import com.greensock.easing.*;

// timer setup
var timer:Timer=new Timer(randomNumber(500,1000));
timer.addEventListener(TimerEvent.TIMER,run_stars);
timer.start();

// Random number generator
function randomNumber(low:Number=NaN, high:Number=NaN):Number {
  var low:Number = low;
  var high:Number = high;
  if(isNaN(low)) { throw new Error("no low number"); }
  if(isNaN(high)) { throw new Error("no high number"); }
  return Math.round(Math.random() * (high - low)) + low;
}

// randomly adding stars on timer
function run_stars(event:TimerEvent):void {
    // random num of stars
    for (var i:Number=1; i<=randomNumber(2,7);i++) {

            var star:m_star = new m_star();
            addChild(star);

            // This is where my problem starts, I'm adding the same movie clip multiple times without any way to identify and remove. 


            star.x = randomNumber(0, stage.stageWidth);
            star.y = randomNumber(0,stage.stageHeight/2);

            TweenLite.to(star, randomNumber(0.5,1), {alpha:0.25, onComplete:removeStar()});

    }

    timer.delay = randomNumber(500,1000);
    timer.start();
}

function removeStar() {
    removeChild(star);
    //this would be where I attempt to remove a star but because they aren't unique it will never work, and the star movie clip is called inside of the function so it cant even see it. 
    }

stop();

Мне нужен способ сделать видеоклипы уникальными, чтобы я мог сказать своей функции oncomplete удалить клип свойства, если я этого не сделаю, фильм в конечном итоге замедлится и вылетит из-за большого количества (невидимых) фрагментов ролика.

Спасибо!

Ответы [ 2 ]

3 голосов
/ 12 ноября 2009

Передайте мувиклип как параметр функции onComplete: 

TweenLite.to(star, randomNumber(0.5,1), {
    alpha:0.25,
    onComplete:removeStar, 
    onCompleteParams:[star]
});

function removeStar(mc:MovieClip):void
{
    if (contains(mc))
    {
        removeChild(mc);
    }
}
1 голос
/ 04 декабря 2009

Заметил ошибку здесь: 

for (var i:Number=1; i<=randomNumber(2,7);i++) {

Это будет вызывать случайное число от 2 до 7 каждый раз, когда оно проходит цикл. У вас будет наклон к 1 или 2 звездам, а не к 5 или 6. 1004 * 

var len:int = randomNumber(2, 7);
for (var i:int = 1; i <= len; i++) {

, вероятно, ближе к работе, чем вы хотели.

...