MAX Value и его соответствующие узлы в XSLT - PullRequest
Новая
       14

MAX Value и его соответствующие узлы в XSLT

0 голосов
/ 17 мая 2018

Я немного застрял в получении максимального значения Qty из простого структурированного XML. Так что нужна помощь!

Мой XML выглядит следующим образом: 

  <?xml version="1.0" encoding="utf-8"?>
<TANK_DETAILS>
    <TABLES>
        <OUTPUT>
            <item>
                <AREA>INDIA</AREA>
                <MACHINE>T100</MACHINE>
                <MATERIAL>1111111</MATERIAL>
                <BATCH>100</BATCH>
                <QTY>18815.000</QTY>
            </item>
            <item>
                <AREA>INDIA</AREA>
                <MACHINE>T102</MACHINE>
                <MATERIAL>1111111</MATERIAL>
                <BATCH>200</BATCH>
                <QTY>100.000</QTY>
            </item>
            <item>
                <AREA>INDIA</AREA>
                <MACHINE>T103</MACHINE>
                <MATERIAL>1111111</MATERIAL>
                <BATCH>300</BATCH>
                <QTY>10000.000</QTY>
            </item>
            <item>
                <AREA>INDIA</AREA>
                <MACHINE>T101</MACHINE>
                <MATERIAL>1111111</MATERIAL>
                <BATCH>400</BATCH>
                <QTY>35550.000</QTY>
            </item>
            <item>
                <AREA>INDIA</AREA>
                <MACHINE>T104</MACHINE>
                <MATERIAL>1111111</MATERIAL>
                <BATCH>500</BATCH>
                <QTY>10100.000</QTY>
            </item>
            </OUTPUT>
            </TABLES>
        </TANK_DETAILS>

Я хочу получить <MACHINE>,<BATCH> & <Qty> Где <QTY> - максимум.

Выходной XML должен выглядеть так: 

<Rowsets>
            <Rowset>
                <Row>
                    <MACHINE>T101</MACHINE>
                    <BATCH>400</BATCH>
                    <QTY>35550.000</QTY>
                </Row>
            </Rowset>
        </Rowsets>

XSLT, который я пробую, выглядит следующим образом: 

 <?xml version="1.0" encoding="UTF-8" standalone="no"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>

    <!-- Putting the maximum QTY from the list into a variable -->
    <xsl:variable name="max-QTY">
      <xsl:call-template name="find-max">

        <!-- Select the list of QTY elements -->
        <xsl:with-param name="QTY" select="//*[contains(local-name(), 'QTY')]"/>
      </xsl:call-template>
    </xsl:variable>


    <xsl:template match="*">
        <!-- Displaying the result -->
        <QTY>
            <xsl:value-of select="$max-QTY"/>
        </QTY>
    </xsl:template>


    <!-- This template works recursively on the list of QTY. -->
    <xsl:template name="find-max">
        <xsl:param name="QTY"/>
        <!-- The value of the first QTY in this list. -->
        <xsl:variable name="this-QTY">
      <xsl:value-of select="$QTY[position() = 1]"/>
    </xsl:variable>

        <xsl:choose>
            <xsl:when test="$QTY">
                <!-- The maximum value of the remaining QTY in this list. -->
                <xsl:variable name="other-QTY">
          <xsl:call-template name="find-max">
            <xsl:with-param name="QTY" select="$QTY[position() != 1]"/>
          </xsl:call-template>
        </xsl:variable>
                <!-- Return the maximum of this QTYand the remaining QTY. -->
                <xsl:choose>
                    <xsl:when test="$other-QTY&gt; $this-QTY">
                        <xsl:value-of select="$other-QTY"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$this-QTY"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
            <!-- We've reached the last QTY in the list. -->
            <xsl:otherwise/>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

Вывод, который я получаю: 

<?xml version="1.0" encoding="utf-8"?>
<QTY>35550.000</QTY>

Таким образом, я могу найти Максимум <QTY>, но я изо всех сил пытаюсь получить соответствующие <MACHINE> & <BATCH> для максимума <QTY>.

Я уверен, что совершаю небольшую ошибку, но я очень застрял и сталкиваюсь с блоком кодеров.

Также, если есть лучший способ найти максимум, пожалуйста, предоставьте оптимальный ответ. Это было бы полезно.

Спасибо.

Ответы [ 2 ]

0 голосов
/ 17 мая 2018

Я бы просто отсортировал item s по QTY, а затем вывел бы первое (в порядке убывания) или последнее (в порядке возрастания): 

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="TABLES">
      <Rowsets>
          <Rowset>
              <xsl:for-each select="OUTPUT/item">
                  <xsl:sort select="QTY" data-type="number" order="descending"/>
                  <xsl:if test="position() = 1">
                      <Row>
                          <xsl:copy-of select="MACHINE | BATCH | QTY"/>
                      </Row>
                  </xsl:if>
              </xsl:for-each>
          </Rowset>
      </Rowsets>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / 94hvTz2 имеет онлайн-образец.

0 голосов
/ 17 мая 2018

Я бы начал с того, что у меня есть ключ, например: 

<xsl:key name="kQTY" match="QTY" use="."/>

Тогда я бы сохранил максимальный QTY в переменной, например: 

<xsl:variable name="maxQTY">
    <xsl:for-each select="//item">
        <xsl:sort select="key('kQTY', QTY)" order="descending"/>
        <xsl:if test="position()=1">
            <xsl:value-of select="QTY"/>
        </xsl:if>
    </xsl:for-each>
</xsl:variable>

Затем в шаблоне, который соответствует узлу OUTPUT, я бы отфильтровал элемент, который содержит максимальное количество QTY, например: 

<xsl:template match="OUTPUT">
    <Rowset>
            <xsl:apply-templates select="item[QTY=$maxQTY]"/>
    </Rowset>
</xsl:template>

Затем шаблон, необходимый для фильтрации содержимого элемента: 

<xsl:template match="item">
    <xsl:apply-templates select="MACHINE,BATCH,QTY"/>
</xsl:template>

Несколько подходящих шаблонов для очистки 

<xsl:template match="TANK_DETAILS">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="TABLES">
    <Rowsets>
        <xsl:apply-templates/>
    </Rowsets>
</xsl:template>

и шаблон удостоверения личности: 

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

Вся таблица стилей выглядит следующим образом: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:key name="kQTY" match="QTY" use="."/>

    <xsl:variable name="maxQTY">
        <xsl:for-each select="//item">
            <xsl:sort select="key('kQTY', QTY)" order="descending"/>
            <xsl:if test="position()=1">
                <xsl:value-of select="QTY"/>
            </xsl:if>
        </xsl:for-each>
    </xsl:variable>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="OUTPUT">
        <Rowset>
                <xsl:apply-templates select="item[QTY=$maxQTY]"/>
        </Rowset>
    </xsl:template>

    <xsl:template match="item">
        <xsl:apply-templates select="MACHINE,BATCH,QTY"/>
    </xsl:template>

    <xsl:template match="TANK_DETAILS">
        <xsl:apply-templates/>
    </xsl:template>

    <xsl:template match="TABLES">
        <Rowsets>
            <xsl:apply-templates/>
        </Rowsets>
    </xsl:template>

</xsl:stylesheet>

Смотрите это в действии здесь .

...