оптимизация ранцев с динамическими переменными - PullRequest
Новая
       147

оптимизация ранцев с динамическими переменными

0 голосов
/ 03 сентября 2018

Я пытаюсь решить проблему оптимизации, она очень похожа на проблему ранца, но ее невозможно решить с помощью динамического программирования. Проблема, которую я хочу решить, очень похожа на эту:

enter image description here

enter image description here

enter image description here enter image description here

1 Ответ

0 голосов
/ 04 сентября 2018

действительно, вы можете решить эту проблему с помощью CPLEX. Позвольте мне показать вам, что в OPL.

Модель (.mod) 

{string} categories=...;

{string} groups[categories]=...;

{string} allGroups=union (c in categories) groups[c];

{string} products[allGroups]=...;
{string} allProducts=union (g in allGroups) products[g];

float prices[allProducts]=...;

int Uc[categories]=...;
float Ug[allGroups]=...;

float budget=...;

dvar boolean z[allProducts]; // product out or in ?

dexpr int xg[g in allGroups]=(1<=sum(p in products[g]) z[p]);
dexpr int xc[c in categories]=(1<=sum(g in groups[c]) xg[g]);

maximize 
sum(c in categories) Uc[c]*xc[c]+
sum(c in categories) sum(g in groups[c]) Uc[c]*Ug[g]*xg[g];
subject to
{
ctBudget:
    sum(p in allProducts) z[p]*prices[p]<=budget;
}

{string} solution={p | p in allProducts : z[p]==1};

execute
{
writeln("solution = ",solution);
}

Данные .dat 

categories={Carbs,Protein,Fat};
groups=[{Meat,Milk},{Pasta,Bread},{Oil,Butter}];
products=[
{Product11,Product12},{Product21,Product22,Product23},
{Product31,Product32},{Product41,Product42},
{Product51},{Product61,Product62}];

prices=[1,4,1,3,2,4,2,1,3,1,2,1];

// User 1
Uc=[1,1,0];
Ug=[0.8,0.2,0.1,1,0.01,0.6];
budget=3;

//User 2
//Uc=[1,1,0];
//Ug=[0.8,0.2,0.1,1,0.01,0.6];
//budget=2;

и это дает 

solution =  {"Product11" "Product21" "Product41"}
...