VBA - адаптация диапазонов ячеек в рабочей книге для отправки по электронной почте

Question

В настоящее время я работаю над фрагментом кода, в котором я отправляю ежедневное электронное письмо, в котором файл Excel включен в качестве вложения, а также включаю активный лист в тело письма.Меня попросили выяснить, возможно ли адаптировать встроенный компонент VBA для включения новых диапазонов ячеек.

Так, например.На одном листе он будет содержать данные о торговой активности за этот день.Если я хочу добавить торговые данные второго дня на тот же рабочий лист и добавить в этот раздел только этот раздел, возможно ли без изменения диапазонов ячеек каждый раз в VBA?

Я прикрепил свой код ниже:

Sub Mail_Sheet_Outlook_Body()

    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set rng = Nothing
    Set rng = ActiveSheet.UsedRange
    'You can also use a sheet name
    'Set rng = Sheets("YourSheet").UsedRange

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .to = "recipient@test.com"
        .CC = ""
        .BCC = ""
        .Subject = "Trades Today" & Date
        .HTMLBody = RangetoHTML(rng)
        .Attachments.Add ActiveWorkbook.FullName
        .Send                                    'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing

End Function

Буду признателен за любые советы по этому вопросу.

Answer 1

Мой ответ может показаться немного конкретным, но я думаю, что из него вы можете, по крайней мере, понять, к чему я клоню.

---

Вот что я рассматриваю в качестве «основного» листа.В этом примере он не обновлялся со вчерашнего дня (следовательно, дата 9/12/2018).

Вот таблица с сегодняшними данными:

Следующий скрипт возьмет сегодняшние данные, добавит к нему столбец "Date" и заполнит сегодняшнюю дату для всех этих строк.Затем он скопирует данные из листа «сегодня» на «мастер» лист вверху списка.

Sub Data_Copy()

    Dim ws1 As Worksheet
    Set ws1 = ActiveSheet           'adjust as necessary

    Dim ws2 As Worksheet
    Set ws2 = sheets(ws1.index + 1) 'adjust as necessary

    Dim lastRow As Long
    lastRow = ws2.Range("A" & rows.count).End(xlUp).row

    If ws2.Range("A1").Value2 <> "Date" Then
        ws2.Columns(1).Insert Shift:=xlRight
        ws2.Range("A1").Value2 = "Date"

        ws2.Range("A2:A" & lastRow).value = Date
    End If

    ws2.rows("2:" & lastRow).copy
    ws1.rows(2).Insert Shift:=xlDown
    Application.CutCopyMode = False

End Sub

Данные в листе «сегодня» после того, как предыдущий скрипт добавил "Date" колонка:

И вот этот «основной» лист после того, как в него были вставлены сегодняшние данные:

---

Наконец, вот обновленная подпрограмма Mail_Sheet_Outlook_Body, так что она захватывает только данные с сегодняшней датой из ActiveSheet (которую я ранее называл 'master').

Теперь он работает вниз по столбцуA и получает номер строки, когда не находит в этой ячейке сегодняшнюю дату.Затем он устанавливает rng для перехода от "A1" к последнему столбцу в UsedRange и к последней строке с текущей датой.

Sub Mail_Sheet_Outlook_Body()

    ...

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With


    'gets last row with today's date
    Dim i As Long
    For i = 2 To Range("A" & rows.count).End(xlUp).row
        If CDate(Range("A" & i).value) <> Date Then
            Exit For
        End If
    Next i

    'makes range out of today's cells
    Set rng = Range(Cells(1, "A"), Cells(i - 1, ActiveSheet.UsedRange.Columns.count))


    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    ...

End Sub

Function RangetoHTML(rng As Range)
    ...
End Function