Как убрать нежелательный вывод в VERILOG? - PullRequest
Новая
       75

Как убрать нежелательный вывод в VERILOG?

0 голосов
/ 12 ноября 2018

Я работаю над очень большим модулем, в котором этот модуль умножения и суммирования является небольшой частью, но он поможет мне выразить свой вопрос здесь.

Код RTL: 

module mul_and_add #(parameter BITS = 32,
parameter SHIFT = 15
)

(
  clk,
  i_multiplicand,
  i_multiplier,
  i_adder,
  o_result
);

input clk;
input signed  [BITS-1:0]    i_multiplicand;
input signed  [BITS-1:0]    i_multiplier;
input signed  [BITS-1:0]    i_adder;
output signed [BITS-1:0]    o_result;

reg signed    [2*BITS-1:0]  mul_result;
reg signed    [BITS:0]      add_result;
wire signed   [BITS-1:0]    o_result;

always @(posedge clk)

begin

mul_result <= i_multiplicand * i_multiplier;
add_result <=  i_adder + (mul_result >> SHIFT);

end

assign o_result = add_result[BITS-1:0];

endmodule

Код ТБ: 

module tb_mul_and_add (
                        );

parameter BITS = 32;

reg  clk;
reg  signed [ BITS - 1 : 0 ] i_multiplicand;
reg  signed [ BITS - 1 : 0 ] i_multiplier;
reg  signed [ BITS - 1 : 0 ] i_adder;

wire signed [ BITS - 1 : 0 ] o_result;

mul_and_add mul_and_add_i (
    .clk(clk),
    .i_multiplicand(i_multiplicand),
    .i_multiplier(i_multiplier),
    .i_adder(i_adder),
    .o_result(o_result)
                  );

parameter CLKPERIODE = 10;

initial clk = 1'b1;
always #(CLKPERIODE/2) clk = !clk;

initial begin
  i_multiplicand =  32'h00010000;
  i_multiplier =    32'h00010000;
  i_adder =     32'h00010000;
  #30
  i_multiplicand = 32'h00008000;
  i_multiplier = 32'h00010000;
  i_adder = 32'h00020000;
  #70
  $finish();
end

endmodule

Вывод: Cadence SimVision

Output from Cadence SimVision

Данные, помеченные красным прямоугольником, являются нежелательными данными, от которых я хочу избавиться, потому что, когда я несколько раз использую этот модуль, перед правильным выводится много нежелательных данных. Поэтому, когда мне нужно разобраться в данных, чтобы построить график, нужно многое пройти.

Итак, что за магический трюк, о котором я не знаю, чтобы избавиться от нежелательных данных?

Кроме того, если у вас есть идея для лучшей оптимизации или какой-либо критики, пожалуйста, не стесняйтесь поделиться.

Заранее спасибо.

1 Ответ

0 голосов
/ 12 ноября 2018

Измените код RTL, чтобы сделать mul_result провод, вместо задержки в один цикл для расчета: 

wire signed   [2*BITS-1:0]  mul_result = i_multiplicand * i_multiplier;
always @(posedge clk) begin
    add_result <= i_adder + (mul_result >> SHIFT);
end

Измените код TB, чтобы выровнять входные изменения с фронтом тактового генератора и использовать не-блокирующие назначения, чтобы избежать условий гонки: 

initial begin
  i_multiplicand =  32'h00010000;
  i_multiplier =    32'h00010000;
  i_adder =     32'h00010000;
  repeat (3) @(posedge clk);
  i_multiplicand <= 32'h00008000;
  i_multiplier <= 32'h00010000;
  i_adder <= 32'h00020000;
  #70
  $finish();
end

Как примечание стиля кодирования, вы можете уменьшить беспорядок, используя порты модуля ANSI: 

module mul_and_add #(
    parameter BITS  = 32,
    parameter SHIFT = 15
)
(
   input clk,
   input signed  [BITS-1:0] i_multiplicand,
   input signed  [BITS-1:0] i_multiplier,
   input signed  [BITS-1:0] i_adder,
   output signed [BITS-1:0] o_result
);

reg signed    [BITS:0]      add_result;
wire signed   [2*BITS-1:0]  mul_result = i_multiplicand * i_multiplier;
always @(posedge clk) begin
    add_result <= i_adder + (mul_result >> SHIFT);
end

assign o_result = add_result[BITS-1:0];

endmodule
...