Пропустить обработку, где значения являются пробелами, используя Excel VBA - PullRequest
0 голосов
/ 01 июня 2018

У меня есть лист Excel с адресами электронной почты, To, CC, Subject и т. Д.

У меня есть пути к файлам для каждого вложения.Это заявления.Некоторые .PDF и некоторые .XLSX в зависимости от запроса.Хотя у меня есть путь к файлу, в некоторых есть несколько столбцов EL, но не во всех строках будет путь к файлу, а не всегда оператор в конце пути.

Мне нужен код VBA для игнорирования пробелов иотсутствующие файлы только прикрепляются как найдено.Это может быть целых 9 файлов или только один или ни одного по строке для получателя.

Я не могу заставить его работать без ошибок, в моей тестовой среде, игнорируя пустые ячейки без пути или путей, которые делаютнет файла.

Sub SendMail()

    Dim objOutlook As Object
    Dim objMail As Object
    Dim ws As Worksheet

    Set objOutlook = CreateObject("Outlook.Application")
    Set ws = ActiveSheet

    For Each cell In ws.Range("A2:A196")

        Set objMail = objOutlook.CreateItem(0)

        With objMail
            .To = cell.Value
            .CC = cell.Offset(0, 1).Value
            .Subject = cell.Offset(0, 2).Value
            .Body = cell.Offset(0, 3).Value
            .Attachments.Add cell.Offset(0, 4).Value
            .Attachments.Add cell.Offset(0, 5).Value
            .Attachments.Add cell.Offset(0, 6).Value
            .Attachments.Add cell.Offset(0, 7).Value
            .Attachments.Add cell.Offset(0, 8).Value
            .Display
        End With

        Set objMail = Nothing
    Next cell

    Set ws = Nothing
    Set objOutlook = Nothing

End Sub

Это мой первый проект VBA.

Ответы [ 2 ]

0 голосов
/ 23 июня 2018

Попробуйте, и, конечно, не стесняйтесь изменять код в соответствии с вашими потребностями.

Составьте список в Sheets ("Sheet1") с помощью:

In column A : Names of the people
In column B : E-mail addresses
In column C:Z : Filenames like this C:\Data\Book2.xls (don't have to be Excel files)

Макрос будет циклически проходить по каждой строке в «Sheet1», и если в столбце B указан адрес электронной почты, а в столбце C: Z указаны имена файлов, он создаст письмо с этой информацией и отправит его.

Sub Send_Files()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim OutApp As Object
    Dim OutMail As Object
    Dim sh As Worksheet
    Dim cell As Range
    Dim FileCell As Range
    Dim rng As Range

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set sh = Sheets("Sheet1")

    Set OutApp = CreateObject("Outlook.Application")

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants)

        'Enter the path/file names in the C:Z column in each row
        Set rng = sh.Cells(cell.Row, 1).Range("C1:Z1")

        If cell.Value Like "?*@?*.?*" And _
           Application.WorksheetFunction.CountA(rng) > 0 Then
            Set OutMail = OutApp.CreateItem(0)

            With OutMail
                .to = cell.Value
                .Subject = "Testfile"
                .Body = "Hi " & cell.Offset(0, -1).Value

                For Each FileCell In rng.SpecialCells(xlCellTypeConstants)
                    If Trim(FileCell) <> "" Then
                        If Dir(FileCell.Value) <> "" Then
                            .Attachments.Add FileCell.Value
                        End If
                    End If
                Next FileCell

                .Send  'Or use .Display
            End With

            Set OutMail = Nothing
        End If
    Next cell

    Set OutApp = Nothing
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

https://www.rondebruin.nl/win/s1/outlook/amail6.htm

0 голосов
/ 01 июня 2018

Это будет игнорировать ваши пустые ячейки в вашем диапазоне, если предположить, что значения, которые вы хотите игнорировать, находятся в вашем диапазоне A2 - A196.

Здесь игнорировать действительно означает перейти к «Else», где ваш цикл начнется заново.Он игнорируется в том смысле, что оператор IF говорит, что он ничего не должен делать, когда пуст.Следующая строка - «Следующая ячейка», которая даст вам желаемый результат.

Sub SendMail()

Dim objOutlook As Object
Dim objMail As Object
Dim ws As Worksheet

Set objOutlook = CreateObject("Outlook.Application")
Set ws = ActiveSheet

For Each cell In ws.Range("A2:A196")
If cell.value <> "" Then  'If NOT blank, do this (your code)
Set objMail = objOutlook.CreateItem(0)

    With objMail
        .To = cell.Value
      .CC = cell.Offset(0, 1).Value
        .Subject = cell.Offset(0, 2).Value
        .Body = cell.Offset(0, 3).Value
        .Attachments.Add cell.Offset(0, 4).Value
        .Attachments.Add cell.Offset(0, 5).Value
        .Attachments.Add cell.Offset(0, 6).Value
        .Attachments.Add cell.Offset(0, 7).Value
        .Attachments.Add cell.Offset(0, 8).Value
        .Display
    End With

    Set objMail = Nothing
Else 'If IS blank, do this (next cell)
End If 
Next cell

Set ws = Nothing
Set objOutlook = Nothing

End Sub
...