Arduino Wire Library возвращает код ошибки 7 (который не определен в библиотеке) - PullRequest
Новая
       66

Arduino Wire Library возвращает код ошибки 7 (который не определен в библиотеке)

0 голосов
/ 07 сентября 2018

Я использую ESP32 для чтения с IMU, MPU-6050.Я использую код, который доступен на веб-сайте Arduino с небольшими изменениями;Я проверяю код ошибки на endTransmission и печатаю его (я начал это делать, потому что я возвращал все нулевые значения из моих вызовов для чтения регистров MPU).При самом первом вызове для инициализации MPU я получаю код ошибки успеха.Но при каждом вызове после этого я получаю код ошибки 7. Что странно, когда я прослеживаю через библиотеку Wire, я обнаруживаю, что код ошибки 7 не определен.У рассматриваемой функции есть только 4 возможных возвращаемых значения, и 7 не является одним из них.

Вот код целиком.

    #include<Wire.h>
    const int MPU_addr=0x68;  // I2C address of the MPU-6050
    int16_t AcX,AcY,AcZ,Tmp,GyX,GyY,GyZ;
    int initialError;
    void setup(){
      Wire.begin();
      Wire.beginTransmission(MPU_addr);
      Wire.write(0x6B);  // PWR_MGMT_1 register
      Wire.write(0);     // set to zero (wakes up the MPU-6050)
      initialError = Wire.endTransmission(true);
      Serial.begin(9600);

    }
    void loop(){
      int error ;
      Wire.beginTransmission(MPU_addr);
      Wire.write(0x3B);  // starting with register 0x3B (ACCEL_XOUT_H)
      error = Wire.endTransmission(false);
      if(error)
      {
        Serial.print("Errors: ");
        Serial.print(initialError);
        Serial.print(" ");
        Serial.println(error);
      }
      else {
        Wire.requestFrom(MPU_addr,14,true);  // request a total of 14 registers
        AcX=Wire.read()<<8|Wire.read();  // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)    
        AcY=Wire.read()<<8|Wire.read();  // 0x3D (ACCEL_YOUT_H) & 0x3E (ACCEL_YOUT_L)
        AcZ=Wire.read()<<8|Wire.read();  // 0x3F (ACCEL_ZOUT_H) & 0x40 (ACCEL_ZOUT_L)
        Tmp=Wire.read()<<8|Wire.read();  // 0x41 (TEMP_OUT_H) & 0x42 (TEMP_OUT_L)
        GyX=Wire.read()<<8|Wire.read();  // 0x43 (GYRO_XOUT_H) & 0x44 (GYRO_XOUT_L)
        GyY=Wire.read()<<8|Wire.read();  // 0x45 (GYRO_YOUT_H) & 0x46 (GYRO_YOUT_L)
        GyZ=Wire.read()<<8|Wire.read();  // 0x47 (GYRO_ZOUT_H) & 0x48 (GYRO_ZOUT_L)
        Serial.print("AcX = "); Serial.print(AcX);
        Serial.print(" | AcY = "); Serial.print(AcY);
        Serial.print(" | AcZ = "); Serial.print(AcZ);
        Serial.print(" | Tmp = "); Serial.print(Tmp/340.00+36.53);  //equation for temperature in degrees C from datasheet
        Serial.print(" | GyX = "); Serial.print(GyX);
        Serial.print(" | GyY = "); Serial.print(GyY);
        Serial.print(" | GyZ = "); Serial.println(GyZ);
        delay(333);
      }
    }

initialError - ноль (успех), другая ошибка - 7 (?).Кто-нибудь имеет представление о том, что здесь происходит и как исправить?

1 Ответ

0 голосов
/ 07 сентября 2018

Я нашел проблему. Ну, это не проблема, а другая реализация.

EPS32 использует другую реализацию библиотеки Wire. У него есть другие возвращаемые значения, которых нет в пакете с программным обеспечением Arduino. 

                typedef enum {
                    I2C_ERROR_OK=0,
                    I2C_ERROR_DEV,      // 1
                    I2C_ERROR_ACK,     // 2
                    I2C_ERROR_TIMEOUT, // 3
                    I2C_ERROR_BUS,     // 4
                    I2C_ERROR_BUSY,    // 5
                    I2C_ERROR_MEMORY,  // 6
                    I2C_ERROR_CONTINUE,// 7
                    I2C_ERROR_NO_BEGIN // 8
                } i2c_err_t;

Код ошибки 7 означает, что запросы находятся в очереди. Они не были отправлены. Каждый раз, когда вызов Wire :: EndTransmission вызывается с ложным в этой реализации вместо того, чтобы фактически отправлять запрос, запросы просто помещаются в очередь. Когда endTransmission вызывается с true в качестве аргумента (или без qrgument), все запросы отправляются одновременно.

Другим следствием этого различия в реализации является код, который обрабатывает ненулевые значения, поскольку ошибки не обязательно будут работать должным образом, поскольку не все ненулевые значения действительно являются кодами ошибок.

Для моего случая я могу просто использовать Wire :: endTransmission (true). Для других, сталкивающихся с этой проблемой, ваше решение может потребовать дополнительных соображений и возможных изменений в логике.

...